FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» quel est ce comportement de Panoramic_editor
par Oscaribout Aujourd'hui à 3:02

» bug BORDER_HIDE : bloque la commande full_space
par silverman Aujourd'hui à 1:19

» Découpe dans une image
par JL35 Hier à 22:00

» FNC IsDateValide(d$) pour vérifier la validité d'une date
par papydall Hier à 18:57

» Pour faire plaisir à jjn4.
par Pedro Alvarez Hier à 8:13

» Pour faire plaisir à Marc37.
par Marc Jeu 22 Fév 2018 - 21:46

» Couleur d'une variable qui n'est pas un mot-clé
par bignono Jeu 22 Fév 2018 - 14:03

» Un catalogue de photos de fleurs, avec KBDD, affichage HTML
par Klaus Mer 21 Fév 2018 - 22:44

» KGF_dll - nouvelles versions
par Klaus Mer 21 Fév 2018 - 22:30

» Mah-Jong anglais
par jjn4 Mer 21 Fév 2018 - 14:22

» Partie fractionnaire d'un flottant
par silverman Mer 21 Fév 2018 - 14:19

» bug CREATE_HIDE : corruption de form
par silverman Mer 21 Fév 2018 - 13:32

» Racine carrée d’un nombre par l’algorithme de Héron
par Ouf_ca_passe Mer 21 Fév 2018 - 9:52

» Méthode manuelle d'extraction de la racine carrée
par pascal10000 Mer 21 Fév 2018 - 7:47

» [annulé]ON_MOVE n,l ne fonctionne que sur le form 0
par silverman Mar 20 Fév 2018 - 16:52

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Février 2018
LunMarMerJeuVenSamDim
   1234
567891011
12131415161718
19202122232425
262728    
CalendrierCalendrier

Partagez | 
 

 Exemples de définition et utilisation de Fonctions FNC

Aller en bas 
AuteurMessage
papydall

avatar

Nombre de messages : 5746
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Exemples de définition et utilisation de Fonctions FNC   Mer 14 Fév 2018 - 14:11

Code:

rem ============================================================================
rem   Exemples de définition et utilisation de Fonctions FNC
rem ============================================================================
rem Exemples d’appel

' message PGCD%(10,15)
' message PPCM%(10,12)
' message factorielle(5)
' ------------------------------------------------------------------------------
' message Combinaison(10,3) : ' Combinaisons de 3 chevaux parmi 10, tiercé dans le désordre
' message Combinaison(52,13): ' Nombre de mains au bridge
' message Combinaison(52,5) : ' Au poker 5 cartes sur 52
' message Combinaison(49,6) : ' Au loto  6 numéros sur 49
' ------------------------------------------------------------------------------  
' message Arrangement(8,3)  : ' Arrangement de 3 chevaux parmi 8, tiercé dans l'ordre
' message Arrangement(12,4) : ' Code de 54 chiffres différents sur un tableau de 12 touches
' message Arrangement(15,4) : ' Idem avec 15 touches
' ------------------------------------------------------------------------------  
' message Permutation(10)
' ------------------------------------------------------------------------------
' message Distance(0,0,10,10)
' message Distance(1,1,8,8)
' ------------------------------------------------------------------------------
' message CircleArea(1)
' message CircleArea(8)
' ------------------------------------------------------------------------------
dim i
for i = 0 to 20
    print "Fibonaci(" + str$(i) + ") = " + str$(Fibonacci(i))
next i
' ------------------------------------------------------------------------------
end
rem ============================================================================
' Calcul du Plus Grand Commun Diviseur de 2 entiers
FNC PGCD%(a%,b%)
    while a% <> b%
        if a% > b%
           a% = a%-b%
        else
           b% = b%-a%
        end_if
    end_while
    RESULT a%
END_FNC
rem ============================================================================
' Calcul du Plus Petit Commun Multiple de 2 entiers
FNC PPCM%(a%,b%)
    dim_local a1%,b1%
    a1% = a% : b1% = b%
    while a1% <> b1%
        if a1% < b1%
           a1% = a1% + a%
        else
           b1% = b1% + b%
        end_if
    end_while
    result a1%
END_FNC
rem ============================================================================
' Calcul de la factorielle d'un entier >= 0
FNC Factorielle(n%)
    dim_local fac
    fac = 1
    while n% > 1
        fac = fac * n%
        n% = n% - 1
    end_while
    result fac
END_FNC
rem ============================================================================
' Calcul de la combinaison de p% éléments parmi n%
' Une combinaison de p éléments pris dans un ensemble à n éléments distincts est
' un sous-ensemble à p éléments de cet ensemble.
' Les éléments sont pris sans répétition et ne sont pas ordonnés.
FNC Combinaison(n%,p%)
    result int(0.5 + factorielle(n%) / (factorielle(p%) * factorielle(n% - p%)))        
END_FNC
rem ============================================================================
' Calcul du nombre de permutations différentes de n% éléments
' Une permutation de n éléments distincts est un réarrangement ordonné, sans
' répétition de ces n éléments
FNC Permutation(n%)      
    result factorielle(n%)
END_FNC
rem ============================================================================
' Calcul du nombre d'arrangements dans l'ordre de p% objets parmi n%
' Un arrangement est une permutation de p éléments pris parmi n éléments distingts (p <= n)
' Les éléments sont pris sans répétition et sont ordonnés
FNC Arrangement(n%,p%)
    result int(0.5 + factorielle(n%) / factorielle(n% - p%))
END_FNC
rem ============================================================================
' Calcul de la distance entres 2 points
FNC Distance(x1,y1,x2,y2)
    result sqr((y2-y1) * (y2-y1) + (x2-x1) * (x2-x1))
END_FNC
rem ============================================================================
' Calcul du nombre de Fibonacci
FNC Fibonacci(n%)
    dim_local i,u,v,w
    if n% <= 0
       result 0
       exit_fnc
    end_if
    if n% = 1
       result 1
       exit_fnc
    end_if
    u = 0 : v = 1
    for i = 2 to n%
        w = u + v : u = v : v = w
    next i
    result v
END_FNC
rem ============================================================================
' Calcul de l'aire d'un cercle de rayon r
FNC CircleArea(r)
    result pi*r*r
END_FNC
rem ============================================================================
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
papydall

avatar

Nombre de messages : 5746
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Exemples de définition et utilisation de Fonctions FNC   Mer 14 Fév 2018 - 18:40

Code:

rem ============================================================================
rem           Des maths pour l’Amour
rem ============================================================================

dim x,y,xc,yc,t,z
picture 10 : full_space 10 : 2d_target_is 10 : 2d_pen_color 255,0,0
alpha 20 : top 20,20 : left 20,150 : font_bold 20 : font_size 20,18
font_name 20,"tahoma" : font_color 20,255,0,0 : color 20, 255,255,255
alpha 30 : top 30,height_client(10) -70 : left 30,150 : font_bold 30
font_size 30,18 : font_name 30,"comic sans ms" : font_color 30,255,0,0 : color 30,255,255,255
xc = width_client(10)/2 : yc = height_client(10)/2 -20 : z = 10
degrees
2d_poly_from xc,yc-5*z
for t = 0 to 360
    x = 16*cube(sin(t))
    y = 13*cos(t) - 5*cos(2*t) - 2*cos(3*t) - cos(4*t)
    2d_poly_to xc+z*x, yc-z*y : ' display
next t
2d_flood xc,yc,255,0,0
caption 20,"Des maths pour l’Amour"
caption 30,"Joyeuse Saint-Valentin !"

end    
rem ============================================================================
FNC Cube(x)
    result x*x*x
END_FNC
rem ============================================================================
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Marc



Nombre de messages : 632
Age : 57
Localisation : TOURS
Date d'inscription : 17/03/2014

MessageSujet: Re: Exemples de définition et utilisation de Fonctions FNC   Mer 14 Fév 2018 - 21:18

Bravo et MERCI Papydall !

cheers Magnifique cœur !  cheers

Merci aussi pour les démonstrations et applications de FNC
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5746
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Exemples de définition et utilisation de Fonctions FNC   Jeu 15 Fév 2018 - 2:48

Code:

rem ============================================================================
rem         Calcul de l’Indice de Masse Corporelle IMC
rem ============================================================================
rem  Appel : indice = IMC(Poids,Taille)
rem  Poids en kg
rem  taille en m
rem ============================================================================
 
dim indice, classification$, risque$
' Exemples
 indice = IMC(50,1.70) : Diagnostic()
 indice = IMC(82,1.69) : Diagnostic()
 indice = IMC(60,1.70) : Diagnostic()
 indice = IMC(85,1.80) : Diagnostic()
 indice = IMC(100,1.65): Diagnostic()
 indice = IMC(120,1.72): Diagnostic()
end
rem ============================================================================
rem diagnostic
rem ============================================================================
SUB Diagnostic()
    if indice < 16
       classification$ = "Maigreur extrême"
       risque$ = "Risque de maladie acrue"
    else
       if indice >= 16 and indice <= 19
          classification$ = "Maigreur"
          risque$ = "Risque de maladie élévé"
       else
          if indice > 19 and indice <= 25
             classification$ = "Corpulence normale"
             risque$ = "Risque de maladie faible"
          else
             if indice > 25 and indice <= 30
                classification$ = "Embonpoint"
                risque$ = "Risque de maladie acrue"
             else
                if indice > 30 and indice <= 35
                   classification$ = "Obésité de classe I"
                   risque$ = "Risque de maladie élévé"
                else
                   if indice > 35 and indice <= 40
                      classification$ = "Obésité de classe II"
                      risque$ = "Risque de maladie très élévé"
                   else
                      classification$ = "Obésité de classe III"
                      risque$ = "Risque de maladie extrêmement élévé"
                   end_if
                end_if
             end_if
          end_if
       end_if
    end_if
    message "IMC = " + str$(indice) + chr$(13) + Classification$ + chr$(13) + risque$
END_SUB
rem ============================================================================
' Poids en kg
' Taille en m
FNC IMC(poids,taille)
    result poids / taille / taille
END_FNC
rem ============================================================================
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Marc



Nombre de messages : 632
Age : 57
Localisation : TOURS
Date d'inscription : 17/03/2014

MessageSujet: Re: Exemples de définition et utilisation de Fonctions FNC   Lun 19 Fév 2018 - 22:50

Merci Papydall !

En référence à ton programme de calcul IMC :

Mince ! affraid

J'ai une légère surcharge pondérale. Shocked

Il va me falloir perdre un peu de poids...  scratch

Peut-être faut-il remplacer le clavier et la souris par des haltères !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Contenu sponsorisé




MessageSujet: Re: Exemples de définition et utilisation de Fonctions FNC   

Revenir en haut Aller en bas
 
Exemples de définition et utilisation de Fonctions FNC
Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» Kaspersky utilisation ? ( résolu )
» [Résolu] Utilisation de REGCLEANER (sauvegarde)
» Infoland Définition Lettre C
» Première utilisation 1490T
» [RESOLU] Modification de la taille de la police du manuel d'utilisation DEZL

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Vos sources, vos utilitaires à partager-
Sauter vers: