FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» Objet 3D_PLANE, réalisation d'un dé en 3D
par Marc Aujourd'hui à 0:33

» Cacher la barre des tâches
par Klaus Hier à 21:27

» Une "base de connaissance" - pour jouer ou plus si affinité
par Minibug Hier à 10:29

» quel est ce comportement de Panoramic_editor
par Oscaribout Hier à 0:22

» Des FORM(s) Colorés
par Jean Claude Dim 20 Mai 2018 - 20:58

» Recherches dans un fichier texte
par JL35 Dim 20 Mai 2018 - 20:18

» Problème d'affichage des pages du forum (Résolu)
par Jean Claude Dim 20 Mai 2018 - 20:00

» Créer une application *.exe
par Yannick Ven 18 Mai 2018 - 20:01

» [RÉSOLU] Priorité affichage des objets : comment la définir?
par papydall Ven 18 Mai 2018 - 18:22

» Aucune différence entre ON_CLICK et ON_DOUBLE_CLICK
par Jean Claude Jeu 17 Mai 2018 - 8:37

» [Résolu] Récuperer les fonctions systeme de Panoramic
par Minibug Mar 15 Mai 2018 - 23:21

» Est-ce qu'un fichier est inclus dans l'application ?
par Yannick Mar 15 Mai 2018 - 12:04

» Création d'une application avec Panoramic_Editor
par Klaus Mar 15 Mai 2018 - 0:36

» Pour faire patienter
par Minibug Lun 14 Mai 2018 - 21:25

» Une copie de Panoramic Editeur
par Minibug Lun 14 Mai 2018 - 19:55

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Mai 2018
LunMarMerJeuVenSamDim
 123456
78910111213
14151617181920
21222324252627
28293031   
CalendrierCalendrier

Partagez | 
 

 Ca pourrait être utile dans un jeu 2D...

Aller en bas 
AuteurMessage
Klaus

avatar

Nombre de messages : 11084
Age : 69
Localisation : Ile de France
Date d'inscription : 29/12/2009

MessageSujet: Ca pourrait être utile dans un jeu 2D...   Mar 11 Juil 2017 - 21:46

Récemment, mon fils m'a posé le problème suivant:
Un jeu 2D (simulation du vol d'un vaisseau spatial), on a un "monde" assez vaste, et un rectangle restraint est affiché dans une fenêtre de visualisation (fenêtre mobile, bien sûr).
Le vaisseau est entouré de "cibles" dont certaines sont "hors cadre", donc non visibles à un instant donné.
Or, le vaisseau dispose d'un semblant de radar qui lui permet de connaître la direction exacte dans laquelle se trouvent les cibles, dans pour autant connaître leur distance.
Le radar affiche une flèche au bord de la fenêtre de visualisation, dans l'axe d'un rayon reliant le vaisseau à la cible (donc avec la même pente !), mais la pointe de la flèche se trouve sur un des 4 côtés de la fenêtre de visualisation.

Question: comment déterminer le point sur bord de la fenêtre de visualisation vers lequel la flèche doit pointer, ainsi que sa pente (inclinaison) ?

Solution:
J'ai fait un petit code Panoramic qui dessine un rectangle symbolisant la fenêtre de visuialisation.
Dans ce rectangle, il y a un cercle représantant le vaisseau.
Tout autour, il y a 14 cercles "hors cadre" représentant les cibles.
Alors le programme dessine les 14 rayons en pointillé, calcule les pentes de ces rayons (et donc la pente des flèches) et détermine les coordonnés de l'intersection des rayons avec les 4 bords.
Pour matérialiser l'exactitude du calcul, le programme dessine un cercle sur ces 14 point d'intersection. Ces points sont donc l'endroit vers lequels les flèches doivent pointer, avec leurs pentes associées.

Voici le code:
Code:

dim x%(14),y%(14), i%

data  100,80,  400,50,  600,70,  900,90,  1000,200, 1100,300
data 1200,450, 1100,700, 1200,600,  750,600,  400,700,  150,600
data  80,400,  70,250
for i%=1 to 14
  read x%(i%)
  read y%(i%)
next i%


full_space 0
picture 1 : full_space 1

2d_target_is 1
print_target_is 1

2d_fill_color 255,255,0
2d_rectangle 300,200,800,500

' tracer le cercle symbolisant le vaisseau
2d_fill_color 0,0,255
2d_circle 600,300,5

' tracer les cercles symbolisant les 14 cibles "hors cadre"
for i%=1 to 14
  2d_fill_color 255,0,0
  2d_circle x%(i%),y%(i%),5
  2d_fill_color 255,255,255
  print_locate x%(i%)+10,y%(i%)-10
  print str$(i%)
next i%

' tracer les 14 flèches vers les cibles
for i%=1 to 14
  Fleche(i%, 300,200,800,500, 600,300, x%(i%),y%(i%))
next i%

end

' xc1%,yc1%: coin en haut à gauche du cadre d'affichage (zone visible)
' xc2%,yc2%: coin en bas à droite du cadre d'affichage (zone visible)
' xv%,yv%:  position du vaisseau
' x%,y%      position de la cible hors cadre à viser par une flèche
sub Fleche(i%,xc1%,yc1%,xc2%,yc2%, xv%,yv%, xcible%,ycible%)
  ' équations des 4 côtés de la zone de visualisation
  ' X = xc1%  <== côté gauche
  ' Y = yc1%  <== côté haut
  ' X = xc2%  <== côté droit
  ' Y = yc2%  <== côté bas
 
  ' équation de la droite entre le vaisseau et la cible
  ' Y = aX + b
  '    a = (ycible%-yv% )/(xcible%-xv%)
  ' avec point (xv%,yv%):
  ' yv% = (ycible%-yv% )/(xcible%-xv%)*xv% + b
  ' ==>  b = yv% - (ycible%-yv% )/(xcible%-xv%)*xv%
  ' équation définitive;
  ' Y = ((ycible%-yv% )/(xcible%-xv%))*X + yv% - ((ycible%-yv% )/(xcible%-xv%))*xv%
  ' ou, avec des variables intermédiaires regroupant en fait des termes constants:
  '  cc1% = ycible%-yv%
  '  cc2% = xcible%-xv%
  ' ==>  Y = (cc1//cc2%)*X + yv% - (cc1%/cc2%)*xv% 
  ' et, acec cc2% = cc1%/cc2%:
  ' ==>  Y = cc3%*X + yv% - cc3%*xv%
  dim_local XX%,YY%
  dim_local cc1, cc2, cc3
 
  ' rayon de la navette vers a cible
  2d_pen_dot
  2d_poly_from xv%,yv%
  2d_poly_to xcible%,ycible%
  2d_pen_solid
 
  ' calcul des variables intermédiaires:
  cc1 = ycible%-yv%
  cc2 = xcible%-xv% + 1  : ' +1 pour éviter une division par 0 !
  cc3 = cc1 / cc2        : ' ceci est la pente de la droite entre navette et cible !
  ' la routine calcule l'intersection du rayon navette/cible avec un des 4 bords.
  ' les coordonnées de ce point sont (XX%,YY%)
     
  ' intersection avec le bord gauche:
  if xcible%<xv%
    XX% = xc1%
    ' pour info: Y = cc3*X + yv% - cc3*xv%
    YY% = cc3*XX% + yv% - cc3*xv%
    if (YY%>=yc1%) and (YY%<=yc2%)
      2d_fill_color 0,0,0
      2d_circle XX%,YY%,5
      print_locate XX%+10,YY%
      2d_fill_color 255,255,0
      print str$(i%)
      exit_sub
    end_if
  end_if
 
  ' intersection avec le bord haut:
  if ycible%<yv%
    YY% = yc1%
    ' pour info: Y = cc3*X + yv% - cc3*xv%
    XX% = (YY% - (yv% - cc3*xv%))/cc3
    if (XX%>=xc1%) and (XX%<=xc2%)
      2d_fill_color 0,0,0
      2d_circle XX%,YY%,5
      print_locate XX%,YY%+10
      2d_fill_color 255,255,0
      print str$(i%)
      exit_sub
    end_if
  end_if
 
  ' intersection avec le bord droit:
  if xcible%>xv%
    XX% = xc2%
    ' pour info: Y = cc3*X + yv% - cc3*xv%
    YY% = cc3*XX% + yv% - cc3*xv%
    if (YY%>=yc1%) and (YY%<=yc2%)
      2d_fill_color 0,0,0
      2d_circle XX%,YY%,5
      print_locate XX%-10,YY%
      2d_fill_color 255,255,0
      print str$(i%)
      exit_sub
    end_if
  end_if
 
  ' intersection avec le bord bas:
  if ycible%>yv%
    YY% = yc2%
    ' pour info: Y = cc3*X + yv% - cc3*xv%
    XX% = (YY% - (yv% - cc3*xv%))/cc3
    if (XX%>=xc1%) and (XX%<=xc2%)
      2d_fill_color 0,0,0
      2d_circle XX%,YY%,5
      print_locate XX%,YY% -20
      2d_fill_color 255,255,0
      print str$(i%)
      exit_sub
    end_if
  end_if
 
end_sub
et voici une capture d'écran:
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://klauspanoramic.comxa.com/index.html
Jean Claude

avatar

Nombre de messages : 5356
Age : 64
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Ca pourrait être utile dans un jeu 2D...   Mer 12 Juil 2017 - 9:03

Très intéressant,

je mets de coté, car c'est certain, ça va servir Very Happy

Merci Klaus pour le partage.
A+


Dernière édition par Jean Claude le Mer 12 Juil 2017 - 10:53, édité 1 fois
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 8074
Age : 47
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Mer 12 Juil 2017 - 9:42

Effectivement, cela pourrait bien rendre service.
Je mets de côté aussi.

Merci Klaus.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Contenu sponsorisé




MessageSujet: Re: Ca pourrait être utile dans un jeu 2D...   

Revenir en haut Aller en bas
 
Ca pourrait être utile dans un jeu 2D...
Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» Liens inactifs dans Outlook Express
» compteur php dans page générée par e-anim
» Composition de trains dans RRTC 7.0 B1 Gold
» Insertion d'animation dans un php joomla
» [Resolu] Bannière avec lien dans une signature

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Vos sources, vos utilitaires à partager-
Sauter vers: