FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» Logiciel de soutien scolaire en langues.
par Pedro Alvarez Aujourd'hui à 16:52

» KGF_dll - nouvelles versions
par Klaus Aujourd'hui à 14:16

» Compilateur FBPano
par Ouf_ca_passe Aujourd'hui à 12:25

» mise a jour calculatrice
par papydall Aujourd'hui à 2:01

» double guillemets "" dans un EDIT
par Marc Hier à 23:43

» Documentation de KGF
par Klaus Lun 20 Nov 2017 - 22:52

» Zoom sur une portion d'écran
par JL35 Lun 20 Nov 2017 - 21:51

» Recherche d'une expression dans un source
par Marc Lun 20 Nov 2017 - 13:08

» Tracer une grille n'importe où sur l'écran
par JL35 Dim 19 Nov 2017 - 22:14

» TourD Version 2
par Klaus Sam 18 Nov 2017 - 23:58

» La métamatière et le peuple
par JL35 Ven 17 Nov 2017 - 21:18

» Capture d'une zone de l'écran total
par JL35 Ven 17 Nov 2017 - 18:41

» qui peut résoudre mon prb
par pascal10000 Jeu 16 Nov 2017 - 17:30

» évènements et objets système : listage automatique
par Jean Claude Jeu 16 Nov 2017 - 11:15

» Panoramic et la reconnaissance vocale.
par papydall Jeu 16 Nov 2017 - 3:45

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Novembre 2017
LunMarMerJeuVenSamDim
  12345
6789101112
13141516171819
20212223242526
27282930   
CalendrierCalendrier

Partagez | 
 

 Choix d'une police de caractères

Voir le sujet précédent Voir le sujet suivant Aller en bas 
AuteurMessage
JL35



Nombre de messages : 5992
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Choix d'une police de caractères   Jeu 26 Oct 2017 - 16:49

Histoire de meubler le silence, juste une petite sub pour choisir la police de caractères d'un objet
(avec taille, couleur, enrichissements)
Code:
PICTURE 1: FULL_SPACE 1
PRINT_TARGET_IS 1: PRINT "Voyez Le Brick Géant"
Police(1,100,200)
PRINT "Que J'Examine Près Du Wharf"
END
' ==============================================================================
SUB Police(objet%,x%,y%)
  ' Choix police, taille, enrichissements, couleur de texte sur l'objet objet%
  ' (positionnement de la fenêtre en x%,y% de l'écran)
  DIM_LOCAL fm%,fl%,fp%,co%,i%,j%,k%,r%,g%,b%,xs%,ys%,expol%,dt%,cl%,np%,lp%,la%
  DIM_LOCAL sp%,ck%,wg%
  IF LABEL("Afff") = 0 THEN LABEL Afff
  IF LABEL("Cfff") = 0 THEN LABEL Cfff
  IF LABEL("Vfff") = 0 THEN LABEL Vfff
  IF LABEL("Ffff") = 0 THEN LABEL Ffff
fm%=950
  FORM fm%: TOP fm%,y%: LEFT fm%,y%: WIDTH fm%,300: HEIGHT fm%,200: BORDER_SMALL fm%
          FONT_BOLD i%: FONT_NAME i%,"Arial": COLOR fm%,180,255,255
          ON_CLOSE fm%,Ffff
          CAPTION fm%,"POLICE,  TAILLE,  COULEUR,  ENRICHISSEMENTS"
i%=fm%+1: CONTAINER_OPTION i%: PARENT i%,fm%: HEIGHT i%,16: CAPTION i%,"Polices:": co%=i%
i%=i%+1: OPTION i%: PARENT i%,i%-1: TOP i%,0: LEFT i%,45: CAPTION i%,"Toutes"
i%=i%+1: OPTION i%: PARENT i%,i%-2: TOP i%,TOP(i%-1): LEFT i%,98: CAPTION i%,"Fixes"
        MARK_ON co%+1: ON_CLICK co%+1,Cfff: ON_CLICK co%+2,Cfff
i%=i%+1: EDIT i%: PARENT i%,fm%: TOP i%,TOP(i%-3)+20: LEFT i%,0: WIDTH i%,110
        TEXT i%,"Arial": np% = i%: ON_CLICK np%,Cfff: ' Police de caractères
i%=i%+1: LIST i%: PARENT i%,fm%: TOP i%,44: LEFT i%,0: WIDTH i%,WIDTH_CLIENT(fm%): ' Exemple
        HEIGHT i%,HEIGHT(fm%)-100: la% = i%
        FONT_NAME la%,TEXT$(np%): FONT_SIZE la%,12: ' Taille de départ
        ITEM_ADD la%,"Voyez le brick géant": ITEM_ADD la%,"  que j'examine"
        ITEM_ADD la%,"    près du wharf": ITEM_ADD la%,"0123456789"
fl%=i%+1: ' Form liste des polices
  FORM fl%: HIDE fl%: BORDER_HIDE fl%: TOP fl%,TOP(fm%)+TOP(np%)+50: LEFT fl%,LEFT(fm%)+10
        WIDTH fl%,150: HEIGHT fl%,600
i%=fl%+1: LIST i%: PARENT i%,fl%: FULL_SPACE i%: ' liste des polices
        lp%=i%: ON_CLICK lp%,Cfff: ' choix d'une police de la liste
i%=i%+1: SPIN i%: PARENT i%,fm%: TOP i%,TOP(np%): LEFT i%,LEFT(np%)+WIDTH(np%)+1: sp% = i%
        WIDTH i%,42: POSITION i%,12: ON_CHANGE i%,Afff: ' Taille
        MIN sp%,1: MAX sp%,255
i%=i%+1: CHECK i%: PARENT i%,fm%: TOP i%,0: LEFT i%,LEFT(sp%)+WIDTH(sp%)+15: ck%=i%
        WIDTH i%,25: CAPTION i%,"G": ON_CLICK i%,Afff: ' Gras
i%=i%+1: CHECK i%: PARENT i%,fm%: TOP i%,TOP(i%-1): LEFT i%,LEFT(i%-1)+40
        WIDTH i%,25: CAPTION i%,"I": ON_CLICK i%,Afff: ' Italiques
i%=i%+1: CHECK i%: PARENT i%,fm%: TOP i%,TOP(i%-1): WIDTH i%,23: LEFT i%,LEFT(i%-1)+40
        CAPTION i%,"S": ON_CLICK i%,Afff: ' Souligné
i%=i%+1: PICTURE i%: PARENT i%,fm%: TOP i%,TOP(i%-1)+17: LEFT i%,LEFT(sp%)+45
        j% = 25: WIDTH i%,125: HEIGHT i%,j%: cl%=i%: ON_CLICK cl%,Cfff: ' Couleur police
        dt% = NUMBER_2D_TARGET: 2D_TARGET_IS i%
        2D_FILL_COLOR 0,0,0: 2D_RECTANGLE 0,0,18,j%: ' couleur choisie
        2D_RECTANGLE 21,0,50,j%/2+1: ' 1ère rangée, noir
        2D_FILL_COLOR 255,0,0: 2D_RECTANGLE 51,0,75,j%/2+1: ' rouge
        2D_FILL_COLOR 0,255,0: 2D_RECTANGLE 76,0,100,j%/2+1: ' vert
        2D_FILL_COLOR 0,0,255: 2D_RECTANGLE 101,0,125,j%/2+1: ' bleu
        2D_FILL_COLOR 255,255,255: 2D_RECTANGLE 21,j%/2,50,j%: ' 2ème rangée, blanc
        2D_FILL_COLOR 220,220,0: 2D_RECTANGLE 51,j%/2,75,j%: ' jaune
        2D_FILL_COLOR 255,0,255: 2D_RECTANGLE 76,j%/2,100,j%: ' magenta
        2D_FILL_COLOR 0,255,255: 2D_RECTANGLE 101,j%/2,125,j%: ' cyan
i%=i%+1: BUTTON i%: PARENT i%,fm%: HEIGHT i%,18: TOP i%,HEIGHT_CLIENT(fm%)-18
        LEFT i%,5: WIDTH i%,120: CAPTION i%,"Voir tous les caractères": ON_CLICK i%,Vfff
i%=i%+1: BUTTON i%: PARENT i%,fm%: HEIGHT i%,18: TOP i%,HEIGHT_CLIENT(fm%)-18
        LEFT i%,WIDTH(fm%)-100: CAPTION i%,"OK": ON_CLICK i%,Ffff
fp%=i%+1: wg% = 20
  FORM fp%: HIDE fp%: BORDER_HIDE fp%: TOP fp%,TOP(fl%): LEFT fp%,LEFT(fm%)
          WIDTH fp%,(wg%+2)*17-3: HEIGHT fp%,(wg%+2)*17+25: COLOR fp%,255,128,0
i%=fp%+1: GRID i%: PARENT i%,fp%: TOP i%,5: LEFT i%,5: WIDTH i%,WIDTH(fp%)
        HEIGHT i%,WIDTH(i%): GRID_ROW i%,17: GRID_COLUMN i%,17
        GRID_COLUMN_WIDTH i%,wg%: GRID_ROW_HEIGHT i%,wg%
        FONT_NAME i%,"Lucida Console": FONT_SIZE i%,12
        FOR j% = 0 TO 15
            GRID_WRITE i%,1,j%+2,HEX$(j%): GRID_WRITE i%,j%+2,1,HEX$(j%)
        NEXT j%
i%=i%+1: BUTTON i%: PARENT i%,fp%: TOP i%,HEIGHT(fp%)-26: LEFT i%,WIDTH(fp%)/2-40
        CAPTION i%,"OK": FONT_SIZE i%,14: FONT_BOLD i%: ON_CLICK i%,Vfff

  WHILE expol% = 0: PAUSE 200: END_WHILE: ' <=== Attente =====
  ' Clic sur 'OK' (validation des paramètres choisis et quitter la sub)
  FONT_NAME objet%,TEXT$(np%): FONT_SIZE objet%,POSITION(sp%)
  FONT_BOLD_OFF objet%: FONT_ITALIC_OFF objet%: FONT_UNDERLINE_OFF objet%
  IF CHECKED(ck%) = 1 THEN FONT_BOLD objet%
  IF CHECKED(ck%+1) = 1 THEN FONT_ITALIC objet%
  IF CHECKED(ck%+2) = 1 THEN FONT_UNDERLINE objet%
  FONT_COLOR objet%,r%,g%,b%
  2D_TARGET_IS dt%: DELETE fl%: DELETE fp%: DELETE fm%: EXIT_SUB
' ---------------------------
Afff:
  CLEAR la%: FONT_SIZE la%,POSITION(sp%): ' Aperçu du résultat
  FONT_BOLD_OFF la%: FONT_ITALIC_OFF la%: FONT_UNDERLINE_OFF la%
  IF CHECKED(ck%) = 1 THEN FONT_BOLD la%
  IF CHECKED(ck%+1) = 1 THEN FONT_ITALIC la%
  IF CHECKED(ck%+2) = 1 THEN FONT_UNDERLINE la%
  ITEM_ADD la%,"Voyez le brick géant": ITEM_ADD la%,"  que j'examine"
  ITEM_ADD la%,"    près du wharf": ITEM_ADD la%,"0123456789"
RETURN
' ----------------------------
Cfff:
  i% = NUMBER_CLICK
  IF i% = (co%+1) OR i% = (co%+2) OR i% = np%: ' clic nom de police (-> choix police)
    CLEAR lp%: FONT_NAMES_LOAD lp%
    FOR j% = COUNT(lp%) TO 1 STEP -1: ' Élimination de polices inutiles
        IF LEFT$(ITEM_READ$(lp%,j%),1)="@" THEN ITEM_DELETE lp%,j%
    NEXT j%
    IF CHECKED(fm%+3) = 1: ' seulement les polices à pas fixe
        FOR j% = COUNT(lp%) TO 1 STEP -1
            FONT_NAME cl%,ITEM_READ$(lp%,j%)
            IF TEXT_WIDTH("iiiii",cl%) <> TEXT_WIDTH("mmmmm",cl%)
                ITEM_DELETE lp%,j%
            END_IF
        NEXT j%
    END_IF
    SHOW fl%: TO_FOREGROUND fl%
  ELSE
    IF i% = lp%: ' clic une police de la liste
        TEXT np%,ITEM_INDEX$(lp%): FONT_NAME la%,TEXT$(np%): HIDE fl%
    ELSE
        IF i% = cl%: ' clic une couleur
            xs%=MOUSE_X_LEFT_DOWN(cl%): ys%=MOUSE_Y_LEFT_DOWN(cl%)
            r%=COLOR_PIXEL_RED(cl%,xs%,ys%): g%=COLOR_PIXEL_GREEN(cl%,xs%,ys%)
            b%=COLOR_PIXEL_BLUE(cl%,xs%,ys%)
            2D_FILL_COLOR r%,g%,b%: 2D_RECTANGLE 0,0,18,25: FONT_COLOR la%,r%,g%,b%
        END_IF
    END_IF
  END_IF
RETURN
' ---------------------------------
Vfff:
  i% = NUMBER_CLICK
  IF i% = fp%+2
      HIDE fp%
  ELSE
      FONT_NAME fp%+1,TEXT$(np%)
      FOR j% = 0 TO 15
          FOR i% = 0 TO 15
              GRID_WRITE fp%+1,j%+2,i%+2,CHR$(16*j%+i%)
          NEXT i%
      NEXT j%
  SHOW fp%
  END_IF
RETURN
' ---------------------------------
Ffff:
  expol% = 1: ' Clic sur 'OK', validation des choix
RETURN
END_SUB
' ==============================================================================

PS 23h00 Modifié suite aux remarques judicieuses de papydall et Jean Claude
28/10 petites modifs esthétiques
23h20 ajout de la possibilité de visualiser l'ensemble des caractères de la police courante (choisie)


Dernière édition par JL35 le Dim 29 Oct 2017 - 0:19, édité 4 fois
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5594
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Choix d'une police de caractères   Jeu 26 Oct 2017 - 17:36

Salut vieux !
Tu as bien fait d’essayer de meubler le silence qui règne sur le Forum.
De ma part j’apporte aussi mon truc pour améliorer l’ameublement.
Mais avant et pour voir de quoi je parle :
Lance le programme : la taille (par défaut) indiquée dans le SPIN est 12
Augmente-la : 13,14,15, etc
Tout fonctionne à merveille ! Bravo.
Maintenant, diminue la taille 14,13,12,11, etc et observe l’affichage.
On ne peut pas dire que c’est beau comme meuble !

Voici ce que Papydall propose :

Code:

' ---------------------------
Afff:
'  clear la% : ' <------------------------------------------------------ Papydall

  FONT_SIZE la%,POSITION(sp%)
  FONT_BOLD_OFF la%: FONT_ITALIC_OFF la%: FONT_UNDERLINE_OFF la%
  IF CHECKED(ck%) = 1 THEN FONT_BOLD la%
  IF CHECKED(ck%+1) = 1 THEN FONT_ITALIC la%
  IF CHECKED(ck%+2) = 1 THEN FONT_UNDERLINE la%
  ' ==================================================================  Papydall
  ITEM_ADD la%,"Voyez le brick géant": ITEM_ADD la%,"  que j'examine"
  ITEM_ADD la%,"    près du wharf": ITEM_ADD la%,"0123456789"
  ' ==================================================================  Papydall
RETURN
' ----------------------------



Bon ce n'est pas grand chose, mais je ne vais pas rater une belle occasion de sortir du silence tongue
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
JL35



Nombre de messages : 5992
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Choix d'une police de caractères   Jeu 26 Oct 2017 - 18:00

Bonjour mon jeune ami papydall,

Comme tu dis ce n'est pas grand chose, mais est-ce qu'il ne manquerait pas quelque chose à ton code ???
J'ai là un sous-programme Afff qui n'est appelé de nulle part et qui se sent bien seul... d'ailleurs il refuse obstinément de faire quoi que ce soit... scratch

Bon j'ai du monde qui arrive, désolé pour la suite, je verrai plus tard...
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5594
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Choix d'une police de caractères   Jeu 26 Oct 2017 - 19:51

JL35 a écrit:
Comme tu dis ce n'est pas grand chose, mais est-ce qu'il ne manquerait pas quelque chose à ton code ???
J'ai là un sous-programme Afff qui n'est appelé de nulle part et qui se sent bien seul... d'ailleurs il refuse obstinément de faire quoi que ce soit...  

Hé ! Ce n’est pas mon code.
C’est un sous-programme du tien auquel j’ai apporté ma modification.
Remplace dans ton code le sous-programme du même nom avec celui que je propose et il obéira gentiment de faire son boulot.

Occupe-toi de tes invités ; le reste peut attendre.

A propos, je ne suis pas si jeune que ça ; tu peux m’appeler « le vieux » farao
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Jean Claude

avatar

Nombre de messages : 5062
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Choix d'une police de caractères   Jeu 26 Oct 2017 - 20:57

Salut les anciens Very Happy

@Papydall,
C'est vrai que pour meubler une pièce, il est préférable de la vider avant !  Razz

clear la% au sous-programme Afff: ne suffit pas, car ensuite on n'a plus rien dans le mémo.
Alors, j'ai ajouter en paramètre le texte à formater pour le rétablir à chaque changement.

Code:
dim a$
PICTURE 1: FULL_SPACE 1
PRINT_TARGET_IS 1: PRINT "Voyez Le Brick Géant"
a$="Que J'Examine Près Du Wharf"
Police(a$,1,100,75)
PRINT "Que J'Examine Près Du Wharf"
END
' ==============================================================================
SUB Police(texte$,objet%,x%,y%)
  ' Choix police, taille, enrichissements, couleur de texte sur l'objet objet%
  ' (positionnement de la fenêtre de choix en x%,y% de l'écran)
  DIM_LOCAL fm%,co%,fl%,i%,j%,r%,g%,b%,xs%,ys%,expol%,dt%,cl%,np%,lp%,la%,sp%,ck%
  IF LABEL("Afff") = 0 THEN LABEL Afff
  IF LABEL("Cfff") = 0 THEN LABEL Cfff
  IF LABEL("Ffff") = 0 THEN LABEL Ffff
fm%=950
  FORM fm%: TOP fm%,y%: LEFT fm%,y%: WIDTH fm%,300: HEIGHT fm%,240: BORDER_SMALL fm%
          FONT_BOLD i%: FONT_NAME i%,"Arial": COLOR fm%,180,255,255
          ON_CLOSE fm%,Ffff
          CAPTION fm%,"POLICE,  TAILLE,  COULEUR,  ENRICHISS."
i%=fm%+1: CONTAINER_OPTION i%: PARENT i%,fm%: HEIGHT i%,16: CAPTION i%,"Polices:": co%=i%
i%=i%+1: OPTION i%: PARENT i%,i%-1: TOP i%,0: LEFT i%,45: CAPTION i%,"Toutes"
i%=i%+1: OPTION i%: PARENT i%,i%-2: TOP i%,TOP(i%-1): LEFT i%,100: CAPTION i%,"Fixes"
         MARK_ON co%+1: ON_CLICK co%+1,Cfff: ON_CLICK co%+2,Cfff
i%=i%+1: EDIT i%: PARENT i%,fm%: TOP i%,TOP(i%-3)+17: LEFT i%,0: WIDTH i%,110
         TEXT i%,"Arial": np% = i%: ON_CLICK np%,Cfff
i%=i%+1: LIST i%: PARENT i%,fm%: TOP i%,40: LEFT i%,0: WIDTH i%,WIDTH(fm%)-16: ' exemple
         HEIGHT i%,HEIGHT(fm%)-100: la% = i%
         FONT_NAME la%,"Arial": FONT_SIZE la%,12
         ITEM_ADD la%,"Voyez le brick géant": ITEM_ADD la%,"  que j'examine"
         ITEM_ADD la%,"    près du wharf": ITEM_ADD la%,"0123456789"
fl%=i%+1: ' liste des polices
  FORM fl%: HIDE fl%: BORDER_HIDE fl%: TOP fl%,TOP(fm%)+TOP(np%)+50: LEFT fl%,LEFT(fm%)+10
         WIDTH fl%,150: HEIGHT fl%,500
i%=fl%+1: LIST i%: PARENT i%,fl%: FULL_SPACE i%: ' liste des polices
         lp%=i%: ON_CLICK lp%,Cfff
i%=i%+1: SPIN i%: PARENT i%,fm%: TOP i%,TOP(np%): LEFT i%,WIDTH(np%)+5: sp% = i%
         WIDTH i%,40: POSITION i%,12: ON_CHANGE i%,Afff
         MIN sp%,1: MAX sp%,255
i%=i%+1: CHECK i%: PARENT i%,fm%: TOP i%,0: LEFT i%,LEFT(i%-1)+WIDTH(i%-1)+2: ck%=i%
         WIDTH i%,25: CAPTION i%,"G": ON_CLICK i%,Afff
i%=i%+1: CHECK i%: PARENT i%,fm%: TOP i%,TOP(i%-1): LEFT i%,LEFT(i%-1)+25
         WIDTH i%,25: CAPTION i%,"I": ON_CLICK i%,Afff
i%=i%+1: CHECK i%: PARENT i%,fm%: TOP i%,TOP(i%-1): WIDTH i%,23: LEFT i%,LEFT(i%-1)+25
         CAPTION i%,"S": ON_CLICK i%,Afff
i%=i%+1: PICTURE i%: PARENT i%,fm%: TOP i%,TOP(i%-1)+16: LEFT i%,LEFT(i%-3)-2
         j% = 22: WIDTH i%,77: HEIGHT i%,j%: cl%=i%: ON_CLICK cl%,Cfff
         dt% = NUMBER_2D_TARGET: 2D_TARGET_IS i%
         2D_FILL_COLOR 0,0,0: 2D_RECTANGLE 0,0,18,j%: ' couleur choisie
         2D_RECTANGLE 21,0,34,j%/2+1: ' 1ère rangée, noir
         2D_FILL_COLOR 255,0,0: 2D_RECTANGLE 36,0,49,j%/2+1: ' rouge
         2D_FILL_COLOR 0,255,0: 2D_RECTANGLE 50,0,63,j%/2+1: ' vert
         2D_FILL_COLOR 0,0,255: 2D_RECTANGLE 64,0,77,j%/2+1: ' bleu
         2D_FILL_COLOR 255,255,255: 2D_RECTANGLE 21,j%/2,34,j%: ' 2ème rangée, blanc
         2D_FILL_COLOR 220,220,0: 2D_RECTANGLE 36,j%/2,49,j%: ' jaune
         2D_FILL_COLOR 255,0,255: 2D_RECTANGLE 50,j%/2,63,j%: ' magenta
         2D_FILL_COLOR 0,255,255: 2D_RECTANGLE 64,j%/2,77,j%: ' cyan
i%=i%+1: BUTTON i%: PARENT i%,fm%: HEIGHT i%,20: TOP i%,HEIGHT(fm%)-55
         LEFT i%,WIDTH(fm%)/2+32: CAPTION i%,"OK": ON_CLICK i%,Ffff
  WHILE expol% = 0: PAUSE 200: END_WHILE
  FONT_NAME objet%,TEXT$(np%): FONT_SIZE objet%,POSITION(sp%)
  FONT_BOLD_OFF objet%: FONT_ITALIC_OFF objet%: FONT_UNDERLINE_OFF objet%
  IF CHECKED(ck%) = 1 THEN FONT_BOLD objet%
  IF CHECKED(ck%+1) = 1 THEN FONT_ITALIC objet%
  IF CHECKED(ck%+2) = 1 THEN FONT_UNDERLINE objet%
  FONT_COLOR objet%,r%,g%,b%
  2D_TARGET_IS dt%: DELETE fl%: DELETE fm%: EXIT_SUB
' ---------------------------
Afff:
  clear la%
  FONT_SIZE la%,POSITION(sp%)
  FONT_BOLD_OFF la%: FONT_ITALIC_OFF la%: FONT_UNDERLINE_OFF la%
  IF CHECKED(ck%) = 1 THEN FONT_BOLD la%
  IF CHECKED(ck%+1) = 1 THEN FONT_ITALIC la%
  IF CHECKED(ck%+2) = 1 THEN FONT_UNDERLINE la%
  item_add la%,texte$
RETURN
' ----------------------------
Cfff:
  clear la% : item_add la%,texte$
  i% = NUMBER_CLICK
  IF i% = (co%+1) OR i% = (co%+2) OR i% = np%: ' clic nom de police (-> choix police)
    CLEAR lp%: FONT_NAMES_LOAD lp%
    FOR j% = COUNT(lp%) TO 1 STEP -1
        IF LEFT$(ITEM_READ$(lp%,j%),1)="@" THEN ITEM_DELETE lp%,j%
    NEXT j%
    IF CHECKED(fm%+3) = 1: ' seulement les polices à pas fixe
        FOR j% = COUNT(lp%) TO 1 STEP -1
            FONT_NAME cl%,ITEM_READ$(lp%,j%)
            IF TEXT_WIDTH("iiiii",cl%) <> TEXT_WIDTH("mmmmm",cl%)
                ITEM_DELETE lp%,j%
            END_IF
        NEXT j%
    END_IF
    SHOW fl%: TO_FOREGROUND fl%
  ELSE
    IF i% = lp%: ' clic une police de la liste
        TEXT np%,ITEM_INDEX$(lp%): FONT_NAME la%,TEXT$(np%): HIDE fl%
    ELSE
        IF i% = cl%: ' clic une couleur
            xs%=MOUSE_X_LEFT_DOWN(cl%): ys%=MOUSE_Y_LEFT_DOWN(cl%)
            r%=COLOR_PIXEL_RED(cl%,xs%,ys%): g%=COLOR_PIXEL_GREEN(cl%,xs%,ys%)
            b%=COLOR_PIXEL_BLUE(cl%,xs%,ys%)
            2D_FILL_COLOR r%,g%,b%: 2D_RECTANGLE 0,0,18,22: FONT_COLOR la%,r%,g%,b%
        END_IF
    END_IF
  END_IF
RETURN
' ---------------------------------
Ffff:
  expol% = 1
RETURN
END_SUB
' ==============================================================================

@JL35 j'ai agrandi form 0 car sous w8.1 c'est trop petit, les barres de défilements masque une partie du container.

Cette Sub est très pratique pour choisir  une police et adapter ses attributs à un texte, elle me rappelle celle de Bignono.

Bonne soirée à vous deux.


A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5594
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Choix d'une police de caractères   Jeu 26 Oct 2017 - 21:34

Jen Claude a écrit:
clear la% au sous-programme Afff: ne suffit pas, car ensuite on n'a plus rien dans le mémo.

Bien sûr que ça ne suffit pas.
Dans ma modification, j’ai ajouté aussi ce qu’il fallait pour que ça suffise.
Revoir mon code ci-haut.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Jean Claude

avatar

Nombre de messages : 5062
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Choix d'une police de caractères   Jeu 26 Oct 2017 - 21:44

Effectivement je n'avais pas vu !

Mais il reste le sous-programme Cfff:

Là aussi il faut intervenir car si on change de police, le problème reste.

Code:
Cfff:
clear la% : item_add la%,texte$

Et tout va bien.

A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
JL35



Nombre de messages : 5992
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Choix d'une police de caractères   Ven 27 Oct 2017 - 0:05

Merci les gars pour vos remarques frappées au coin du bon sens.), j'ai corrigé là-haut.

papydall
Citation :
A propos, je ne suis pas si jeune que ça ; tu peux m’appeler « le vieux »
Tout est relatif ! moi tu peux m'appeler "l'ancêtre" !

Pour la petite histoire:
'Voyez le brick géant que j'examine près du wharf'
'Portez ce vieux whisky au juge blond qui fume'
'The quick brown fox jumps over the lazy dog's back'

sont des phrases contenant toutes les lettres de l'alphabet qu'on utilisait en télégraphie (internationale pour la dernière) pour vérifier la qualité des transmissions.
En code Baudot à 5 moments (= 5 bits) des téléscripteurs, c'était des séries de lettres 'ryryry...' dont le codage utilise les 5 positions.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5594
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Choix d'une police de caractères   Ven 27 Oct 2017 - 1:54

Moi, je n’ai connu que l’alphabet international qui est toujours utilisé en Météorologie et en Aéronautique.

Signalisation Phonétique Internationale:
 


=====================================================

Papa Alpha Romeo Delta Oscar November
Papa Oscar Uniform Romeo
Lima Echo
Hotel Oscar Romeo Sierra
Sierra Uniform Juliett Echo Tango

====================================================
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
JL35



Nombre de messages : 5992
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Choix d'une police de caractères   Ven 27 Oct 2017 - 11:38

Celui-là je l'ai utilisé aussi, autrefois, sans doute à l'armée.
Il y avait aussi l'équivalent français avec des prénoms:
Anatole, Berthe, ... et je ne me souviens plus de la suite... c'est loin tout ça...
(tiens, si ça intéresse, c'est là: http://j.poitou.free.fr/pro/html/tkn/alpha-tel.html )

Et pour le HS, pardon JL35 Smile
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Contenu sponsorisé




MessageSujet: Re: Choix d'une police de caractères   

Revenir en haut Aller en bas
 
Choix d'une police de caractères
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» recherche d'une police de caractère
» [résolu]Horloge et compteur digital
» Taille de la police de caractères dans PANORAMIC EDITOR
» Pb pour le choix de la voie
» Vous avez demandé la POLICE, ne quittez pas...

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Vos sources, vos utilitaires à partager-
Sauter vers: