FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» Button_picture
par pascal10000 Aujourd'hui à 11:41

» Pourquoi le compilateur stagne
par Minibug Aujourd'hui à 11:09

» 4 (en analyse): SYNEDIT_TARGET_IS_OBJECT devient inactif
par Jack Aujourd'hui à 10:09

» 3 (en analyse): Mauvaise interprétation du string "THEN"
par Jack Aujourd'hui à 10:03

» KGF.dll - demandes ou suggestions de modifications ou ajouts
par Marc Aujourd'hui à 10:00

» KGF_dll - nouvelles versions
par pascal10000 Hier à 17:27

» Mah-Jong européen new-look
par Minibug Mar 12 Déc 2017 - 22:31

» track_bar circulaire
par Klaus Mar 12 Déc 2017 - 13:54

» API Windows
par Klaus Mar 12 Déc 2017 - 3:21

» Cartes de voeux, menus, etc.
par JL35 Lun 11 Déc 2017 - 17:48

» a l'aide klaus
par Minibug Lun 11 Déc 2017 - 11:42

» bug SYNEDIT_TARGET_IS_OBJECT
par Jack Lun 11 Déc 2017 - 0:16

» Jukebox : Serge Reggiani
par papydall Sam 9 Déc 2017 - 5:58

» Ecouter la radio fm sur votre pc
par pascal10000 Sam 9 Déc 2017 - 3:42

» anomalie
par Klaus Sam 9 Déc 2017 - 3:21

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Décembre 2017
LunMarMerJeuVenSamDim
    123
45678910
11121314151617
18192021222324
25262728293031
CalendrierCalendrier

Partagez | 
 

 Demande urgente en maths.

Voir le sujet précédent Voir le sujet suivant Aller en bas 
AuteurMessage
Pedro Alvarez

avatar

Nombre de messages : 882
Date d'inscription : 19/01/2014

MessageSujet: Demande urgente en maths.   Lun 23 Oct 2017 - 16:57

Bonjour à tous.

L'un d'entre vous pourrait-il m'aider à factoriser les 2 expressions suivantes:

98 - 50x² -3(5x+7)²

et

98 - 50x² + (4x+9)(15x+21)

Il s'agit de problème de maths posés à un élève de seconde.

Merci d'avance.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Pedro Alvarez

avatar

Nombre de messages : 882
Date d'inscription : 19/01/2014

MessageSujet: Demande urgente en maths   Lun 23 Oct 2017 - 17:33

Bonjour.

Je viens de trouver la solution du 1er problème:

98 - 50x² peut s'écrire:  -2(25x²-49)

Soit:

-2(5x+7)(5x-7)

De là découle la solution du 2è problème.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Froggy One

avatar

Nombre de messages : 395
Date d'inscription : 06/01/2012

MessageSujet: Sujet: Demande urgente en maths   Lun 23 Oct 2017 - 18:32

Il y a fort longtemps que je n'ai pas fait cette gym mentale mais... d'après ton premier exercice, on a

-2(5x+7)(5x-7)+3(4x+9)(5x+7)

donc

(5x+7)(2x+41)

J'ai bon ?
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://gaeldwest.wordpress.com
mindstorm

avatar

Nombre de messages : 542
Age : 48
Localisation : charente
Date d'inscription : 13/02/2013

MessageSujet: Re: Demande urgente en maths.   Lun 23 Oct 2017 - 19:35

bonjours a tous
je crois qu'il y a une épidémie de maths sur le forum...
moi qui venais pour oublier les maths de mon fils...
je suis pris en tenaille
affraid
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 5086
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Demande urgente en maths.   Lun 23 Oct 2017 - 21:18

Mindstorm a écrit:
je crois qu'il y a une épidémie de maths sur le forum...

Oui effectivement et c'est dû à l'intervention de Braveen Very Happy

Les maths ne sont peut-être pas hors sujet, car je pense personnellement qu'elles sont plusqu'utile à la programmation dans certain cas (en particulier, pour les dessins en 2D).

Je ne vais pas répondre à la question de Pédro, je n'ai pas les connaissances suffisantes, (Papydall, Jean Debort et d'autres les ont certainement).
Cela me ramène à mes années "collège" (pratiquement 50 ans en arrière) et je me rappelle les avoir aimés ces satanés maths Very Happy  .
Malheureusement il ne m'en reste pas grand chose, mais suffisamment pour programmer et c'est l’essentiel.

A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
JL35



Nombre de messages : 6018
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Demande urgente en maths.   Lun 23 Oct 2017 - 21:21

Ceci dit mindstorm a raison, je ne vois pas où est le rapport entre la question initiale et Panoramic scratch
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Froggy One

avatar

Nombre de messages : 395
Date d'inscription : 06/01/2012

MessageSujet: Re: Demande urgente en maths.   Lun 23 Oct 2017 - 22:11

C.Q.F.D

Une démonstration par l'absurde ?
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://gaeldwest.wordpress.com
JL35



Nombre de messages : 6018
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Demande urgente en maths.   Lun 23 Oct 2017 - 22:26

Je ne sais pas qui est l'absurde, alors pour sa démonstration...
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5613
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Demande urgente en maths.   Mar 24 Oct 2017 - 0:27

‘Demande urgente en maths’.
Tel fut le titre du post !
Je l’ai vu et je me suis précipité pour venir en urgence.
Mais la question ne m’intéressait pas : faire des exercices de mathématiques élémentaires sur un forum de discussion sur le langage Panoramic, je ne trouve pas ça si urgent que ça ! Ce n’est pas le bon Forum tout simplement.
C’est pourquoi je n’ai pas réagis sur le coup.
Mais vu la tournure de la discussion, j’aime bien apporter mon point vue.

Jean Claude a écrit:
Les maths ne sont peut-être pas hors sujet, car je pense personnellement qu'elles sont plus qu'utile à la programmation dans certain cas (en particulier, pour les dessins en 2D).

Je dirais même plus : les maths sont indispensables partout !
Mais nous sommes sur un forum de discussion sur le langage Panoramic et non une autre discipline.
Je répondrai (dans la limite de mes connaissances) à toute question de maths, pourvue qu’elle soit liée à Panoramic en particulier, ou à l’algorithmique en général.
S’il s’avèrerait utile, je peux répondre à  quelques questions de maths servant à la programmation tels que :
• Les coordonnées cartésiennes / polaires / paramétriques
• Les matrices de transformations géométriques du plan
• Les équations des certaines courbes classiques ou exotiques ou simplement esthétiques
• La construction de certaines figures géométriques  telles que les polygones réguliers, etc.
• Etc.    


A condition que ces questions soient directement liées à la programmation en Panoramic, je me ferai un plaisir à partager mon (maigre) savoir.

A bon entendeur, salut !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Froggy One

avatar

Nombre de messages : 395
Date d'inscription : 06/01/2012

MessageSujet: Re: Demande urgente en maths.   Mar 24 Oct 2017 - 9:50

Message bien reçu !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://gaeldwest.wordpress.com
mindstorm

avatar

Nombre de messages : 542
Age : 48
Localisation : charente
Date d'inscription : 13/02/2013

MessageSujet: Re: Demande urgente en maths.   Mar 24 Oct 2017 - 20:20

ou la la
loin de moi l'idée d'éveiller une telle tornade Very Happy
et c'est, comme de bien entendu, Papydall qui résume le mieux la situation " les maths ne sont pas hors sujet" et il le prouve continuellement.
J'exprimais juste mon indigestion actuel pour les maths, du à mon fils en 1°S qui me bombarde de questions sur les équations du second degré.
Aujourd'hui encore, j'étais CANONISE ( les matheux comprendront)


Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5613
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Demande urgente en maths.   Mer 25 Oct 2017 - 1:31

mindstorm a écrit:
J'exprimais juste mon indigestion actuel pour les maths, du à mon fils en 1°S qui me bombarde de questions sur les équations du second degré.


Quand j’étais en 1ère année Panoramic, j’ai posté un code pour résoudre de telles équations.
C’était sur cette page

Peu après, j’ai posté un autre code pour résoudre les équations du troisième degré, mais ça n’a suscité aucun commentaire !
C’était sur cette autre page .

Je viens de revoir le code et j’ai constaté qu’il comportait une minibug   Wink (Salut Laurent. Où es-tu ?).
Comme le post a été verrouillé, je rappelle ici les codes.

Code:

' ******************************************************************************

'    2DEGRE.BAS par Papydall

' Résolution de l'équation du second dégré ax² + bx + c = 0

' ******************************************************************************

' D'après le théorème fondamental de l'algèbre des polynômes : tout polynôme de
' dégré N admet exactement N solutions (on dit aussi racines ou zéros). Ces
' racines sont réelles ou complexes, simples ou multiples et si elles sont
' complexes, elles sont conjuguées deux-à-deux.
' Ce programme permet de résoudre un polynôme du second dégré

' Le trinôme du second dégré admet donc deux racines : soit réelles simples ou
' double , soit complexes conjuguées.

' RAPPEL : un nombre complexe s'écrit sous forme z = x + i*y , avec x et y réels
' et i nombre imaginaire dont le carré vaut -1 (i² = -1).
' x s'appelle partie réelle du nombre complexe z ; y s'appelle partie imaginaire
' du nombre complexe z.
' Si y = 0 , le nombre est réel. Si x = 0 , le nombre est imaginaire pur.
' Deux nombres complexes conjugués sont deux nombres complexes dont leurs
' parties imaginaires sont de signes contraires.

' ******************************************************************************

init()    : ' appel de la procédure d'initialisation
demarrer() : ' appel de la procédure de demarrage
end  : ' Cette instruction est INDISPENSABLE ici pour que le programme puisse s'arrêter
      ' et ne tente pas d'exécuter la ligne suivante qui provoquerait une erreur
' ******************************************************************************

' Déclaration des étiquettes "label" , des variables globales, des objets etc..
SUB init()
    label suite    : ' sous-programme pour faire un autre calcul
    label quit    : ' sous-programme pour quitter l'application
    dim a,b,c      : ' les coefficients du trinôme
    dim x1,x2      : ' les racines réelles
    dim re,im      : ' Les racines complexes
    dim complexe%  : ' flag pour indiquer si les racines sont complexes (=1) ou réelles (=0)
    color 0,0,0,0  : font_color 0,0,255,0 : ' fond noir, texte vert
    font_size 0,12 : font_bold 0 : ' Taille de la fonte 12, écriture en gras
    caption 0,"Résolution de l'équation du second dégré : AX² + BX + C = 0"
    ' création de 2 boutons : l'un pour poursuivre, l'autre pour quitter
    button 1 : top 1,250 : left 1,50  : width 1, 100
    on_click 1,suite : ' si on clique sur ce bouton, on se branche sur le sous-programme suite
    button 2 : top 2,250 : left 2,300 : width 2, 80
    on_click 2,quit : ' si on clique sur ce bouton, on se branche sur le sous-programme quit
    caption 1,"Autre calcul" : caption 2,"Quitter" : ' textes des 2 boutons
END_SUB
' ******************************************************************************
' Procédure de saisie des coefficients a,b,c
SUB saisie()
    DIM_LOCAL r$ : ' texte de la saisie
    ' Saisie du coefficient A
    ' Cette saisie se fait par 2 boucles REPEAT :
    repeat      : ' Cette boucle assure que le coefficient soit différent de 0
        repeat  : ' Cette boucle assure que le coefficient soit numérique
              r$ = message_input$("Entrer le paramètre A (différent de zéro)","A = ","")
        until numeric(r$) = 1 : ' Si on est ici, c'est qu'on a saisie bien une valeur numérique
    until val(r$) <> 0 : ' Si on est ici, c'est que la valeur saisie est bien différente de 0
    A = val(r$)  : ' On récupère la valeur saisie dans la variable A
    ' Saisie du coefficient B
    ' Cette fois, il n'est pas nécessaire que la valeur soit différente de 0
    ' mais seulement qu'elle soit numérique
    repeat
      r$ = message_input$("Entrer le paramètre B","B = ","")
    until numeric(r$) = 1
    B = val(r$)
    ' Saisie du coefficient C
    ' identique à la saisie du coefficient B
    repeat
      r$ = message_input$("Entrer le paramètre C","C = ","")
    until numeric(r$) = 1
    c = val(r$)
END_SUB
' ******************************************************************************
' Procédure de calcul de la solution
SUB resol_2degre(AX2,BX,C)
    DIM_LOCAL p,q,delta : ' variables locales utilisées pour le calcul
      p = BX/AX2 : q = C/AX2 : delta = (p/2)*(p/2)-q    
      if delta < 0          : ' les racines sont complexes conjuguées
          complexe% = 1      : ' on met le flag à 1
          delta = abs(delta)  : ' On prend la valeur absolue pour le calcul
          re = 0-(p/2) : im = sqr(delta) : ' parties réelle et imaginaire de la solution
      else                  : ' les racine sont réelles
          complexe% = 0
          x1 = 0-(p/2) + sqr(delta) : x2 = 0-(p/2) - sqr(delta) : ' calcul des 2 racines
      end_if
END_SUB
' ******************************************************************************
' Cette procédure fait appel à la procédure de saisie et à celle de calcul
SUB demarrer()
    dim_local a$,b$,c$ : ' Pour un affichage correct
    cls  : ' pour travailler sur un écran propre
    hide 1 : hide 2 : ' avant le calcul, on cache les 2 boutons
    saisie() : ' Appel de la procédure de saisie des coefficients A,B,C
    resol_2degre(a,b,c) : ' Appel de la procédure de la recherche de la solution
    ' On affiche le resultat de notre effort !!!
    if a = 1  then a$ = "x² " : else : a$ = str$(a)+"x² " : ' Pour ne pas afficher 1x²
    if a = -1 then a$ = "-x²" : ' pour ne pas afficher -1x²
    if b = 1  then b$ = "+x " : else : b$ = str$(b)+"x " : ' Pour ne pas afficher 1x
    if b = -1 then b$ = "-x " : ' pour ne pas afficher -1x
    if b > 1  then b$ = "+"+str$(b)+"x "
    if b = 0  then b$ = ""
    if c = 0  then c$ = " = 0" : else : c$ = str$(c)+" = 0 :"
    if c > 0  then c$ = "+"+c$
    print_locate 50,20  : ' on positionne le curseur pour l'affichage
    print "La solution de : "; a$+b$+c$
    if complexe% = 0  : ' Les racines sont-elles réelles ?
      ' oui, les racines sont réelles
      print_locate 50,50
      if x1 = x2      : ' est-ce une racine double ?
          print "Une racine réelle double :"
          print_locate 50,80 : print "X1 = X2 = " ;x1
      else : ' les racines sont distinctes
          print "Deux racines réelles distinctes :"
          print_locate 50,80 : print "X1 = " ;x1
          print_locate 50,100 : print "X2 = " ;x2
      end_if
    else  : ' les racines sont belles et bien complexes
      print_locate 50,50 : print "Deux racines complexes conjuguées :"
      print_locate 50,80 : print "X1 = "; re;" + ";im; "i"
      print_locate 50,100 : print "X2 = "; re;" -  ";im; "i"
    end_if
    show 1 : show 2 : ' on montre les 2 boutons
END_SUB
' ******************************************************************************
' sous-programme pour un autre calcul
suite:
  ' l'utilisateur a cliqué sur le bouton 'Autre calcul'  
  demarrer()
return
' ******************************************************************************
' sous-programme pour quitter l'application
quit:
  ' l'utilisateur a cliqué sur le bouton 'quitter'
  ' on veut s'assurer par une confirmation de quitter, sinon on ne fait rien
  if message_confirmation_yes_no("Vous voulez vraiment quitter ?") = 1 then terminate
return
' ************************** FIN ***********************************************


Code:

' ******************************************************************************

'    3DEGRE.BAS par Papydall

' Résolution de l'équation du troisième dégré ax^3 + bx^2 + cx + d = 0

' ******************************************************************************

' D'après le théorème fondamental de l'algèbre des polynômes : tout polynôme de
' dégré N admet exactement N solutions (on dit aussi racines ou zéros). Ces
' racines sont réelles ou complexes, simples ou multiples et si elles sont
' complexes, elles sont conjuguées deux-à-deux.
' Ce programme permet de résoudre un polynôme du troisième dégré

' L'équation du troisième dégré admet donc trois racines : soit réelles simples
' ou multiples , soit complexes conjuguées.

' RAPPEL : un nombre complexe s'écrit sous forme z = x + i*y , avec x et y réels
' et i nombre imaginaire dont le carré vaut -1 (i² = -1).
' x s'appelle partie réelle du nombre complexe z ; y s'appelle partie imaginaire
' du nombre complexe z.
' Si y = 0 , le nombre est réel. Si x = 0 , le nombre est imaginaire pur.
' Deux nombres complexes conjugués sont deux nombres complexes dont leurs
' parties imaginaires sont de signes contraires.

' ******************************************************************************
Run()
end
' ******************************************************************************
SUB Run()
    label suite    : ' sous-programme pour faire un autre calcul
    label quit    : ' sous-programme pour quitter l'application
    dim a,b,c,d    : ' les coefficients de l'équation
    dim x1,x2,x3  : ' les racines réelles
    dim re,im      : ' Les racines complexes (partie réelle et partie imaginaire)
    dim complexe%  : ' flag pour indiquer si les racines sont complexes (=1) ou réelles (=0)
    color 0,0,0,0  : font_color 0,0,255,0 : font_size 0,12 : font_bold 0
    width 0,width(0)*2
    caption 0,"Résolution de l'équation du troisième dégré : AX^3 + BX^2 + CX + D = 0"
    button 1 : top 1,250 : left 1,50  : width 1, 100 : on_click 1,suite
    button 2 : top 2,250 : left 2,300 : width 2, 80  : on_click 2,quit
    caption 1,"Autre calcul" : caption 2,"Quitter"
    Demarrer()
END_SUB
' ******************************************************************************
SUB demarrer()
    cls  : hide 1 : hide 2
    saisie() : resol_3degre(a,b,c,d) : Format() : Affiche()
    show 1 : show 2
END_SUB
' ******************************************************************************
' Procédure de saisie des coefficients a,b,c,d
SUB saisie()
    DIM_LOCAL r$
    ' Saisie de coefficient A
    repeat      : ' Cette boucle assure que le coefficient A soit différent de 0
        repeat  : ' Cette boucle assure que le coefficient soit numérique
              r$ = message_input$("Entrer le paramètre A (différent de zéro)","A = ","")
        until numeric(r$) = 1
    until val(r$) <> 0
    A = val(r$)
    ' Saisie du coefficient B
    repeat
      r$ = message_input$("Entrer le paramètre B","B = ","")
    until numeric(r$) = 1
    B = val(r$)
    ' Saisie du coefficient C
    repeat
      r$ = message_input$("Entrer le paramètre C","C = ","")
    until numeric(r$) = 1
    c = val(r$)
    ' Saisie du coefficient D
    repeat
      r$ = message_input$("Entrer le paramètre D","D = ","")
    until numeric(r$) = 1
    d = val(r$)
END_SUB
' ******************************************************************************
' Procédure de calcul de la solution
SUB resol_3degre(AX3,BX2,CX,D)
    DIM_LOCAL p,q,delta,radic1,radic2,phi
    complexe% = 0
    p = (c/a)-(power(b,2)/(3*power(a,2)))
    q = (d/a)-(b*c)/(3*(power(a,2)))+(2*(power(b,3))/(27*power(a,3)))
    delta = power(q,2)/4 + power(p,3)/27
    if delta > 0  : ' Une racine réelle et 2 racines complexes conjuguées
      complexe% = 1
      radic1 = (0-q/2)+ sqr(delta) : radic2 = (0-q/2)- sqr(delta)
      x1 = sgn(radic1)*power((abs(radic1)),1/3)+ sgn(radic2)*power(abs(radic2),1/3)
      x1 = x1 - b/(3*a)
      re = 0-0.5*sgn(radic1)*(power(abs(radic1),1/3)+ sgn(radic2)*power(abs(radic2),1/3))
      re = re-b/(3*a)
      im = 0.5*sqr(3)*sgn(radic1)*(power(abs(radic1),1/3)- sgn(radic2)*power(abs(radic2),1/3))
      exit_sub : ' les calculs sont faits, on quitte la procédure
    end_if
    if delta = 0  : ' Trois racines réelles
       complexe% = 0
      if  p = 0  : ' une racine réelle triple
          x1 = sgn(d/a)* power(abs(d/a),1/3) : x2 = x1 : x3 = x1
      else  : ' une racine simple et une racine double
          x1 = 3*q/p : x1 = x1 - b/(3*a)
          x2 = 0-3*q/(2*p) : x2 = x2- b/(3*a)
          x3 = x2
      end_if
      exit_sub : ' les calculs sont faits, on quitte la procédure
    end_if
    ' ici delta est forcément < 0 et l'équation admet 3 racines réelles distinctes
    phi = acos(((3*q)/(2*p))*sqr(0-3/p))
    x1 = 2*sqr(0-p/3)*cos(phi/3) : x1 = x1 - b/(3*a)
    x2 = 2*sqr(0-p/3)*cos((phi+2*pi)/3) : x2 = x2 - b/(3*a)
    x3 = 2*sqr(0-p/3)*cos((phi+4*pi)/3) : x3 = x3 - b/(3*a)

END_SUB
' ******************************************************************************
' Procédure de formatage de la solution
SUB Format()
    dim_local a$,b$,c$,d$
    dim_local epsilon : epsilon = power(10,0-10)
    if a = 1  then a$ = "x^3 " : else : a$ = str$(a)+"x^3 " : ' Pour ne pas afficher 1x^3
    if a = -1 then a$ = "-x^3" : ' pour ne pas afficher -1x^3
    if b = 1  then b$ = "+x^2 " : else : b$ = str$(b)+"x^2 " : ' Pour ne pas afficher 1x^2
    if b = -1 then b$ = "-x^2 " : ' pour ne pas afficher -1x^2
    if b > 1  then b$ = "+" + str$(b)+"x^2 "
    if b = 0  then b$ = ""
    if c = 1  then c$ = "+x " : else : c$ = str$(c)+"x " : ' Pour ne pas afficher 1x
    if c = -1 then c$ = "-x " : ' pour ne pas afficher -1x
    if c > 1  then c$ = "+" + str$(c)+"x "
    if c = 0  then c$ = ""
    if d = 0  then d$ = " = 0" : else : d$ = str$(d)+" = 0 :"
    if d > 0  then d$ = "+" + str$(d)+" = 0"

    x1 = x1 + sgn(x1)*epsilon : x1 = int(x1*100000+0.5)/100000
    x2 = x2 + sgn(x2)*epsilon : x2 = int(x2*100000+0.5)/100000
    x3 = x3 + sgn(x3)*epsilon : x3 = int(x3*100000+0.5)/100000

    re = re + sgn(re)*epsilon : re = int(re*100000+0.5)/100000
    im = im + sgn(im)*epsilon : im = int(im*100000+0.5)/100000
    print_locate 50,20 : print "La solution de : "+a$+b$+c$+d$
END_SUB
' ******************************************************************************
' Procédure d'affichage de la solution
SUB Affiche()
    print_locate 50,20  : ' on positionne le curseur pour l'affichage
    if complexe% = 0  : ' Les racines sont réelles
      print_locate 50,50
      if x1 = x2    : ' une racine triple
          print "Une racine triple"
          print_locate 50,80 : print "X1 = X2 = X3 = ";x1
      else
          if x2 = x3    : ' une racine double
            print "Une racine réelle simple et une racine réelle double :"
            print_locate 50,80  : print "X1 = "; x1
            print_locate 50,100 : print "X2 = X3 = " ; x2
          else : ' les trois racines sont réelles et distinctes
            print "Trois racines réelles distinctes :"
            print_locate 50,80  : print "X1 = " ; x1
            print_locate 50,100 : print "X2 = " ; x2
            print_locate 50,120 : print "X3 = " ; x3
          end_if
      end_if
    else  : ' une racine réelle et deux racines complexes conjuguées
      print_locate 50,50  : print "une racine réelle et deux racines complexes conjuguées"
      print_locate 50,80  : print "X1 = ";x1
      print_locate 50,100 : print "X2 = "; re;" + ";ABS(im); "i"
      print_locate 50,120 : print "X3 = "; re;" -  ";abs(im); "i"
    end_if
END_SUB

' ******************************************************************************
' sous-programme pour un autre calcul
suite:
  demarrer()
return
' ******************************************************************************
' sous-programme pour quitter l'application
quit:
  if message_confirmation_yes_no("Vous voulez vraiment quitter ?") = 1 then terminate
return
' ************************** FIN ***********************************************


Une autre question Question
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
mindstorm

avatar

Nombre de messages : 542
Age : 48
Localisation : charente
Date d'inscription : 13/02/2013

MessageSujet: Re: Demande urgente en maths.   Mer 25 Oct 2017 - 20:27

Papydall est formidable cheers
mieux, c'est notre ange gardien santa
Bon d'accord j'en fait trop mais c'est un forum entre amis.
je fonce pour décortiquer tes codes
il faut que je réfléchisse pour calculer une échelle a partir des résultats et donc obtenir un représentation graphique
encore merci
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5613
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Demande urgente en maths.   Jeu 26 Oct 2017 - 2:30

mindstorm a écrit:
il faut que je réfléchisse pour calculer une échelle a partir des résultats et donc obtenir un représentation graphique

Pour tracer la courbe représentative d’une fonction y = f(x), j’ai déjà posté un programme qui répond à cette question.
D’ailleurs il fait beaucoup plus :  il peut tracer jusqu’à 4 courbes sur le même graphique avec des couleurs différentes.
C’est utile pour comparer des graphes des courbes surtout au voisinage d’un point particulier (par exemple les courbes sinus hyperbolique et cosinus hyperboliques au voisinage de l’infini)
Le programme utilise une dll de notre ami Jean_Debord EVAL.DLL.
Cette DLL reconnait toute une batterie d’opérateurs et de fonctions mathématiques, beaucoup plus que ne propose panoramic.
Tu trouveras toutes les explications nécessaires pour l’utilisation du programme qui est  bien documenté et son utilisation est intuitive.

Voici le lien où se trouve ce petit bijou  Laughing

Le programme utilise différentes procédures SUB que tu peux utiliser pour réaliser ton propre programme :
pour le tracé des axes : axe des X et axe des Y ;
pour le passage des coordonnées utilisateur aux coordonnées écran.
Pour le tracé de la courbe, etc.

Bon,  sers-toi comme il te plaira.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
mindstorm

avatar

Nombre de messages : 542
Age : 48
Localisation : charente
Date d'inscription : 13/02/2013

MessageSujet: Re: Demande urgente en maths.   Jeu 26 Oct 2017 - 19:37

effectivement Papydall
je suis passé a coté et je ne l'avais pas retenu car je ne métrise pas bien les DLL.
Ensuite j'avais oublié!
Grave erreur No
tout compte fait, je l'aime bien cette DLL
merci à Jean Debord et Papydall
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5613
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Demande urgente en maths.   Jeu 26 Oct 2017 - 19:58

Le code explique bien comment utiliser cette dll dans un programme personnel.
Ce n’est pas si difficile.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
papydall

avatar

Nombre de messages : 5613
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Demande urgente en maths.   Dim 29 Oct 2017 - 1:26

Le grand mystère des Mathématiques:
 
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Contenu sponsorisé




MessageSujet: Re: Demande urgente en maths.   

Revenir en haut Aller en bas
 
Demande urgente en maths.
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» [Annulée] Demande de page d'aceuil
» [Annulée] Demande de description des catégories.
» [résolu] demande d'aide à l'optimisation
» [Basil] Demande de mise en page
» Demande de CSS

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: A l'aide!-
Sauter vers: