FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» Mah-Jong américain
par Jean Claude Hier à 19:37

» StratégoV8 et V9
par Jean Claude Hier à 13:18

» Problème avec Deepl
par Klaus Hier à 0:34

» Déformation d'image en trapèze
par Klaus Dim 14 Jan 2018 - 16:22

» Quelques nouvelles ...
par Jean Claude Ven 12 Jan 2018 - 22:40

» Renommer les instructions ITEM_... ?
par Jicehel Ven 12 Jan 2018 - 18:56

» Ludothèque Panoramic
par jjn4 Ven 12 Jan 2018 - 18:11

» sous-programmes et fonctions
par Jack Ven 12 Jan 2018 - 17:51

» KGF_dll - nouvelles versions
par Minibug Ven 12 Jan 2018 - 0:21

» Mah-Jong français
par Jean Claude Jeu 11 Jan 2018 - 22:15

» HVIEWER
par Klaus Mer 10 Jan 2018 - 2:06

» panoramic 0.9.28
par gigi75 Ven 5 Jan 2018 - 14:06

» Un jeu qui va vous énerver!
par Jean Claude Jeu 4 Jan 2018 - 22:05

» Bonne fêtes de fin d'année ! Meilleurs Vœux 2018 !
par Jicehel Jeu 4 Jan 2018 - 17:28

» Mah-Jong international
par jjn4 Jeu 4 Jan 2018 - 16:55

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Janvier 2018
LunMarMerJeuVenSamDim
1234567
891011121314
15161718192021
22232425262728
293031    
CalendrierCalendrier

Partagez | 
 

 SrcMapMaker

Voir le sujet précédent Voir le sujet suivant Aller en bas 
AuteurMessage
Yannick

avatar

Nombre de messages : 8009
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: SrcMapMaker   Sam 11 Mar 2017 - 5:34

Un petit utilitaire pour penser son projet et en faire un plan...

Fonctionne avec KGF
Crée son dossier de stockage des fichiers dans Mes documents

Une fois le plan établit, un petit clic sur la 5eme icone et le projet est créé sur le bureau.

Code:
hide 0
variables()
constantes()
labels()
init()
form_principal()
  show picttbI%(3)
  show picttbI%(4)
  show picttbI%(5)
  ActiveInactiveEB(0)
show 0
end

' ==============================================================================
' !DECLARATIONS
' ==============================================================================

' !> VARIABLES
  sub variables()
' !>> Incrémentation
      dim no%
' !>> Position de la souris sur les barres de menu
      dim xtb%
      dim yeb%
' !>> Boutons actifs des barres
      dim tb_active%
      dim eb_active%
' !>> Etat de l' application
      dim appli_etat% :' 0 vide, 1 fichier ouvert, 2 fichier ouvert modifié
' !>> Projet
      dim projet$ :' nom du projet
      dim scriptfiledl$ :' fichier du dlist
      dim scriptfiletv$ :' fichier du treeview
' !>> Infos TV
      dim TVselectedNode%
      dim TVselectedText$
      dim TVselectedNiv%
      dim TVselectedChilds%
      dim TVselectedico%
  end_sub
' ------------------------------------------------------------------------------
 
' !> CONSTANTES
  sub constantes()
      dim_local i%

' !>> Dossier racine
      dim path$ : path$=dir_current$
      if right$(path$,1)="\" : path$=left$(path$,len(path$)-1) : end_if
      path$=path$+"\"

' !>> Dossiers application
      dim dir_img$    : dir_img$ = path$+"img\"
      dim dir_help$  : dir_help$ = path$+"help\"
      dim dir_desk$  :' sera défini dans init()
      dim dir_script$ :' sera défini dans init()
     
' !>> Fichiers dll
      dim kgf$        : kgf$ = "C:\KGF\KGF.dll"
' !>> Fichiers help
      dim help$(5)      : for i%=1 to 5  : help$(i%) = dir_help$+"Aide_"+str$(i%)+".inf"  : next i%
' !>> Fichiers images
'    treeview
      dim img_tv$(10)  : for i%=1 to 10 : img_tv$(i%) = dir_img$+"picto_"+str$(i%)+".bmp" : next i%
      dim images_tv$    : images_tv$= dir_img$+"tv_lib.ilb"
'    toolbar
      dim img_tb$      : img_tb$= dir_img$+"tb.bmp"
      dim imgO_tb$(5)  : for i%=1 to 5  : imgO_tb$(i%)= dir_img$+"tb_1"+str$(i%)+".bmp"  : next i%
      dim imgC_tb$(5)  : for i%=1 to 5  : imgC_tb$(i%)= dir_img$+"tb_2"+str$(i%)+".bmp"  : next i%
      dim imgI_tb$(5)  : for i%=1 to 5  : imgI_tb$(i%)= dir_img$+"tb_0"+str$(i%)+".bmp"  : next i%
'    editbar
      dim img_eb$      : img_eb$= dir_img$+"eb.bmp"
      dim imgO_eb$(5)  : for i%=1 to 5  : imgO_eb$(i%)= dir_img$+"eb_1"+str$(i%)+".bmp"  : next i%
      dim imgC_eb$(5)  : for i%=1 to 5  : imgC_eb$(i%)= dir_img$+"eb_2"+str$(i%)+".bmp"  : next i%
      dim imgI_eb$(5)  : for i%=1 to 5  : imgI_eb$(i%)= dir_img$+"eb_0"+str$(i%)+".bmp"  : next i%
'    etat appli
      dim img_etat0$    : img_etat0$ = dir_img$+"etat0.bmp"
      dim img_etat1$    : img_etat1$ = dir_img$+"etat1.bmp"
      dim img_etat2$    : img_etat2$ = dir_img$+"etat2.bmp"
     
' !>> Objets
'    objets panoramic
'    objet cachés pour objets kgf
      dim edi_tv%      : no%=no%+1      : edi_tv%=no%
'    form principal
      dim pan_tb%      : no%=no%+1      : pan_tb%=no%
      dim pan_eb%      : no%=no%+1      : pan_eb%=no%
      dim pan_tv%      : no%=no%+1      : pan_tv%=no%
      dim pan_sb%      : no%=no%+1      : pan_sb%=no%
      dim picttb%      : no%=no%+1      : picttb%=no%
      dim picttbO%(5)  : for i%=1 to 5  : no%=no%+1  : picttbO%(i%)=no% : next i%
      dim picttbI%(5)  : for i%=1 to 5  : no%=no%+1  : picttbI%(i%)=no% : next i%
      dim pictetat%    : no%=no%+1      : pictetat%=no%
      dim picteb%      : no%=no%+1      : picteb%=no%
      dim pictebO%(5)  : for i%=1 to 5  : no%=no%+1  : pictebO%(i%)=no% : next i%
      dim pictebI%(5)  : for i%=1 to 5  : no%=no%+1  : pictebI%(i%)=no% : next i%
      dim memobidon%    : no%=no%+1      : memobidon%=no%
      dim listhelp%    : no%=no%+1      : listhelp%=no%
      dim dlistscript%  : no%=no%+1      : dlistscript%=no%
'    boites de dialogue
      dim odial%        : no%=no%+1      : odial%=no%
      dim sdial%        : no%=no%+1      : sdial%=no%
'    fichiers en lecture/ecriture
      dim f_or%        : no%=no%+1      : f_or%=no%
      dim f_ow%        : no%=no%+1      : f_ow%=no%
'    objets kgf
      dim TV%
      dim IL%

' !> COULEURS KGF
' !>> Couleur du texte du treeview
      dim TVtextcolor%    : TVtextcolor%=(127*256+85)*256+85
      dim TVtextcolorsel% : TVtextcolorsel%=(0*256+0)*256+255
'      message str$(TVtextcolor%)+chr$(13)+str$(TVtextcolorsel%)
  end_sub
' ------------------------------------------------------------------------------

' !> LABELS
  sub labels()
' !>> Evénements généraux
      label clic_tb  :' clics de la toolbar
      label clic_eb  :' clics de la editbar
      label change
      label dclic
' !>> Redimensionnement du form 0
      label Resize0
' !>> Evénements toolbar
      label movepantb
      label movepicttb
      label downpicttb
      label uppicttb
' !>> Evénements editbar
      label movepaneb
      label movepicteb
      label downpicteb
  end_sub
' ------------------------------------------------------------------------------

' ==============================================================================
' !INITIALISATION
' ==============================================================================

' !> INIT
  sub init()
      dim_local res%,i%,bmp$
     
' !>> Activation de la dll
      dll_on kgf$
     
' !>> Récupération de l' adresse du bureau
      dir_desk$ = string$(511," ")
      res% = dll_call2("GetWindowsFoldersPath",0,adr(dir_desk$))
      dir_desk$ = trim$(dir_desk$)+"\"

' !>> Création du dossier de sauvegarde des script
      dir_script$ = string$(511," ")
      res% = dll_call2("GetWindowsFoldersPath",5,adr(dir_script$))
      dir_script$ = trim$(dir_script$)+"\SrcMapMaker\"
      if dir_exists(dir_script$)=0 then dir_make dir_script$
     
' !>> Création de l' imagelist pour l' objet treeview
      IL% = dll_call2("CreateImageList",16,16)
      for i%=1 to 10
        bmp$ = img_tv$(i%)
        res% = dll_call4("AddImageToImageList",IL%,adr(bmp$),0,0)
      next i%
      res% = dll_call2("SaveImageList",IL%,adr(images_tv$))

  end_sub
' ------------------------------------------------------------------------------

' ==============================================================================
' !INTERFACE
' ==============================================================================

' !> FORM PRINCIPAL
  sub form_principal()
      dim_local i%,res%,l%,t%,txt$
     
      height 0,550
      width 0,900
      top 0,(screen_y-height(0))/2
      left 0,(screen_x-width(0))/2
     
      color 0,230,230,230
     
      font_name 0,"Arial"
      font_size 0,8
      font_bold 0
     
      caption 0,"Src Map Maker"
     
      create_hide
      edit edi_tv% : on_change edi_tv%,change
      create_show
     
      panel pan_tb%
      height pan_tb%,32
      width pan_tb%,width_client(0)-10
      top pan_tb%,5
      left pan_tb%,5
      on_mouse_move pan_tb%,movepantb
     
        picture picttb%
        parent picttb%,pan_tb%
        height picttb%,24
        width picttb%,120
        top picttb%,4
        left picttb%,4
        file_load picttb%,img_tb$
        on_mouse_move picttb%,movepicttb
     
        create_hide
        l%=4
        for i%= 1 to 5
       
            picture picttbO%(i%)
            parent picttbO%(i%),pan_tb%
            height picttbO%(i%),24
            width picttbO%(i%),24
            top picttbO%(i%),4
            left picttbO%(i%),l%
            file_load picttbO%(i%),imgO_tb$(i%)
            cursor_point picttbO%(i%)
            on_mouse_down picttbO%(i%),downpicttb
            on_mouse_up picttbO%(i%),uppicttb
            on_click picttbO%(i%),clic_tb

            picture picttbI%(i%)
            parent picttbI%(i%),pan_tb%
            height picttbI%(i%),24
            width picttbI%(i%),24
            top picttbI%(i%),4
            left picttbI%(i%),l%
            file_load picttbI%(i%),imgI_tb$(i%)

            l%=l%+24
        next i%
        create_show
       
        picture pictetat%
        parent pictetat%,pan_tb%
        height pictetat%,24
        width pictetat%,24
        top pictetat%,4
        left pictetat%,width(pan_tb%)-width(pictetat%)-5
        file_load pictetat%,img_etat0$
     
      panel pan_eb%
      height pan_eb%,height_client(0)-152
      width pan_eb%,300
      top pan_eb%,top(pan_tb%)+height(pan_tb%)+5
      left pan_eb%,5
      on_mouse_move pan_eb%,movepaneb
     
        picture picteb%
        parent picteb%,pan_eb%
        height picteb%,160
        width picteb%,290
        top picteb%,5
        left picteb%,5
        file_load picteb%,img_eb$
        on_mouse_move picteb%,movepicteb
       
        create_hide
        t%=5
        for i%= 1 to 5

            picture pictebO%(i%)
            parent pictebO%(i%),pan_eb%
            height pictebO%(i%),32
            width pictebO%(i%),290
            top pictebO%(i%),t%
            left pictebO%(i%),5
            file_load pictebO%(i%),imgO_eb$(i%)
            cursor_point pictebO%(i%)
            on_mouse_down pictebO%(i%),downpicteb
            on_click pictebO%(i%),clic_eb

            picture pictebI%(i%)
            parent pictebI%(i%),pan_eb%
            height pictebI%(i%),32
            width pictebI%(i%),290
            top pictebI%(i%),t%
            left pictebI%(i%),5
            file_load pictebI%(i%),imgI_eb$(i%)

            t%=t%+32
        next i%
        create_show
       
      panel pan_tv%
      height pan_tv%,height_client(0)-152
      width pan_tv%,width_client(0)-width(pan_eb%)-15
      top pan_tv%,top(pan_tb%)+height(pan_tb%)+5
      left pan_tv%,width_client(0)-width(pan_tv%)-5
     
        TV% = dll_call3("CreateTreeViewEx",handle(pan_tv%),1,adr(images_tv$))
        res% = dll_call3("SetTreeViewEventReceiver",TV%,1,handle(edi_tv%))
        res% = dll_call5("ResizeTreeView",TV%,5,5,width(pan_tv%)-10,height(pan_tv%)-10)
        res% = dll_call4("SetTreeViewOptions",TV%,1,4,1)
        res% = dll_call4("SetTreeViewOptions",TV%,1,2,TVtextcolor%)
        res% = dll_call4("SetTreeViewOptions",TV%,1,3,TVtextcolorsel%)

      panel pan_sb%
      height pan_sb%,100
      width pan_sb%,width_client(0)-10
      top pan_sb%,height_client(0)-height(pan_sb%)-5
      left pan_sb%,5
     
        list listhelp%
        parent listhelp%,pan_sb%
        height listhelp%,height(pan_sb%)-10
        width listhelp%,width(pan_sb%)-10
        top listhelp%,5
        left listhelp%,5
        font_bold listhelp%
        color listhelp%,250,250,205
        font_color listhelp%,190,90,255
     
      dlist dlistscript%

      on_resize 0,Resize0
  end_sub
' ------------------------------------------------------------------------------
' ==============================================================================
' !MENU
' ==============================================================================

' !> EVENEMENTS CLIC
  clic_tb:

      if number_click = picttbO%(1)
        Nouveau()
        return
      end_if

      if number_click = picttbO%(2)
        Ouvrir()
        return
      end_if
     
      if number_click = picttbO%(3)
        Fermer()
        return
      end_if

      if number_click = picttbO%(4)
        Enregistrer()
        return
      end_if
     
      if number_click = picttbO%(5)
        CreateProject()
        return
      end_if
  return
' ------------------------------------------------------------------------------

  clic_eb:
      hide pictebO%(eb_active%)
      file_load pictebO%(eb_active%),imgO_eb$(eb_active%)
      on_mouse_down pictebO%(eb_active%),downpicteb
     
      if number_click = pictebO%(1)
        AddFile()
        return
      end_if
     
      if number_click = pictebO%(2)
        AddSection()
        return
      end_if
     
      if number_click = pictebO%(3)
        AddSsSection()
        return
      end_if
     
      if number_click = pictebO%(4)
        AddCommentaire()
        return
      end_if
     
      if number_click = pictebO%(5)
        DeleteNode()
        return
      end_if
     
  return
' ------------------------------------------------------------------------------

' !> EVENEMENTS CHANGE
  change:
      off_change edi_tv%
      RecupInfoTreeview()
      on_change edi_tv%,change
  return
' ------------------------------------------------------------------------------

' !> EVENEMENTS DOUBLE CLIC
  dclic:
  return
' ------------------------------------------------------------------------------

' !> REDIMENSIONNEMENT DU FORM PRINCIPAL
  Resize0:
      ResizeFormPrincipal()
  return
' ------------------------------------------------------------------------------

' !> GESTION DU MENU TOOLBAR
' !>> Evenement mouse_move sur panel toolbar
  movepantb:
      off_mouse_move pan_tb%
      ResetToolbar()
      on_mouse_move pan_tb%,movepantb
  return
' !>> Evenement mouse_move sur un bouton de zone de la toolbar
  movepicttb:
      off_mouse_move picttb%
      xtb% = mouse_x_position(picttb%)
      ResetToolbar()
      ShowButtonTb()
      on_mouse_move picttb%,movepicttb
  return
' !>> Evenement mouse_down sur un bouton actif de la toolbar
  downpicttb:
      off_mouse_down picttbO%(tb_active%)
      file_load picttbO%(tb_active%),imgC_tb$(tb_active%)
      on_mouse_up picttbO%(tb_active%),uppicttb
  return
' !>> Evenement mouse_up sur un bouton actif de la toolbar
  uppicttb:
      off_mouse_up picttbO%(tb_active%)
      hide picttbO%(tb_active%)
      file_load picttbO%(tb_active%),imgO_tb$(tb_active%)
      on_mouse_down picttbO%(tb_active%),downpicttb
  return
' ------------------------------------------------------------------------------

' !> GESTION DU MENU EDIT
' !>> Evenement mouse_move sur panel editbar
  movepaneb:
      off_mouse_move pan_eb%
      ResetEditbar()
      on_mouse_move pan_eb%,movepaneb
  return
' !>> Evenement mouse_move sur un bouton de zone de la editbar
  movepicteb:
      off_mouse_move picteb%
      yeb% = mouse_y_position(picteb%)
      ResetEditbar()
      ShowButtonEb()
      on_mouse_move picteb%,movepicteb
  return
' !>> Evenement mouse_down sur un bouton actif de la editbar
  downpicteb:
      off_mouse_down pictebO%(eb_active%)
      file_load pictebO%(eb_active%),imgC_eb$(eb_active%)
  return
' ------------------------------------------------------------------------------

' !> GESTION DU TREEVIEW
' ------------------------------------------------------------------------------

' ==============================================================================
' !FONCTIONS
' ==============================================================================

' !> REDIMENSIONNEMENT DU FORM PRINCIPAL

  sub ResizeFormPrincipal()
      dim_local res%
 
      height pan_tb%,32
      width pan_tb%,width_client(0)-10
      top pan_tb%,5
      left pan_tb%,5
     
        height pictetat%,24
        width pictetat%,24
        top pictetat%,4
        left pictetat%,width(pan_tb%)-width(pictetat%)-5
     
      height pan_eb%,height_client(0)-152
      width pan_eb%,300
      top pan_eb%,top(pan_tb%)+height(pan_tb%)+5
      left pan_eb%,5

      height pan_tv%,height_client(0)-152
      width pan_tv%,width_client(0)-width(pan_eb%)-15
      top pan_tv%,top(pan_tb%)+height(pan_tb%)+5
      left pan_tv%,width_client(0)-width(pan_tv%)-5

        res% = dll_call5("ResizeTreeView",TV%,5,5,width(pan_tv%)-10,height(pan_tv%)-10)

      height pan_sb%,100
      width pan_sb%,width_client(0)-10
      top pan_sb%,height_client(0)-height(pan_sb%)-5
      left pan_sb%,5
     
        height listhelp%,height(pan_sb%)-10
        width listhelp%,width(pan_sb%)-10
        top listhelp%,5
        left listhelp%,5
  end_sub

' !> GESTION DE TOOLBAR
' !>> Initialisation de la toolbar
  sub ResetToolbar()
      dim_local i%
     
      for i%=1 to 5
        hide picttbO%(i%)
      next i%
      clear listhelp%
  end_sub
' ------------------------------------------------------------------------------

' !>> Affichage du bouton survolé
  sub ShowButtonTb()
      dim_local x%,y%,i%,p1%,p2%

      p2%=29
      for i%=1 to 5
        if xtb%>p1% and xtb%<p2%
            tb_active%=i%
            show picttbO%(i%)
            exit_for
        end_if
        p1%=p2%-1
        p2%=p2%+24
      next i%
  end_sub
' ------------------------------------------------------------------------------

' !> GESTION DE EDITBAR
' !>> Initialisation de l' editbar
  sub ResetEditbar()
      dim_local i%

      for i%=1 to 5
        hide pictebO%(i%)
      next i%
      clear listhelp%
  end_sub
' ------------------------------------------------------------------------------

' !>> Affichage du bouton survolé
  sub ShowButtonEb()
      dim_local x%,y%,i%,p1%,p2%

      p2%=37
      for i%=1 to 5
        if yeb%>p1% and yeb%<p2%
            eb_active%=i%
            show pictebO%(i%)
            file_load listhelp%,help$(i%)
            exit_for
        end_if
        p1%=p2%-1
        p2%=p2%+32
      next i%
  end_sub
' ------------------------------------------------------------------------------

' !> CREATION D UN PROJET
  sub Nouveau()
      dim_local res%,m%
     
      Fermer()
     
      m%=message_input("Nouveau projet","Nom du projet","")
      if m%=1
        projet$ = message_text$
        scriptfiledl$ = dir_script$+projet$+".ini"
        scriptfiletv$ = dir_script$+projet$+".inf"
        res% = dll_call4("AddTreeViewRootNode",TV%,adr(projet$),1,2)
        appli_etat%=2
        file_load pictetat%,img_etat2$
        hide picttbI%(3)
        hide picttbI%(4)
        hide picttbI%(5)
        ActiveInactiveEB(1)
      end_if
  end_sub
' ------------------------------------------------------------------------------

' !> OUVRIR
  sub Ouvrir()
      dim_local res%,Nprojet$
     
      Fermer()
     
      dir_change dir_script$
      open_dialog odial%
      dir_dialog odial%,dir_script$
      filter odial%,"*.ini|*.ini"
      Nprojet$ = file_name$(odial%)
      delete odial%
      dir_change path$
     
      if Nprojet$<>"_"
        scriptfiledl$ = Nprojet$
        scriptfiletv$ = left$(Nprojet$,len(Nprojet$)-4)+".inf"
        projet$ = file_extract_name$(Nprojet$)
        projet$ = left$(projet$,len(projet$)-4)

        file_load dlistscript%,scriptfiledl$
        res% = dll_call2("LoadTreeViewFromFile",TV%,adr(scriptfiletv$))
        appli_etat%=1
        file_load pictetat%,img_etat1$
        hide picttbI%(3)
        hide picttbI%(4)
        hide picttbI%(5)
        ActiveInactiveEB(1)
      end_if
  end_sub
' ------------------------------------------------------------------------------

' !> FERMER
  sub Fermer()
      dim_local res%,m%,mess$
     
      if appli_etat%<>0
        if appli_etat%=1
            clear dlistscript%
            res% = dll_call1("ClearTreeView",TV%)
            appli_etat%=0
            file_load pictetat%,img_etat0$
        else
            mess$ = "Le fichier en cours a été modifié !"+chr$(13)
            mess$ = mess$+"Voulez vous enregistrer les modifications ?..."
            m%=message_warning_yes_no(mess$)
            if m%=1
              Enregistrer()
            end_if
            clear dlistscript%
            res% = dll_call1("ClearTreeView",TV%)
            appli_etat%=0
            file_load pictetat%,img_etat0$
        end_if
      end_if
      show picttbI%(3)
      show picttbI%(4)
      show picttbI%(5)
      ActiveInactiveEB(0)
  end_sub
' ------------------------------------------------------------------------------

' !> ENREGISTRE LE PROJET EN COURS
  sub Enregistrer()
      dim_local res%

      if projet$=""
        exit_sub
      end_if
      res% = dll_call2("SaveTreeViewToFile",TV%,adr(scriptfiletv$))
      file_save dlistscript%,scriptfiledl$
      appli_etat%=1
      file_load pictetat%,img_etat1$
  end_sub
' ------------------------------------------------------------------------------

' !> ACTIVATION/INACTIVATION DE L EDITBAR
  sub ActiveInactiveEB(AI%)
      dim_local i%
 
      if AI% = 0
        for i%=1 to 5
            show pictebI%(i%)
        next i%
      else
        for i%=1 to 5
            hide pictebI%(i%)
        next i%
      end_if
  end_sub

' ------------------------------------------------------------------------------

' !> RECUP DES INFOS DEPUIS TREEVIEW SUR CLIC
  sub RecupInfoTreeview()
      dim_local t$,action$,par$,i%,res%

      t$      = text$(edi_tv%)
      action$ = left$(t$,instr(t$,",")-1)
      t$      = right$(t$,len(t$)-instr(t$,","))

      TVselectedNode% = val(left$(t$,instr(t$,",")-1))
      TVselectedText$ = right$(t$,len(t$)-instr(t$,","))
      par$ = string$(200," ")
      TVselectedNiv%  = dll_call3("GetTreeViewInformation",TV%,5,adr(par$))
      TVselectedChilds%  = dll_call3("GetTreeViewInformation",TV%,6,adr(par$))
      TVselectedico% = dll_call4("SetTreeViewOptions",TV%,2,6,adr(par$))
  end_sub
' ------------------------------------------------------------------------------

' !> AJOUTER UN FICHIER
  sub AddFile()
      dim_local res%,m%,file$,par$,ok%

      m% = message_input("Ajouter un fichier","Nom du fichier : ","")
      file$ = message_text$
      if m%=1
        if file$<>""
            res% = dll_call3("SelectTreeViewNode",TV%,0,1)
            res% = dll_call4("AddTreeViewChildNode",TV%,adr(file$),3,4)
            appli_etat%=2
            file_load pictetat%,img_etat2$
        else
            m% = message_information_ok("Vous devez donner un nom au fichier.")
        end_if
      end_if
  end_sub
' ------------------------------------------------------------------------------

' !> AJOUTER UNE SECTION
  sub AddSection()
      dim_local res%,m%,section$,par$,mess$
     
      mess$ = "Vous devez sélectionner"+chr$(13)
      mess$ = mess$+"soit un fichier"+chr$(13)
      mess$ = mess$+"soit une section."
      if TVselectedNiv%<>1 and TVselectedNiv%<>2
        m% = message_information_ok(mess$)
        exit_sub
      else
        if TVselectedico% = 9
            m% = message_information_ok(mess$)
            exit_sub
        end_if
      end_if
     
      m% = message_input("Ajouter une section","Nom de la section : ","")
      section$ = message_text$
      if m%=1
        if section$<>""
            if TVselectedNiv%=2
              res% = dll_call5("InsertTreeViewNode",TV%,1,adr(section$),5,6)
            else
              res% = dll_call4("AddTreeViewChildNode",TV%,adr(section$),5,6)
            end_if
            appli_etat%=2
            file_load pictetat%,img_etat2$
        else
            m% = message_information_ok("Vous devez donner un nom à la section.")
        end_if
      end_if
  end_sub
' ------------------------------------------------------------------------------

' !> AJOUTER UNE SOUS SECTION
  sub AddSsSection()
      dim_local res%,m%,Ssection$,par$,mess$

      mess$ = "Vous devez sélectionner"+chr$(13)
      mess$ = mess$+"soit une section"+chr$(13)
      mess$ = mess$+"soit une sous section."
      if TVselectedNiv%<>2 and TVselectedNiv%<>3
        m% = message_information_ok(mess$)
        exit_sub
      else
        if TVselectedico% = 9
            m% = message_information_ok(mess$)
            exit_sub
        end_if
      end_if
     
      m% = message_input("Ajouter une section","Nom de la sous section : ","")
      Ssection$ = message_text$
      if m%=1
        if Ssection$<>""
            if TVselectedNiv%=3
              res% = dll_call5("InsertTreeViewNode",TV%,1,adr(Ssection$),7,8)
            else
              res% = dll_call4("AddTreeViewChildNode",TV%,adr(Ssection$),7,8)
            end_if
            appli_etat%=2
            file_load pictetat%,img_etat2$
        else
            m% = message_information_ok("Vous devez donner un nom à la sous section.")
        end_if
      end_if
  end_sub
' ------------------------------------------------------------------------------

' !> AJOUTER UN COMMENTAIRE
  sub AddCommentaire()
      dim_local res%,m%,com$,par$,mess$

      mess$ = "Vous devez sélectionner"+chr$(13)
      mess$ = mess$+"soit un fichier"+chr$(13)
      mess$ = mess$+"soit une section"+chr$(13)
      mess$ = mess$+"soit une sous section."
      if TVselectedNiv%=0
        m% = message_information_ok(mess$)
        exit_sub
      end_if
     
      m% = message_input("Ajouter un commentaire","Commentaire : ","")
      com$ = message_text$
      if m%=1
        if com$<>""
            if TVselectedico%=9
              res% = dll_call5("InsertTreeViewNode",TV%,1,adr(com$),9,10)
            else
              res% = dll_call4("AddTreeViewChildNode",TV%,adr(com$),9,10)
            end_if
            appli_etat%=2
            file_load pictetat%,img_etat2$
        else
            m% = message_information_ok("Un commentaire ne peut pas être vide.")
        end_if
      end_if
  end_sub
' ------------------------------------------------------------------------------

' !> SUPPRIMER UN NOEUD
  sub DeleteNode()
      dim_local res%
     
      res% = dll_call1("DeleteTreeViewNode",TV%)
      appli_etat%=2
      file_load pictetat%,img_etat2$
  end_sub
' ------------------------------------------------------------------------------

' !> CREATION DU PROJET
  sub CreateProject()
      dim_local res%,pathproject$,par$,Nelement%,ind%,txt$,niv%,nfile%,ico%,m%
     
      pathproject$ = dir_desk$+projet$+"\"

      if dir_exists(pathproject$)=1
        m% = message_warning_yes_no("Un dossier du même nom existe sur vôtre bureau !"+chr$(13)+"Voulez vous le remplacer ?...")
        if m%<>1
            exit_sub
        else
            res% = dll_call1("DeleteFileToRecycleBin",adr(pathproject$))
        end_if
      end_if
     
      dir_make pathproject$
      Nelement% = dll_call3("GetTreeViewInformation",TV%,0,adr(par$))

      for ind%=1 to Nelement%
        res% = dll_call3("SelectTreeViewNode",TV%,ind%,1)
        txt$ = string$(200," ")
        res% = dll_call3("GetTreeViewInformation",TV%,2,adr(txt$))
        txt$ = trim$(txt$)
        par$ = string$(200," ")
        niv% = dll_call3("GetTreeViewInformation",TV%,5,adr(par$))
        par$ = trim$(par$)
        ico% = dll_call4("SetTreeViewOptions",TV%,2,6,adr(par$))

        if niv%=1 and ico%<>9
            if nfile%= 1
              file_close f_ow%
            end_if
            file_open_write f_ow%,pathproject$+txt$+".bas"
            file_writeln f_ow%,"' "+string$(78,"=")
            file_writeln f_ow%,"' "+txt$
            file_writeln f_ow%,"' "+string$(78,"=")
            nfile%= 1
        end_if
           
        if niv%=2 and ico%<>9
            file_writeln f_ow%,""
            file_writeln f_ow%,"' > "+txt$
        end_if
       
        if niv%=3 and ico%<>9
            file_writeln f_ow%,"' >> "+txt$
        end_if
       
        if ico%=9
            file_writeln f_ow%,"' "+txt$
        end_if
       
        if ind%=Nelement%
            file_close f_ow%
        end_if
      next ind%
  end_sub

Le fichier zip avec les images et les fichiers d' aide sont sur mon webdav.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
 
SrcMapMaker
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 1 sur 1

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Vos sources, vos utilitaires à partager-
Sauter vers: