FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» Planétarium virtuel.
par Pedro Alvarez Sam 21 Juil 2018 - 16:57

» Roues dentées
par jean_debord Sam 21 Juil 2018 - 10:40

» Attention arnaque !
par mindstorm Jeu 19 Juil 2018 - 19:18

» Qui fait quoi ?
par silverman Mer 18 Juil 2018 - 15:21

» ITEM_SELECT N,L pour synedit
par silverman Mer 18 Juil 2018 - 15:20

» Boussole
par jean_debord Mer 18 Juil 2018 - 11:06

» Roue à n faces
par Marc Dim 15 Juil 2018 - 22:16

» Exemple d'une nouvelle version d'un GRID
par Jean Claude Ven 13 Juil 2018 - 10:32

» Une simple question
par Oscaribout Sam 7 Juil 2018 - 23:20

» BUG sur l'objet TAB
par Jack Sam 7 Juil 2018 - 21:12

» Monopoly moderne
par jjn4 Sam 7 Juil 2018 - 15:06

» Récapitulatif ludothèque panoramic jjn4
par jjn4 Ven 6 Juil 2018 - 17:41

» Lignes ondulées
par JL35 Ven 6 Juil 2018 - 17:39

» bug off_activate 0 : sans d'effet
par silverman Ven 6 Juil 2018 - 13:02

» Position des objets d'un conteneur dans FBPano et Panoramic
par Navigateur Ven 6 Juil 2018 - 12:59

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Juillet 2018
LunMarMerJeuVenSamDim
      1
2345678
9101112131415
16171819202122
23242526272829
3031     
CalendrierCalendrier

Partagez | 
 

 Intelligence Artificielle

Aller en bas 
AuteurMessage
Minibug

avatar

Nombre de messages : 2979
Age : 51
Localisation : Vienne (86)
Date d'inscription : 09/02/2012

MessageSujet: Intelligence Artificielle   Sam 27 Jan 2018 - 11:20

Bonjour à tous !

Une fois n'est pas coutume, je souhaite vous faire découvrir un programme qui n'est pas de moi !  Wink

Ce programme a été présenté initialement dans le magazine MICRO_SYSTEMES de décembre 1984.
Il a été écrit en basic pour l'Apple II ! Il s'agit du MINI-SYSTEME EXPERT de PHILIPPE LARVET.
Vous pouvez retrouver l'article ici avec le code présenté dans les pages du magazine.

Il s'agit en fait d'un programme d'IA qui va ajouter des connaissances à une base de données qui pourra ensuite être interrogée.

Patrice Dargenton a repris ce code et l'a adapté en VB sur son site (IAVB).

Pour vous simplifier le travail,
j'ai déposé la version un fichier IAVB-master.zip (de Patrice Dargenton) sur mon WEBDAV si vous voulez tester...
C'est un zip qu'il suffit d'extraire et vous lancez ensuite l'EXEcutable !
Il vous faudra peut être installer certains éléments supplémentaires de Windows. mais rien de bien compliqué...

Si certains se sentent d'attaque pour reprendre le code de la revue MICRO-SYSTEMES et l'adapter à Panoramic... drunken
Je l'avais entièrement saisie tel que mais je ne le retrouve plus sur mon PC. Il faut dire que cela fait déjà un certain temps...  Wink


Bonne lecture et bon amusement... geek



Dernière édition par Minibug le Mar 6 Fév 2018 - 19:28, édité 2 fois
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://gpp.panoramic.free.fr
Minibug

avatar

Nombre de messages : 2979
Age : 51
Localisation : Vienne (86)
Date d'inscription : 09/02/2012

MessageSujet: Re: Intelligence Artificielle   Dim 28 Jan 2018 - 11:16

Salut à tous ! cheers

Je viens de retrouver mon fichier contenant le code initial du programme de 1984 que j'avais recopié.
Je l'ai mis sur mon WEBDAV sous le nom de IA.txt. Et je vous le livre aussi ci-dessous.  drunken

Si quelqu'un veut le mettre au format Panoramic... J’espère ne pas avoir recopié trop d'erreurs...  Wink  

code MINI-SYSTEME EXPERT sur APPLE II:
 
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://gpp.panoramic.free.fr
Minibug

avatar

Nombre de messages : 2979
Age : 51
Localisation : Vienne (86)
Date d'inscription : 09/02/2012

MessageSujet: Re: Intelligence Artificielle   Dim 4 Fév 2018 - 2:25

Bonsoir a tous !

J'ai converti le source en Panoramic. Maintenant on peut donc tester directement avec le code ci-dessous.

Par contre il reste encore quelques erreurs dans les formules.
Il faut dire que le code initial contenait de nombreux GOTO et peut être aussi des erreurs de typographie.
J'ai fait le ménage mais je pense qu'il en reste encore...

Pour les tests, commencez par ajouter des phrases simples comme :
- laurent possede un stylo bleu
- claude possede un stylo vert
- etc...

Ensuite vous pouvez poser des questions du type :
- qui possede un stylo bleu ?
- est ce que laurent possede un stylo vert ?

N'oubliez pas le '?' pour les questions et évitez les accents et la ponctuation.

Pour mieux comprendre je vous invite à reprendre les posts précédents qui font référence aux sites correspondants.

Code:
' #################################################################################################################
' #################################################################################################################
' ################                                                                                 ################
' ################       BASE DE CONNAISSANCES RELATIONNELLE INTERROGEABLE EN LANGAGE NATUREL      ################
' ################                                                                                 ################
' ################                                  RELATIONS TRAITEES :                           ################
' ################                              HORIZONTALES ET VERTICALES                         ################
' ################                INDIRECTION / COMPOSITION DE FONCTIONS / SYLLOGISMES             ################
' ################                                                                                 ################
' ################                     AUTEUR : PHILIPPE LARVET (COPYRIGHT 1984)                   ################
' ################                      ADAPTATION PANORAMIC : MINIBUG (2018)                      ################
' ################                                                                                 ################
' #################################################################################################################
' #################################################################################################################

DIM no% , form% , memo% , edit% , dlist%
DIM chemin$

DIM JM,KM,NP,NM,NT,NE,NI,ND,JI,LB
DIM A,I,J,K,L,M,N,V,R,T,J1,J2,L1,L2,I2,S1,S2
DIM A$,H$,G$,F$,T$,X$,Z$
DIM B$(101,6),C$(11),E$(61),W$(11),D(3),P(3),E(11),S(101,4)
  
LABEL erreur,decode                                
                        
LABEL ligne2160,ligne2170          
LABEL ligne3000
LABEL ligne5000,ligne6000,ligne6010,ligne6170,ligne6180
LABEL ligne7030,ligne7050,ligne7200,ligne7300,ligne7330,ligne7400
LABEL ligne8100,ligne8140
LABEL ligne9200

ERROR_FRENCH : ON_ERROR_GOTO erreur

chemin$=DIR_CURRENT$+chr$(92) 

LEFT no%,0 : TOP no%,SCREEN_Y-300 : WIDTH no%,800 : HEIGHT no%,300 : COLOR no%,200,200,200
   CAPTION no%,"IA - 06.05.2015" : BORDER_SMALL no% : form%=no% : no%=no%+1
   MEMO no% : PARENT no%,form% : LEFT no%,5 : TOP no%,5
      WIDTH no%,WIDTH(form%)-25 : HEIGHT no%,HEIGHT(form%)-76 : COLOR no%,240,240,240
      FONT_NAME no%,"@FangSong" : INACTIVE no% : memo%=no% : no%=no%+1
   EDIT no% : PARENT no%,form% : LEFT no%,5 : TOP no%,HEIGHT(form%)-68
      WIDTH no%,WIDTH(form%)-85 : HEIGHT no%,30 : COLOR no%,240,240,240
      FONT_NAME no%,"@FangSong" : FONT_BOLD no% : FONT_SIZE no%,10
      ON_KEY_DOWN no%,decode : edit%=no% : no%=no%+1
   DLIST no% : dlist%=no% : no%=no%+1
      IF FILE_EXISTS(chemin$+"mots.ini")=1 THEN FILE_LOAD dlist%,chemin$+"mots.ini"
      ITEM_ADD memo%,"I.A. > Je suis prêt ! "  
   SET_FOCUS edit%
                                                                                                                  
' ############################################## MOTS NON SIGNIFIANTS #############################################
DATA EST,LE,LA,DE,UN,UNE,L,DU,D,LES,DES,ET,OU,QUE,QUI,SONT,IL,ELLE,A,T,ETE
DATA EN,OU,COMMENT,AU,N,NE,S,SE,ETAIT,QUOI,C,CE,QUEL,QUELLE,QUELS,QUELLES,PAR
DATA LEQUEL,LAQUELLE,CA,SIGNIFIE,TOUT,OR,TOUS,TOUTE,TOUTES,=,(,),Y,FF      

REPEAT
   READ T$
   NE=NE+1 : E$(NE)=T$
UNTIL T$="FF"

' ################################################# INITIALISATION ################################################
NP=4 : NM=100

END

' ############################################### PROCEDURE DECODE ################################################
decode:
   IF KEY_DOWN_CODE=13
  
      ' ENTREE  
      A$=UPPER$(TEXT$(edit%)) : L=LEN(A$) : NI=0
      ITEM_ADD memo%,"Vous > "+A$ : TEXT edit%,""

      ' EXAMEN DE L'ENTREE
      IF LEFT$(A$,1)="/"

         ' COMMANDES DE SERVICE
         ' LISTAGE DE LA BASE
         IF A$="/L"
            FOR I = 1 TO NT
               ITEM_ADD memo%,"IA > "+STR$(I)+" "+B$(I,NP+1)
            NEXT I
            RETURN
         END_IF
  
         ' SUPPRESSION
         IF LEFT$(A$,2)="/D"
            IF L<=2 : I=NT : ELSE : I=VAL(RIGHT$(A$,L-2)) : END_IF
            FOR J=1 TO NP+1
               B$(I,J)=""
            NEXT J
            ITEM_ADD memo%,"IA > L'assertion n° "+STR$(I)+" est supprimée !"
            RETURN
         END_IF
      
         ' EFFACEMENT DE TOUTE LA BASE
         IF A$="/EFF"
            IF MESSAGE_CONFIRMATION_YES_NO("Voulez vous effacer toute la base ?")=1
               FOR I=1 TO NT
                  FOR J=1 TO NP+1
                     B$(I,J)=""
                  NEXT J
               NEXT I
               ITEM_ADD memo%,"IA > La base est entièrement effacée !"
               NI=0
            ELSE
               ITEM_ADD memo%,"IA > Aucun élément n'est effacé !"  
            END_IF
            RETURN
         END_IF
      
         ' COMMANDE INCONNUE
         ITEM_ADD memo%,"IA > cette commande est inconnue !" : RETURN      
      
      END_IF
      
      IF RIGHT$(A$,1)="?" THEN A$=LEFT$(A$,L-1) : NI=1

      ' EXTRACTION DES MOTS
      FOR K=1 TO NP
         C$(K)="" : E(K)=0
      NEXT K
      L=LEN(A$) : H$=""
      N=1 : ND=0 : J=1

      REPEAT
         I=J

         REPEAT
            J=J+1
            G$=MID$(A$,J,1)
         UNTIL G$=" " OR G$="'" OR G$="-" OR G$="(" OR G$=")" OR J>L
        
         F$=MID$(A$,I,J-I)

         IF I=1 AND LEFT$(F$,2)="QU" THEN N=0 : GOTO ligne2160

         FOR K=1 TO NE
            IF E$(K)=F$ THEN EXIT_FOR
         NEXT K  
         IF K<=NE THEN GOTO ligne2160

         ND=ND+1
         IF NI=0 AND ND>NP THEN ITEM_ADD memo%,"IA > Votre phrase est trop longue !" : RETURN

         H$=H$+F$ : C$(ND)=F$            
         IF ND>2 THEN GOTO ligne2160
         D(ND)=J

         ligne2160:  
         IF J>L THEN GOTO ligne3000

         ligne2170:
         J=J+1
         IF MID$(A$,J,1)=" " AND J<=L THEN GOTO ligne2170    
      
      UNTIL J>L  

      ' FIN EXTRACTION
      ligne3000:
      IF C$(1)="" THEN ITEM_ADD memo%,"IA > Votre question est incompléte !" : RETURN

      IF NI>0 AND C$(1)="DONC" THEN GOTO ligne9200
      IF NI>0 THEN GOTO ligne6000
      IF ND<=1 THEN ITEM_ADD memo%,"IA > Votre phrase est trop courte !" : RETURN

      ' CONTROLE EXISTENCE DE L'ASSERTION DANS LA BASE
      IF NT=0 THEN GOTO ligne5000
      FOR I=1 TO NT
         Z$=""
         FOR J=1 TO NP
            Z$=Z$+B$(I,J)
         NEXT J
         IF Z$=H$ THEN EXIT_FOR
      NEXT I  
      IF I>NT THEN GOTO ligne5000

      ' ASSERTION DEJA CONNUE
      ITEM_ADD memo%,"IA > Assertion déjà connue !"
      RETURN

      ' ENRICHISSEMENT BASE
      ligne5000:    
      FOR I=1 TO NM
         IF B$(I,1)="" THEN EXIT_FOR    
      NEXT I
      IF I>NM THEN ITEM_ADD memo%,"IA > STOP ! La base est pleine !" : TERMINATE

      FOR J=1 TO NP
         B$(I,J)=C$(J)
      NEXT J
      B$(I,NP+1)=A$
      S(I,1)=ND : S(1,2)=D(1) : S(1,3)=D(2)
      ITEM_ADD memo%,"IA > COMPRIS"
      IF I>NT THEN NT=I
      RETURN

      ' INTERROGATION - CONTROLE EXISTENCE DE CHACUN DES MOTS
      ligne6000:
      K=0 : M=NT

      ligne6010:
      T=0 : K=K+1
      FOR I = 1 TO NT
         J=1
         FOR J = 1 TO S(I,1)                    
            IF B$(I,J)=C$(K) THEN EXIT_FOR
         NEXT J
         IF J>S(I,1) THEN GOTO ligne6180
         T=1
         IF E(K)=0 THEN E(K)=I
         IF ND>1 THEN GOTO ligne6170
         IF J=2 AND L>(LEN(C$(K))+1)
            GOTO ITEM_ADD memo%,"IA > "+LEFT$(B$(I,NP+1),S(I,2)) : GOTO ligne6180  
         END_IF
         ITEM_ADD memo%,"IA > "+B$(I,NP+1) : GOTO ligne6180

         ligne6170:
         A=I : I=NT

         ligne6180:
      NEXT I
      
      ' MOT INCONNU
      IF T=0 THEN ITEM_ADD memo%,"IA > Je ne connais pas "+"'"+C$(K)+"' !" : RETURN
      
      ' UN SEUL MOT SIGNIFIANT
      IF ND=1 THEN RETURN
      
      IF A<M THEN M=A
      IF K<ND THEN GOTO ligne6010
      IF ND>NP THEN GOTO ligne8100

      ' RELATION HORIZONTALE
      V = 0
      FOR I=M TO NT
         T=0 : K=0 : J=0
      
         ligne7030:
         K=K+1
         IF K>ND THEN GOTO ligne7300

         ligne7050:
         J=J+1
         IF J>S(I,1) THEN GOTO ligne7200
         IF B$(I,J)<>C$(K) THEN GOTO ligne7050
         T=T+1
         IF T<=2 THEN P(T)=J
         GOTO ligne7030

         ligne7200:
         IF T=0 THEN GOTO ligne7400

         ligne7300:
         IF (T<>ND) OR (T<>S(I,1)) THEN GOTO ligne7330
         ITEM_ADD memo%,"IA > OUI" : V=1 : I=NT
         GOTO ligne7400

         ligne7330:
         IF T<>ND THEN GOTO ligne7400
         V=1
         IF P(1)=1 AND P(2)=2
            LB=LEN(B$(I,NP+1))
            ITEM_ADD memo%,"IA > "+RIGHT$(B$(I,NP+1),LB-S(I,3))
            GOTO ligne7400
         END_IF
         IF P(1)=2 THEN ITEM_ADD memo%,"IA > "+LEFT$(B$(I,NP+1),S(I,2)) : GOTO ligne7400
         IF P(1)=3 THEN ITEM_ADD memo%,"IA > "+LEFT$(B$(I,NP+1),S(I,3)) : GOTO ligne7400  
         ITEM_ADD memo%,"IA > "+B$(I,NP+1)

         ligne7400:
      NEXT I
      IF V=1 THEN RETURN


      ' RELATION VERTICALE - COMPOSITION DE FONCTIONS
      ligne8100:
      FOR K=1 TO ND
         W$(K)=C$(K)
      NEXT K
      R=ND

      ligne8140:
      Z$=W$(R-1)+W$(R)
      FOR I=M TO NT
         IF B$(I,2)+B$(I,3)=Z$ THEN EXIT_FOR
      NEXT I
      IF I<=NT
         R=R-1 : W$(R)=B$(I,1)
         IF R>1 THEN GOTO ligne8140  
         ITEM_ADD memo%,"IA > "+W$(1)
         RETURN
      END_IF
      

      ' INDIRECTION
      I2=E(2) : T=0

      REPEAT
         E(2)=I2

         REPEAT
            FOR J1=1 TO S(E(1),1)
               Z$=B$(E(1),J1)
               FOR J2 = 1 TO S(E(2),1)
                  IF (E(1)<>E(2)) AND (Z$=B$(E(2),J2)) AND (Z$<>C$(1)) AND (Z$<>C$(2))
                     T=1 : ITEM_ADD memo%,"IA > "+B$(E(1),J1) : J1=NP : J2=NP
                  END_IF
               NEXT J2
            NEXT J1
            K=2 : recherche()
         UNTIL V<>1
      
         K=1 : recherche()
      UNTIL V<>1
      
      IF T=1 THEN RETURN

      ' ECHEC FINAL
      IF N=0 : ITEM_ADD memo%,"IA > Je l'ignore !" : ELSE : ITEM_ADD memo%,"IA > non" : END_IF
      RETURN

      ' S Y L L O G I S M E - RECHERCHE MOYEN TERME
      ligne9200:
      S2=NT : S1=NT-1 : T=0
      L1=LEN(B$(S1,NP+1))
      L2=LEN(B$(S2,NP+1))
      FOR K=1 TO 3
         FOR J =1 TO 3          
            IF B$(S1,J)<>"" AND B$(S2,K)=B$(S1,J)
               T=1 : JM=J : KM=K
               J=NP : K=NP
            END_IF
         NEXT J
      NEXT K  
      
      ' ABSENCE DE CONCLUSION
      IF T=0 THEN ITEM_ADD memo%,"IA > Je ne peux rien conclure !" : RETURN

      ' RESOLUTION
      IF KM=1 THEN X$=RIGHT$(B$(S2,NP+1),L2-S(S2,2))
      IF KM=2 THEN X$=LEFT$(B$(S2,NP+1),S(S2,2))    
      IF KM=3 THEN X$=LEFT$(8$(52,NP+1),S(S2,3))    

      IF LEFT$(X$,3)="OR " THEN X$=RIGHT$(X$,LEN(X$)-3)

      IF JM=1 THEN Z$=RIGHT$(B$(S1,NP+1),L1-S(S1,2))
      IF JM=2 THEN Z$=LEFT$(B$(S1,NP+1),S(S1,2))    
      IF JM=3 THEN Z$=LEFT$(B$(S1,NP+1),S(S1,3))    

      IF KM+JM=2
         IF LEFT$(X$,4)="EST " THEN X$=RIGHT$(X$,LEN(X$)-4) : X$="QUELQUE "+X$+" "
         IF LEFT$(X$,5)="SONT " THEN X$=RIGHT$(X$,LEN(X$)-5) : X$="QUELQUES "+X$+" "
      END_IF
      
      ITEM_ADD memo%,"IA > DONC "+X$+" "+Z$ : ITEM_ADD memo%,"IA > " : RETURN
 
   END_IF
RETURN  

' PROCEDURE DE RECHERCHE D'UN PROCHAIN E(K)
SUB recherche()
   V=0
   FOR I=E(K)+1 TO NT
      FOR J=1 TO S(E(K),1)
         IF (B$(I,J)=C$(K)) THEN V=1 : E(K)=I : J=NP : I=NT
      NEXT J
   NEXT I
END_SUB    
          
' PROCEDURE ERREUR
erreur:
   MESSAGE STR$(ERROR_NUMBER)+" "+ERROR_TYPE$+" a la ligne "+STR$(ERROR_LINE)
TERMINATE

' #################################################################################################################


Dernière édition par Minibug le Dim 4 Fév 2018 - 17:56, édité 1 fois
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://gpp.panoramic.free.fr
Pedro Alvarez

avatar

Nombre de messages : 1104
Date d'inscription : 19/01/2014

MessageSujet: Intelligence Artificielle.   Dim 4 Fév 2018 - 8:24

Bonjour.

J'éprouve un grand intérêt pour les programmes d'IA.
La traduction automatique rejoint un peu ce genre de programmes.
J'ai donc testé les données suivantes, après avoir ajouté 'combien' dans la liste des mots:

le corbeau est un oiseau
un oiseau a 2 ailes
combien d'ailes a le corbeau ?


Le programme me répond 'non' !!

Aurais-je omis quelque chose ?
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Minibug

avatar

Nombre de messages : 2979
Age : 51
Localisation : Vienne (86)
Date d'inscription : 09/02/2012

MessageSujet: Re: Intelligence Artificielle   Dim 4 Fév 2018 - 9:38

Salut Pedro Alvarez !

Non, tu n'as rien omis.
Encore que pour les SYLLOGISMES il faut utiliser la question 'DONC ?' pour que le programme parvienne à recouper tes deux phrases de tel manière que :

le corbeau est un oiseau et un oiseau a 2 ailes correspondent à le corbeau a 2 ailes.

Si tu as suivi le post depuis le début, j'ai expliqué avoir récupéré ce code sur internet.
Il date de 1984 et était initialement destiné à l"APPLE II ( de PHILIPPE LARVET).

J'ai donc recopié entièrement le code depuis le magazine MICRO_SYSTEMES.
Il se peut qu'il y est des erreurs de saisie comme le 1 et le I par exemple !

Après j'ai du adapter le code pour Panoramic. Il y avez beaucoup de GOTO que j'ai tenté d'éliminer.
Tout cela explique sûrement le problème que tu as rencontré...
Pour les SYLLOGISMES et les RELATIONS VERTICALES je sais qu'il y a une ou plusieurs erreurs mais pas facile à trouver dans les suites de calculs !

Tu peux aussi tester la version Visual Basic (IAVB) de Patrice Dargenton que j'ai déposé sur mon WEBDAV.
Elle fonctionne parfaitement bien et intègre de nombreuses questions pour faire un tour complet du programme.

Maintenant que j'ai les bases, je vais tenter de développer mon propre système en Panoramic.
Bien que ce ne soit pas évident, je vais essayé de refaire un programme équivalent.

Merci d'avoir tenté le test Pedro.  Wink
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://gpp.panoramic.free.fr
papydall

avatar

Nombre de messages : 5980
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Intelligence Artificielle   Dim 4 Fév 2018 - 12:34

Merci Laurent alias Minibug pour le partage.
Pour la sempiternelle fois, le forum t’a bouffé l’anti-slash en ligne 35
Codez comme ceci

Code:

chemin$=DIR_CURRENT$+chr$(92)  
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
JL35



Nombre de messages : 6302
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Intelligence Artificielle   Dim 4 Fév 2018 - 13:36

Une vengeance de la 'Bêtise Naturelle'.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Minibug

avatar

Nombre de messages : 2979
Age : 51
Localisation : Vienne (86)
Date d'inscription : 09/02/2012

MessageSujet: Re: Intelligence Artificielle   Dim 4 Fév 2018 - 17:58

Merci Papydall, je viens de corriger.

En même temps, il n'est pas utilisé dans le code que j'ai mis en ligne. Suspect
C'est un reliquat d'un ancien code que j'ai pris pour la gestion de l'interface !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://gpp.panoramic.free.fr
RMont



Nombre de messages : 198
Age : 76
Localisation : charente maritime
Date d'inscription : 29/12/2008

MessageSujet: Re: Intelligence Artificielle   Mar 6 Fév 2018 - 17:17

bonjour a tous.
pour minibug.
je me suis penché (un peu) sur ta traduction du prg IA et je me pose cette question:
est-ce que ces lignes ont une utilité
' examen de service : IF LEFT$(A$,1)="/"
' listage de la base   : IF A$="/L"
' suppression           : IF LEFT$(A$,2) ="/D"
' effacement de toute la base : IF A$="/EFF"
si oui ,peux-tu m'expliquer:
j'ai fait une recherche avec edition/rechercher et il n'y a que dans ces lignes que je  trouve
 "/" ; "/L" ; "/D" ;"/EFF"
bonne soirée a vous
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Minibug

avatar

Nombre de messages : 2979
Age : 51
Localisation : Vienne (86)
Date d'inscription : 09/02/2012

MessageSujet: Re: Intelligence Artificielle   Mar 6 Fév 2018 - 19:27

Bonsoir Rmont !

Oui elles ont une utilité. Le / permet d'utiliser des fonctions particulières.

/L : (LISTE) donne la liste de toute les assertions connues dans le programme.
/D xx : (DELETE xx) permet de supprimer l'assertion xx de la liste.
/EFF : (EFFACE) permet de supprimer la liste de toutes les assertions connues.

Si vous souhaitez en savoir plus reportez vous au premier message et testez la version IAVB présentée par PATRICE DARGENTON.
Ce programme est réalisé en Visual Basic et il donne même la parole au programme.
En plus vous avez tout un ensemble de phrases déjà enregistrée qu'il suffit de valider...
Je vous invite vraiment à le tester, c'est bluffant !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://gpp.panoramic.free.fr
Contenu sponsorisé




MessageSujet: Re: Intelligence Artificielle   

Revenir en haut Aller en bas
 
Intelligence Artificielle
Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» Fenêtre Artificiel
» <@¿@> du 29 Janvier : dosettes larmes artificielles
» eclairages "soleil "et "artificiel" avec artlantis

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Présentation et bavardage-
Sauter vers: