FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» Un petit "coucou" à tous les Panoramiciens !
par Yannick Aujourd'hui à 23:06

» mise a jour calculatrice
par joeeee2017 Aujourd'hui à 22:44

» Logiciel de soutien scolaire en langues.
par Pedro Alvarez Aujourd'hui à 16:52

» KGF_dll - nouvelles versions
par Klaus Aujourd'hui à 14:16

» Compilateur FBPano
par Ouf_ca_passe Aujourd'hui à 12:25

» double guillemets "" dans un EDIT
par Marc Hier à 23:43

» Documentation de KGF
par Klaus Lun 20 Nov 2017 - 22:52

» Zoom sur une portion d'écran
par JL35 Lun 20 Nov 2017 - 21:51

» Recherche d'une expression dans un source
par Marc Lun 20 Nov 2017 - 13:08

» Tracer une grille n'importe où sur l'écran
par JL35 Dim 19 Nov 2017 - 22:14

» TourD Version 2
par Klaus Sam 18 Nov 2017 - 23:58

» La métamatière et le peuple
par JL35 Ven 17 Nov 2017 - 21:18

» Capture d'une zone de l'écran total
par JL35 Ven 17 Nov 2017 - 18:41

» qui peut résoudre mon prb
par pascal10000 Jeu 16 Nov 2017 - 17:30

» évènements et objets système : listage automatique
par Jean Claude Jeu 16 Nov 2017 - 11:15

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Novembre 2017
LunMarMerJeuVenSamDim
  12345
6789101112
13141516171819
20212223242526
27282930   
CalendrierCalendrier

Partagez | 
 

 Palette (une de plus): 16, 48 ou 216 couleurs

Voir le sujet précédent Voir le sujet suivant Aller en bas 
AuteurMessage
JL35



Nombre de messages : 5992
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Palette (une de plus): 16, 48 ou 216 couleurs   Jeu 20 Avr 2017 - 17:22

Code:
Palette(100,60,48)
color 0,rpal%,gpal%,bpal%
END
' ==============================================================================
SUB Palette(x%,y%,ncoul%)
  ' Affichage en x%,y% d'une palette de ncoul% couleurs (16, 48 ou 216)
  ' Clic une couleur -> rendue dans les variables rpal%, gpal%, bpal% (déclarées
  '  ou non dans le programme appelant).
  IF LABEL("Ccol") = 0 THEN LABEL Ccol
  IF LABEL("Qcol") = 0 THEN LABEL Qcol
  IF VARIABLE("nbcolor%") = 0 THEN DIM nbcolor%
  IF VARIABLE("rpal%") = 0 THEN DIM rpal%
  IF VARIABLE("gpal%") = 0 THEN DIM gpal%
  IF VARIABLE("bpal%") = 0 THEN DIM bpal%
  DATA "Palette16": ' couleurs ms-dos
  DATA "000000","000080","0000FF","008000","008080","00FF00","00FFFF","800000"
  DATA "800080","808000","808080","C066C0","FF0000","FF00FF","FFFF00","FFFFFF"
  DATA "Palette48": ' couleurs windows
  DATA "FF8080","FFFF80","80FF80","00FF80","80FFFF","0080FF","FF80C0","FF80FF"
  DATA "FF0000","FFFF00","80FF00","00FF40","00FFFF","0080C0","8080C0","FF00FF"
  DATA "804040","FF8040","00FF00","008080","004080","8080FF","800040","FF0080"
  DATA "800000","FF8000","008000","008040","0000FF","0000A0","800080","8000FF"
  DATA "400000","804000","004000","004040","000080","000040","400040","400080"
  DATA "000000","808000","808040","808080","408080","C0C0C0","400040","FFFFFF"
  DIM_LOCAL fo%,pi%,al%,pj%,bt%,nr%,w%,h%,a$,b$,r%,g%,b%,rh$,gh$,bh$,we%,he%,i%,j%,fco%
  IF ncoul%<>16 AND ncoul%<>48 AND ncoul%<>216 THEN ncoul% = 16
  we% = 20: he% = we%: ' dimensions des cases de couleurs
  nr% = ncoul%/8: ' affichage des couleurs sur nr% rangées de 8 colonnes
  w% = we%*8: h% = he%*nr%
  fo% = 900
  pi% = fo%+1: al% = pi%+1: pj% = al%+1: bt% = pj%+1
  IF OBJECT_EXISTS(fo%) = 1 AND ncoul% = nbcolor%
      ' appels successifs
      TOP fo%,y%: LEFT fo%,x%
      SHOW fo%
  ELSE
      ' appel initial ou changement du nombre de couleurs: création des objets
      IF OBJECT_EXISTS(fo%) = 1 THEN DELETE fo%
      FORM fo%: BORDER_SMALL fo%: TOP fo%,y%: LEFT fo%,x%: COLOR fo%,200,255,255
        i% = WIDTH(fo%)-WIDTH_CLIENT(fo%): j% = HEIGHT(fo%)-HEIGHT_CLIENT(fo%)
        WIDTH fo%,w%+i%: HEIGHT fo%,h%+j%+45: CAPTION fo%,"  -    "+STR$(ncoul%)+"  COULEURS    -"
        FONT_NAME fo%,"Arial": ON_CLOSE fo%,Qcol
      PICTURE pi%: PARENT pi%,fo%: WIDTH pi%,w%: HEIGHT pi%,h%: ON_CLICK pi%,Ccol
        2D_TARGET_IS pi%
      ALPHA al%: PARENT al%,fo%: TOP al%,HEIGHT(pi%)+2: LEFT al%,2
        CAPTION al%,"clic une couleur"
      PICTURE pj%: PARENT pj%,fo%: WIDTH pj%,35: HEIGHT pj%,35: TOP pj%,TOP(al%)+3
        LEFT pj%,80
      BUTTON bt%: PARENT bt%,fo%: HEIGHT bt%,20: TOP bt%,TOP(pj%): WIDTH bt%,40
        LEFT bt%,WIDTH(fo%)-58: HEIGHT bt%,HEIGHT(pj%): CAPTION bt%,"OK": ON_CLICK bt%,Qcol
      IF ncoul% = 16 OR ncoul% = 48
          b$ = "Palette"+STR$(ncoul%)
          RESTORE: READ a$: WHILE a$<>b$: READ a$: END_WHILE
      END_IF
      r% = 0: g% = 0: b% = 0: y% = 0
      FOR j% = 0 TO nr%-1
        x% = 0
        FOR i% = 0 TO 7
            IF ncoul% <> 216
                READ a$: r%=HEX(LEFT$(a$,2)): g%=HEX(MID$(a$,3,2)): b%=HEX(RIGHT$(a$,2))
            END_IF
            2D_FILL_COLOR r%,g%,b%: 2D_RECTANGLE x%,y%,x%+we%-1,y%+he%-1: x% = x%+we%
            IF ncoul% = 216: ' couleurs Html
                b% = b%+51
                IF b% > 255
                    b% = 0: g% = g%+51
                    IF g% > 255 THEN g% = 0: r% = r%+51
                END_IF
            END_IF
        NEXT i%
        y% = y%+he%
      NEXT j%
  END_IF
  2D_TARGET_IS pi%: INACTIVE 0
  WHILE fco% = 0: PAUSE 100: TO_FOREGROUND fo%: END_WHILE
  2D_TARGET_IS 0: HIDE fo%: ACTIVE 0: TO_FOREGROUND 0: EXIT_SUB
Ccol:
  x% = MOUSE_X_LEFT_DOWN(pi%): y% = MOUSE_Y_LEFT_DOWN(pi%)
  r% = COLOR_PIXEL_RED(pi%,x%,y%): rh$ = RIGHT$("0"+HEX$(r%),2)
  g% = COLOR_PIXEL_GREEN(pi%,x%,y%): gh$ = RIGHT$("0"+HEX$(g%),2)
  b% = COLOR_PIXEL_BLUE(pi%,x%,y%): bh$ = RIGHT$("0"+HEX$(b%),2)
  a$ = "R= "+rh$+" h ("+STR$(r%)+")"
  a$ = a$+CHR$(10)+"G= "+gh$+" h ("+STR$(g%)+")"+CHR$(10)+"B= "+bh$+" h ("+STR$(b%)+")"
  CAPTION al%,a$
  COLOR pj%,r%,g%,b%
  rpal% = r%: gpal% = g%: bpal% = b%
RETURN
Qcol:
  fco% = 1
RETURN
END_SUB
' ===============================================================================

Edit une petite modif suite à une remarque (vicieuse...?) de papydall.
Edit 21/4 Modifié pour éviter un blocage (si clic sur Form 0 au lieu de la palette)
Re Edit 21/4 Pas de recréation des objets en cas d'appels successifs à la sub (suggestion de Klaus)


Dernière édition par JL35 le Ven 21 Avr 2017 - 22:56, édité 3 fois
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5594
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Palette (une de plus): 16, 48 ou 216 couleurs   Jeu 20 Avr 2017 - 18:31

Salut Jl35.
Belle palette, mais ….
Essaye de cliquer dans FORM 0 (ou sur la croix) avant de cliquer sur le bouton OK et c’est la boucle infernale !
Plus moyen de sortir du programme à cause de la ligne 63
Code:
WHILE fco% = 0: PAUSE 50: END_WHILE

La variable locale fco% étant toujours à zéro, on reste  dans une boucle infinie !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
JL35



Nombre de messages : 5992
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Palette (une de plus): 16, 48 ou 216 couleurs   Jeu 20 Avr 2017 - 20:47

Bien d'accord papydall, ce n'est pas une chose à faire !
Et je n'ai pas de solution simple pour éviter ces étourderies...

Si, il y en a une, faire régulièrement réapparaître le Form des couleurs, je corrige là-haut.
(je mets un To_Foreground 900 dans la boucle d'attente du OK)
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Klaus

avatar

Nombre de messages : 10129
Age : 68
Localisation : Ile de France
Date d'inscription : 29/12/2009

MessageSujet: Re: Palette (une de plus): 16, 48 ou 216 couleurs   Ven 21 Avr 2017 - 1:39

Sans avoit testé ton code, je peux te donner une méthode générale pour prévenir cela.
1. tu places ta palette dans une FORM N séparée
2. lorsque tu veux gérer la palette, tu l'affiches par SHOW N
3. en même temps, tu fais INACTIVE 0
4. tu fais un évènement ON_CLOSE sur la FORM N. Lorsque cet évènement se déclenche, tu traites le résultat, tu caches la form par HIDE N et tu fais ACTIVE 0
5. tu fais un TO_FOREGROUND 0 pour finir le traitement du ON_CLOSE

Et voilà. Plus de boucle infinie, plus de form qui passe en arrière-plan, etc.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://klauspanoramic.comxa.com/index.html
papydall

avatar

Nombre de messages : 5594
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Palette (une de plus): 16, 48 ou 216 couleurs   Ven 21 Avr 2017 - 1:44

JL35 a écrit:
Bien d'accord papydall, ce n'est pas une chose à faire !
Et je n'ai pas de solution simple pour éviter ces étourderies...

C’est ton point de vue et je le respecte, mais, selon moi, ce n’est pas une étourderie.
Quand l’utilisateur final d’un programme n’est pas forcément son concepteur,  ce dernier doit ( ?)  sécuriser  son code contre de telles « choses à ne pas faire ».
J’avoue que j’ai cherché une solution, sans y parvenir!
Alors bravo pour la tienne. tongue
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
JL35



Nombre de messages : 5992
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Palette (une de plus): 16, 48 ou 216 couleurs   Ven 21 Avr 2017 - 18:43

Il est bien évident que tu avais raison de me le faire remarquer papydall, c'est comme ça qu'on avance !
Et ce n'est pas parce que je n'avais pas de solution qu'il n'y avait pas de problème !

Merci à toi Klaus pour tes suggestions, je crois que je vais intégrer ça, ça semble plus sécurisé que ce que j'ai fait, mais je veux que ça reste une sub complètement indépendante du programme principal. Donc le Form de la palette est recréé à chaque appel (et supprimé au retour).

Et encore merci à tous les deux.

Edit: voilà, c'est fait, j'ai adopté la méthode Klaus pour éviter les blocages en cas de clic ailleurs qu'aux endroits prévus.
Et j'ai paramétré les numéros d'objets pour le cas où on voudrait en changer, il suffit de changer la valeur de fo%, le reste suivra.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Klaus

avatar

Nombre de messages : 10129
Age : 68
Localisation : Ile de France
Date d'inscription : 29/12/2009

MessageSujet: Re: Palette (une de plus): 16, 48 ou 216 couleurs   Ven 21 Avr 2017 - 22:07

Citation :
Donc le Form de la palette est recréé à chaque appel (et supprimé au retour).
C'est inutilement lourd, Jl35. Au début de ta sub, tu fais:
Code:
if object_exists(N)
  show N
else
  ... ici, tout le travail de création de cette form
end_if

Si tu procèdes ainsi, tu as un avantage énorme: le contenu de tous les champs reste préservé et tu le retrouves à l'appel suivant, un peu comme des valeurs par défaut dynamiques. Et même si tu fermes la fenêtre par la croix rouge, elle n'est pas physiquement supprimé, mais seulement cachée. J'utilise cette technique pour toutes les fenêtres auxiliaires (optione générales, options de la page, ...) sans aucun problème.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://klauspanoramic.comxa.com/index.html
JL35



Nombre de messages : 5992
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Palette (une de plus): 16, 48 ou 216 couleurs   Ven 21 Avr 2017 - 22:24

Réflexion faite, tu as parfaitement raison Klaus. C'est effectivement une sub qu'on peut être amené à appeler souvent dans un même programme (de dessin par exemple), contrairement à une sub qu'on n'appelle qu'une seule fois (genre: quelle est la version de Windows). Et c'est judicieux de ne pas refaire le travail de création des objets à chaque fois.

Je vais la reformater dans ce sens.

Voilà, c'est fait.
Les objets sont créés à l'appel initial de la sub, et conservés pour les appels suivants éventuels, sauf s'il y a changement du nombre de couleurs (auquel cas on recrée le tout). Il est permis, d'un appel à l'autre, de modifier les coordonnées d'affichage de la palette des couleurs.

Une remarque concernant la palette 48 couleurs: les couleurs n° 39 et n° 47 sont identiques (400040h) du moins sur la palette que j'ai récupéré, je ne sais pas si c'est normal ?
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
mindstorm

avatar

Nombre de messages : 540
Age : 48
Localisation : charente
Date d'inscription : 13/02/2013

MessageSujet: Re: Palette (une de plus): 16, 48 ou 216 couleurs   Mar 25 Avr 2017 - 21:55

Merci Klaus pour cette pratique si évidente qu'elle ne m'a jamais traversé l'esprit
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Klaus

avatar

Nombre de messages : 10129
Age : 68
Localisation : Ile de France
Date d'inscription : 29/12/2009

MessageSujet: Re: Palette (une de plus): 16, 48 ou 216 couleurs   Mer 26 Avr 2017 - 1:18

De rien, Mndstorm ! Pour les idées, le forum est "open bar" - et j'en profite aussi !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://klauspanoramic.comxa.com/index.html
Contenu sponsorisé




MessageSujet: Re: Palette (une de plus): 16, 48 ou 216 couleurs   

Revenir en haut Aller en bas
 
Palette (une de plus): 16, 48 ou 216 couleurs
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» FR7B - Programmation MIDI...
» Challenge 2012 image d'extérieur - cqld - Sketchup Artlantis Photoshop
» Palette de Brush Kanjis *^*
» Nouvelle palette de couleurs
» [inkscape] 06_utiliser la palette de couleurs

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Vos sources, vos utilitaires à partager-
Sauter vers: