FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» Projet de planétarium virtuel.
par Pedro Alvarez Hier à 17:29

» Quantité de mémoire utilisée par un exe
par Navigateur Hier à 14:52

» Problème avec 'file_load'.
par Pedro Alvarez Hier à 8:12

» Version instantanée V 0.9.28i20 du 13/06/2018
par jjn4 Sam 16 Juin 2018 - 14:25

» string$(0,chr$(32)) sans erreur
par silverman Ven 15 Juin 2018 - 19:56

» Version instantanée V 0.9.28i19 du 13/06/2018
par Minibug Ven 15 Juin 2018 - 19:14

» PanExpress : l'éditeur Panoramic avec création d'objet
par Jean Claude Ven 15 Juin 2018 - 7:52

» Mes souhaits d'amélioration de Panoramic.
par Pedro Alvarez Jeu 14 Juin 2018 - 20:17

» [RÉSOLU] Message d'erreur impossible à indentifier
par Minibug Mer 13 Juin 2018 - 20:52

» Cadre pour image
par Jean Claude Mar 12 Juin 2018 - 16:31

» Créateur d'objets Panoramic
par Minibug Mar 12 Juin 2018 - 14:02

» Planétarium gratuit.
par Jean Claude Sam 9 Juin 2018 - 18:50

» Comment afficher une image sans fond.
par JL35 Sam 9 Juin 2018 - 14:16

» image_width(n) et image_height(n)
par silverman Sam 9 Juin 2018 - 11:22

» Site sur la programmation sympa
par Jean Claude Jeu 7 Juin 2018 - 11:20

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Juin 2018
LunMarMerJeuVenSamDim
    123
45678910
11121314151617
18192021222324
252627282930 
CalendrierCalendrier

Partagez | 
 

 Des FORM(s) Colorés

Aller en bas 
AuteurMessage
Jean Claude

avatar

Nombre de messages : 5472
Age : 64
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Des FORM(s) Colorés   Sam 19 Mai 2018 - 21:02

Suite à une discussion récente sur ce forum, j'ai accroché sur un code de Klaus qui proposait des "Faux" Bandeaux pour des FORMulaires.
En 100% Panoramic.

J'ai repris l'idée et je l'ai automatisé avec une SUB.
Il reste à appliquer le déplacement de ces "FORM(s)", mais ce sera pour plus tard.

Voici le résultat:
Code:
' Faux Bandeau sur FORM d'après une proposition de Klaus, adapté JC.

' Les variables
  dim no% :' pour fonctionner avec numérotation des objets par variables.
  dim NbForm% :' pour le comptage des Forms supplémentaires pour activer Show 0...
' Les labels
  label ExitForm,Clic

' FORM 0
  HIDE 0 
  color 0,255,0,0 : height 0,45 : caption 0,"Fermeture"
  ON_CLICK 0,Clic
 
' Céation des Forms
  dim Form1%
  no%=no%+1 : Form1%=no% : FORM no% : width no%,300 : height no%,200
  top no%,50 : left no%, 50 : color no%, 200,250,255
  NbForm%=NbForm%+1
' Ordre des paramètres: Numéro du Form, Titre$ (Caption),Couleurs r.g.b du fond, Couleurs r.g.b du texte, taille du texte 
  MakeBandeauForm(Form1%,"FORM 1",255,255,0,0,0,255,14)
                           
' La création d'un faux bandeau utilise 3 N° d'objet (un FORM et 2 PICTUREs) donc le form suivant est le numéro quatre
  dim Form4%
  no%=no%+1 : Form4%=no% : FORM no% : width no%,300 : height no%,200
  top no%,100 : left no%, 200 : color no%, 200,200,255
  NbForm%=NbForm%+1
  MakeBandeauForm(Form4%,"FORM 4",255,180,0,0,0,255,14)

END

rem ============================================================================
Clic:
  message str$(number_click)
  ' ...
return

ExitForm:
  if message_confirmation_yes_no("Voulez-vous vraiment fermer FORM "+str$(parent(number_click)))=1
    hide parent(number_click)
    NbForm%=NbForm%-1 : if NbForm%=0 then Show 0 : return
  end_if
' OU
'  if parent(number_click)=??? then
RETURN
rem ============================================================================
SUB MakeBandeauForm(NumForm%,TitreForm$,Crfb%,Cgfb%,Cbfb%,Crtb%,Cgtb%,Cbtb%,FsTb%)
  ' Appel de la SUB
  ' NumForm% = numéro du Form concerné
  ' TitreForm$ = Caption du faux bandeau
  ' Crfb%,Cgfb%,Cbfb% = Couleurs du fond du bandeau
  ' Crtb%,Cgtb%,Cbtb% = Couleurs du texte du bandeau
  ' FsTb% = font_size du texte du bandeau
  border_hide NumForm%
  dim_local Wform%: Wform%=width_client(NumForm%)
  no%=no%+1
  picture no% : parent no%,NumForm% : width no%,Wform% : height no%,30 : color no%,Crfb%,Cgfb%,Cbfb%
  2d_target_is no% : print_target_is no% : 2d_fill_color Crfb%,Cgfb%,Cbfb%
  font_color no%,Crtb%,Cgtb%,Cbtb% : font_size no%,FsTb%
  print_locate 10,2 : print TitreForm$
  no%=no%+1
  picture no% : parent no%,NumForm% : width no%,20 : height no%,20 : color no%,255,0,0
  top no%,5 : left no%,Wform%-25
  font_bold no% : font_size no%,10 : font_color no%,255,255,255
  2d_target_is no% : 2d_fill_color 255,0,0
  print_target_is no% : print_locate 5,2 : print "X"
  on_click no%,ExitForm             
END_SUB


A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5951
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Des FORM(s) Colorés   Dim 20 Mai 2018 - 14:02

Après  les FORMs colorés, voici le fond dégradé.

Code:

rem ============================================================================
rem       Effet de couleur dégradé au fond d’une fenêtre
rem ============================================================================
dim i,pas

picture 10 : full_space 10 : 2d_target_is 10 : 2d_pen_width 2
pas = height_client(10)/255
for i = 0 to height_client(10) step pas
    2d_pen_color 255,i/pas,0
    2d_line 0,i,width_client(10),i+pas
next i
rem ============================================================================

Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Jean Claude

avatar

Nombre de messages : 5472
Age : 64
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Des FORM(s) Colorés   Dim 20 Mai 2018 - 20:58

Bravo Papydall, je garde sous le coude.

Pour revenir à mon sujet voici le code avec les déplacements possibles, en suivant l'instruction du message du départ.

Code:
' Faux Bandeau sur FORM d'après une proposition de Klaus, adapté JC.

' Les variables
  dim no% :' pour fonctionner avec numérotation des objets par variables.
  dim NbForm% :' pour le comptage des Forms supplémentaires pour activer Show 0...
  dim FormActif%
' Les labels
  label ExitForm,Clic0,ClicForm,ClicBandeau,move

' FORM 0
  HIDE 0  
  color 0,255,0,0 : height 0,45 : caption 0,"Fermeture"
  ON_CLICK 0,Clic0
  
' Céation des Forms
  dim Form1%
  no%=no%+1 : Form1%=no% : FORM no% : width no%,300 : height no%,200
  top no%,50 : left no%, 50 : color no%, 200,250,255
  on_click no%,ClicForm
  NbForm%=NbForm%+1
' Ordre des paramètres: Numéro du Form, Titre$ (Caption),Couleurs r.g.b du fond, Couleurs r.g.b du texte, taille du texte  
  MakeBandeauForm(Form1%,"FORM 1",255,255,0,0,0,255,14)
                            
' La création d'un faux bandeau utilise 3 N° d'objet (un FORM et 2 PICTUREs) donc le form suivant est le numéro quatre
  dim Form4%
  no%=no%+1 : Form4%=no% : FORM no% : width no%,300 : height no%,200
  top no%,100 : left no%, 200 : color no%, 200,200,255
  on_click no%,ClicForm
  NbForm%=NbForm%+1
  MakeBandeauForm(Form4%,"FORM 4",255,180,0,0,0,255,14)
  FormActif%=Form4%

' déplacement
  dim xp0%, yp0%, x%, y%, d% : d% = 0

' GO
  Message "Cliquez dans le bandeau d'une fenêtre ouvre la possibilité de déplacement,"+chr$(13)+"Clic-gauche-maintenu dans le corps de cette fenêtre pour la déplacer."
END

rem ==============================================================' déplacements
move:
   off_mouse_move FormActif%
   if mouse_left_down(FormActif%)>0
    d%=1
    xp0% = mouse_x_left_down(FormActif%)
    yp0% = mouse_y_left_down(FormActif%)
  end_if
  if mouse_left_up(FormActif%)>0 then d%=0
  if d%=1
    x% = mouse_x_position(FormActif%)
    y% = mouse_y_position(FormActif%)
    left FormActif%,left(FormActif%) - (xp0%-x%)
    top FormActif%,top(FormActif%) - (yp0%-y%)
 end_if
 on_mouse_move FormActif%,move
return
rem ============================================================================
Clic0:
   FormActif%=number_click
return

ClicForm:
   FormActif%=number_click
return

ClicBandeau:
   if number_click<>-1 then FormActif%=parent(number_click)
   on_mouse_move FormActif%,move
return

ExitForm:
  if message_confirmation_yes_no("Voulez-vous vraiment fermer FORM "+str$(parent(number_click)))=1
     hide parent(number_click)
     NbForm%=NbForm%-1 : if NbForm%=0 then Show 0 : return
  end_if
' OU
'  if parent(number_click)=??? then
RETURN
rem ============================================================================
SUB MakeBandeauForm(NumForm%,TitreForm$,Crfb%,Cgfb%,Cbfb%,Crtb%,Cgtb%,Cbtb%,FsTb%)
  ' Appel de la SUB
  ' NumForm% = numéro du Form concerné
  ' TitreForm$ = Caption du faux bandeau
  ' Crfb%,Cgfb%,Cbfb% = Couleurs du fond du bandeau
  ' Crtb%,Cgtb%,Cbtb% = Couleurs du texte du bandeau
  ' FsTb% = font_size du texte du bandeau
  border_hide NumForm%
  dim_local Wform%: Wform%=width_client(NumForm%)
  no%=no%+1
  picture no% : parent no%,NumForm% : width no%,Wform% : height no%,30 : color no%,Crfb%,Cgfb%,Cbfb%
  2d_target_is no% : print_target_is no% : 2d_fill_color Crfb%,Cgfb%,Cbfb%
  font_color no%,Crtb%,Cgtb%,Cbtb% : font_size no%,FsTb%
  print_locate 10,2 : print TitreForm$
  on_click no%, ClicBandeau
  no%=no%+1
  picture no% : parent no%,NumForm% : width no%,20 : height no%,20 : color no%,255,0,0
  top no%,5 : left no%,Wform%-25
  font_bold no% : font_size no%,10 : font_color no%,255,255,255
  2d_target_is no% : 2d_fill_color 255,0,0
  print_target_is no% : print_locate 5,2 : print "X"
  on_click no%,ExitForm              
END_SUB



PS: plus intuitif pour les déplacements

Code:
' Faux Bandeau sur FORM d'après une proposition de Klaus, adapté JC.

' Les variables
  dim no% :' pour fonctionner avec numérotation des objets par variables.
  dim NbForm% :' pour le comptage des Forms supplémentaires pour activer Show 0...
  dim FormActif%
' Les labels
  label ExitForm,Clic0,ClicForm,ClicBandeau,move,ClicMove

' FORM 0
  HIDE 0 
  color 0,255,0,0 : height 0,45 : caption 0,"Fermeture du programme"
  ON_CLICK 0,Clic0
 
' Céation des Forms
  dim Form1%
  no%=no%+1 : Form1%=no% : FORM no% : width no%,300 : height no%,200
  top no%,50 : left no%, 50 : color no%, 200,250,255
  on_click no%,ClicForm
  NbForm%=NbForm%+1
' Ordre des paramètres: Numéro du Form, Titre$ (Caption),Couleurs r.g.b du fond, Couleurs r.g.b du texte, taille du texte 
  MakeBandeauForm(Form1%,"FORM 1",255,255,0,0,0,255,14)
                           
  dim Form5%
  no%=no%+1 : Form5%=no% : FORM no% : width no%,300 : height no%,200
  top no%,100 : left no%, 200 : color no%, 200,200,255
  on_click no%,ClicForm
  NbForm%=NbForm%+1
  MakeBandeauForm(Form5%,"FORM 5",255,180,0,0,0,255,14)
  FormActif%=Form5%

' déplacement
  dim xp0%, yp0%, x%, y%, d% : d% = 0

' GO
END

rem ==============================================================' déplacements
move:
  off_mouse_move FormActif%
  if mouse_left_down(FormActif%)>0
    d%=1
    xp0% = mouse_x_left_down(FormActif%)
    yp0% = mouse_y_left_down(FormActif%)
  end_if
  if mouse_left_up(FormActif%)>0 then d%=0
  if d%=1
    x% = mouse_x_position(FormActif%)
    y% = mouse_y_position(FormActif%)
    left FormActif%,left(FormActif%) - (xp0%-x%)
    top FormActif%,top(FormActif%) - (yp0%-y%)
 end_if
 on_mouse_move FormActif%,move
return
rem ============================================================================
Clic0:
  FormActif%=number_click : off_mouse_move FormActif%
return

ClicForm:
 FormActif%=number_click : off_mouse_move FormActif% : Hint FormActif%+2," Déplacer "
 font_color FormActif%+2,0,0,0 : 2d_target_is FormActif%+2 : print_target_is FormActif%+2 : print_locate 0,-12 : print "¤"
 ' ....
 ' ....
 ' ....
return

ClicBandeau:
 if number_click<>-1 then FormActif%=parent(number_click)
 off_mouse_move FormActif% : font_color FormActif%+2,0,0,0 : 2d_target_is FormActif%+2 : print_target_is FormActif%+2 : print_locate 0,-12 : print "¤"
 Hint FormActif%+2," Déplacer "
  ' ....
return

ClicMove:
  if number_click<>-1 then FormActif%=parent(number_click)
  font_color FormActif%+2,150,200,200 : Hint FormActif%+2," Mode déplacement => Actif "
  2d_target_is FormActif%+2 : print_target_is FormActif%+2 : print_locate 0,-12 : print "¤"
  on_mouse_move FormActif%,move
return

ExitForm:
  if message_confirmation_yes_no("Voulez-vous vraiment fermer FORM "+str$(parent(number_click)))=1
    hide parent(number_click)
    NbForm%=NbForm%-1 : if NbForm%=0 then Show 0 : return
  end_if
' OU
'  if parent(number_click)=??? then
RETURN
rem ============================================================================
SUB MakeBandeauForm(NumForm%,TitreForm$,Crfb%,Cgfb%,Cbfb%,Crtb%,Cgtb%,Cbtb%,FsTb%)
  ' NumForm% = numéro du Form concerné
  ' TitreForm$ = Caption du faux bandeau
  ' Crfb%,Cgfb%,Cbfb% = Couleurs du fond du bandeau
  ' Crtb%,Cgtb%,Cbtb% = Couleurs du texte du bandeau
  ' FsTb% = font_size du texte du bandeau
  border_hide NumForm%
  dim_local Wform%: Wform%=width_client(NumForm%)
  no%=no%+1
  picture no% : parent no%,NumForm% : width no%,Wform% : height no%,30 : color no%,Crfb%,Cgfb%,Cbfb%
  2d_target_is no% : print_target_is no% : 2d_fill_color Crfb%,Cgfb%,Cbfb%
  font_color no%,Crtb%,Cgtb%,Cbtb% : font_size no%,FsTb%
  print_locate 10,2 : print TitreForm$
  on_click no%, ClicBandeau

  no%=no%+1
  picture no% : parent no%,NumForm% : width no%,20 : height no%,20 : color no%,Crfb%,Cgfb%,Cbfb%
  top no%,5 : left no%,Wform%-50
  Hint no%," Déplacer "
  font_bold no% : font_size no%,24 : font_color no%,0,0,0
  2d_target_is no% : 2d_fill_color Crfb%,Cgfb%,Cbfb%
  print_target_is no% : print_locate 0,-12 : print "¤"
  on_click no%,ClicMove             

  no%=no%+1
  picture no% : parent no%,NumForm% : width no%,20 : height no%,20 : color no%,255,0,0
  top no%,5 : left no%,Wform%-25
  Hint no%," Fermer "
  font_bold no% : font_size no%,10 : font_color no%,255,255,255
  2d_target_is no% : 2d_fill_color 255,0,0
  print_target_is no% : print_locate 5,2 : print "X"
  on_click no%,ExitForm             
END_SUB


A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Contenu sponsorisé




MessageSujet: Re: Des FORM(s) Colorés   

Revenir en haut Aller en bas
 
Des FORM(s) Colorés
Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» Color management by Steve Wright
» Une form ou un form ?
» Des renders colorés...
» Extensions courantes
» Pour les fêtes ....

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Vos sources, vos utilitaires à partager-
Sauter vers: