FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» Le Forum est en vacances.
par JL35 Aujourd'hui à 21:20

» Une autre façon de terminer une application.
par JL35 Hier à 14:27

» Compilateur FBPano
par Mike Lun 21 Aoû 2017 - 23:17

» Pb 20 (en analyse): plantage à l'appel d'un SUB
par Jack Lun 21 Aoû 2017 - 21:58

» Pb 19 (en analyse): libellé d'erreur dans des IF imbriqués
par Jack Lun 21 Aoû 2017 - 21:55

» Copier / coller du texte à partir de la fenêtre de commandes
par jean_debord Lun 21 Aoû 2017 - 9:46

» COMPILATEUR V 0.9 beta 8 du 18 aout 2017
par papydall Lun 21 Aoû 2017 - 5:01

» Mettre en windows en veille
par papydall Lun 21 Aoû 2017 - 4:15

» Stretch_on ne stretch plus...
par papydall Dim 20 Aoû 2017 - 15:22

» Pb 18 (en analyse): RESTORE_LABEL avec DATA à la fin
par Jack Dim 20 Aoû 2017 - 13:21

» Problème de traitement des opérateurs avec le compilateur.
par Pedro Alvarez Sam 19 Aoû 2017 - 20:01

» Pb 17 (résolu): ITEM_SELECT ne fonctionne pas
par Jack Jeu 17 Aoû 2017 - 19:26

» un nouveau editeur panobasic
par Jean Claude Jeu 17 Aoû 2017 - 10:18

» Le compilateur.
par Pedro Alvarez Jeu 17 Aoû 2017 - 8:36

» Pb 16 (résolu): ON_CLOSE plante à l'exécution
par Jack Mer 16 Aoû 2017 - 20:00

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Août 2017
LunMarMerJeuVenSamDim
 123456
78910111213
14151617181920
21222324252627
28293031   
CalendrierCalendrier

Partagez | 
 

 Nous sommes le 1er Avril : Jour du Poisson d'Avril !

Voir le sujet précédent Voir le sujet suivant Aller en bas 
AuteurMessage
papydall

avatar

Nombre de messages : 5522
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Nous sommes le 1er Avril : Jour du Poisson d'Avril !   Sam 1 Avr 2017 - 14:10

Code:

rem ============================================================================
rem                  Poissons siamois
rem                    Par Papydall
rem ============================================================================
rem Deux simples équations paramétriques X = f(t) et Y = g(t) permettent de
rem tracer des jolies courbes.
rem Admirez la courbe des poissons siamois.
rem ============================================================================
rem               _________________________________________________________
rem              |                              ||                        |
rem              |   x = 5*cos(t) - c*cos(5*t)  || avec c = sqr(2) - 1    |
rem              |   y = sin(4*t)               || t variant de 0 à 360°  |
rem              |______________________________||________________________|
rem
rem ============================================================================
picture 10 : width 10,width(0)-100 : height 10,height(0)-100
top 10,20  : left 10,50 : 2d_target_is 10 : print_target_is 10
font_name 10,"arial"    : font_size 10,14 : font_color 10,0,0,255
color 0,0,0,0 : 2d_pen_color 255,150,50   : color 10,0,255,255

Poissons_Siamois(250,150,40)
Poissons_Siamois(050,050,06) : Poissons_Siamois(450,050,06)
Poissons_Siamois(060,350,12) : Poissons_Siamois(440,350,12)

2d_fill_color 0,255,255
print_locate 150,020 : print "VIVE LES MATHEMATIQUES"
print_locate 200,050 : print "Poissons siamois"
print_locate 150,220 : print "Equations paramétriques :"
print_locate 150,250 : print "x = 5 * cos(t) - c * cos(5*t)"
print_locate 150,275 : print "y = sin(4*t)"
print_locate 150,300 : print "avec c = sqr(2) - 1"
print_locate 150,325 : print "t angle variant de 0 à 360°"

END
rem ============================================================================
' Equations paramétriques des poissons siamois
' x = 5*cos(t) - c*cos(5*t)
' y = sin(4*t)
' avec c = sqr(2)-1 = 0.41421356...
' t angle variant de 0 à 360°
' ------------------------------------------------------------------------------
' Paramètres :
' xc,yc : coordonnées du point de contact de deux poissons
' taille : taille en pixels
SUB Poissons_Siamois(xc,yc,taille)
    dim_local x,y,t,xp,yp,c
    degrees
    c = sqr(2) - 1
    if taille < 6 then taille = 6
    2d_poly_from xc+taille*(5-c),yc
    for t = 0 to 360
        x = 5*cos(t) - c * cos(5*t) : y = sin(4*t)
        xp = xc + taille * x : yp = yc + taille * y
        2d_poly_to xp,yp
    next t
    2d_flood xc-2,yc,255,150,50 :  2d_flood xc+2,yc,255,150,50
    2d_flood xc+1-(5-2*c)*taille,yc,255,150,50
    2d_flood xc-1+(5-2*c)*taille,yc,255,150,50
END_SUB
rem ============================================================================
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Yannick

avatar

Nombre de messages : 7975
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Sam 1 Avr 2017 - 16:14

Joli Papydall !

Mais ceux ci ne vont pas vivre vieux.
Ils vont avoir un peu de mal à se nourrir.
Laughing
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Laurent (Minibug)

avatar

Nombre de messages : 2353
Age : 50
Localisation : Vienne (86)
Date d'inscription : 10/02/2012

MessageSujet: Re: Nous sommes le 1er Avril : Jour du Poisson d'Avril !   Sam 1 Avr 2017 - 16:26

Bravo pour ta formule Papydall !

@Yannick
Et en plus ils sont aveugles... Laughing
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5522
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Nous sommes le 1er Avril : Jour du Poisson d'Avril !   Sam 1 Avr 2017 - 18:34

Citation :
Ils vont avoir un peu de mal à se nourrir.

Citation :
Et en plus ils sont aveugles...  


Bon, je leur donne la vue.
Quant à la nourriture, ils se contenteront des bisous !  tongue

Code:

rem ============================================================================
rem           Les poissons grandissent et font la bise
rem ============================================================================
dim x,y,a,t,k,r,rx,rx1,rx2,ry,ry1,ry2,cr,cg,cb
a = 10 : k = 2*sqr(2)
caption 0,"Les poissons grandissent et font la bise      <CLICK> pour arrêter"
degrees : ' On travaille en degrés au lieu de radians
width 0,1300 : height 0,880
picture 10 : width 10,width(0)-100 : height 10,height(0)-80 : top 10,20 : left 10,50
2d_target_is 10 : print_target_is 10 : 2d_fill_on
font_name 10, "comic sans ms" : font_bold 10 :  font_size 10,16 : color 10,0,255,255

for r = .1 to 7.8 step .1
  for t = 0 to 720 step 2
    x = a * (cos(t) + k * cos(t/2)) : y = a * sin(t)
    rx = r*x : rx1 = rx/2 : rx2 = rx*2 : ry = r*y : ry1 = ry/2 : ry2 = ry*2
    cr = 255-10*r : cg = 55+10*r : cb = t*r/150
    2d_pen_color cr,cg,cb : 2d_fill_color cr,cg,cb
    2d_circle 350 + rx1, 100 - ry1,2 : 2d_circle 650 - rx1 , 100 + ry1,2 : ' les petits poissons du haut
    2d_circle 200 + rx , 300 + ry,4  : 2d_circle 800 - rx , 300 + ry,4   : ' les poissons moyens du centre
    2d_circle 350 + rx2, 600 + ry2,8 : ' le grand poisson du bas
   display
  next t
  if scancode = 27 then terminate
next r

2d_fill_color 255,255,255 : 2d_circle 350+rx1-15,100-ry1,6 : 2d_circle 350+rx1+15,100-ry1,6
2d_fill_color 000,000,000 : 2d_circle 350+rx1-15,100-ry1,4 : 2d_circle 350+rx1+15,100-ry1,4
2d_fill_color 255,255,255 : 2d_circle 200+rx-20,300-ry,9   : 2d_circle 200+rx+20,300-ry,9
2d_fill_color 000,000,000 : 2d_circle 200+rx-20,300-ry,6   : 2d_circle 200+rx+20,300-ry,6
2d_fill_color 255,255,255 : 2d_circle 350+rx2-50,600-ry2,15
2d_fill_color 000,000,000 : 2d_circle 350+rx2-50,600-ry2,10

Coeur(500,060,10,1)  : Coeur(500,140,10,-1)
Coeur(500,250,15,1)  : Coeur(500,350,15,-1)
Coeur(1050,600,20,1) : Coeur(1050,630,20,-1)

2d_pen_color 0,255,255 : 2d_fill_color 0,255,255
caption 0,"<ESC> pour sortir ...."
repeat
    for t = 2 to 40  step 2
        2d_fill_color 255,255,255 : 2d_circle 970+t/2,600-5*t,42-t : pause 50
        2d_fill_color 000,255,255 : 2d_circle 970+t/2,600-5*t,42-t : pause 50
    next t
until scancode = 27

for t = height(0) to 10 step -10 : height 0,t : pause 100 : next t
terminate
rem ============================================================================
rem ============================================================================
' Dessiner un coeur
' Equation paramétrique d'une cardioïde
' x = power(sin(t),3)
' y = cos(t) - power(cos(t),4)
' Paramètres :
' xc,yc : coordonnées du creux de la cardioïde
' r : paramètre agissant sur la forme de la cadioïde
' sens : paramètre indiquant le sens de la cardioîde :
' sens = -1 <==== la pointe est dirigée vers le bas
' sens = +1 <==== la pointe est dirigée vers le haut
SUB Coeur(xc,yc,r,sens)
    dim_local x,y,t,s
    degrees :  2d_pen_color 255,0,0 : 2d_poly_from xc,yc
    if sens <= 0 then s = -1 : else : s = 1
    for t = 0 to 360
        x = power(sin(t),3) : y = cos(t) - power(cos(t),4)
        2d_poly_to xc+r*x,yc+s*r*y +5*s
    next t
    2d_flood xc,yc-s*2,255,0,0
END_SUB
rem ============================================================================


Dernière édition par papydall le Dim 2 Avr 2017 - 1:06, édité 1 fois
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Marc37



Nombre de messages : 443
Age : 56
Localisation : TOURS
Date d'inscription : 18/03/2014

MessageSujet: Re: Nous sommes le 1er Avril : Jour du Poisson d'Avril !   Sam 1 Avr 2017 - 18:43


Trop cool !

Merci Papydall !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 4989
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Nous sommes le 1er Avril : Jour du Poisson d'Avril !   Sam 1 Avr 2017 - 19:59

Il semble, vu le programme, qu'avril est la période du frai pour tes poissons, qu'ils soient frais ou pas. Razz

lol!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Contenu sponsorisé




MessageSujet: Re: Nous sommes le 1er Avril : Jour du Poisson d'Avril !   

Revenir en haut Aller en bas
 
Nous sommes le 1er Avril : Jour du Poisson d'Avril !
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» Besoin de code pour poisson d'avril
» Catimini C'est moi
» Des poissons siamois pour le 1er Avril
» Redirigé automatiquement
» Pluie de poisson d'avril

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC 32 bits :: Vos sources, vos utilitaires à partager-
Sauter vers: