FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» Immortaliser les photos de famille
par Jean Claude Hier à 21:24

» Concours de Morpions
par jjn4 Hier à 16:34

» Tout est tranquille
par Jean Claude Ven 22 Sep 2017 - 21:41

» Texte en gif animé
par JL35 Ven 22 Sep 2017 - 13:29

» BasicEditor
par Yannick Mer 20 Sep 2017 - 17:17

» Simuler l’appui d'une touche ou combinaison de touches.
par pascal10000 Lun 18 Sep 2017 - 19:30

» Utilisation de HVIEWER pour afficher des images
par papydall Lun 18 Sep 2017 - 17:43

» Panoramic et les gifs animés.
par papydall Lun 18 Sep 2017 - 16:32

» recover source
par pascal10000 Dim 17 Sep 2017 - 14:21

» Recent dans vos menu
par Jean Claude Sam 16 Sep 2017 - 11:41

» Comment centrer un texte 3D.
par pascal10000 Ven 15 Sep 2017 - 20:20

» Carte interface 16 entrées et 16 sorties
par Jicehel Ven 15 Sep 2017 - 16:30

» Version instantanée V 0.9.28i9 possédant l'objet SYNEDIT
par pascal10000 Ven 15 Sep 2017 - 16:20

» Compilateur FBPano
par jean_debord Ven 15 Sep 2017 - 9:59

» 1 (en analyse): 3D_TARGET_IS ne fonctionne pas sur 3D_TEXT
par Jack Jeu 14 Sep 2017 - 19:52

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Septembre 2017
LunMarMerJeuVenSamDim
    123
45678910
11121314151617
18192021222324
252627282930 
CalendrierCalendrier

Partagez | 
 

 Une petite pendule pour Noël

Voir le sujet précédent Voir le sujet suivant Aller en bas 
AuteurMessage
JL35



Nombre de messages : 5951
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Une petite pendule pour Noël   Jeu 22 Déc 2016 - 1:25

Sous la forme d'une sub:
Code:
' Pendule
WIDTH 0,300: HEIGHT 0,300: BORDER_SMALL 0: CAPTION 0,""
PICTURE 1: FULL_SPACE 1
Pendule(1,20,20,200)
TERMINATE
' ===============================================
SUB Pendule(pic%,x%,y%,w%)
' Affichage d'une pendulette de largeur w% en x%,y% du picture pic%
IF LABEL("Finpend") = 0 THEN LABEL Finpend
DIM_LOCAL xc%,yc%,x1%,y1%,r%,rs%,rm%,rh%,s%,m%,h%,et%,al%,a,as,am,ah,sz%,tm$,tt$
ON_CLICK pic%,Finpend
al% = pic%+1: WHILE OBJECT_EXISTS(al%)=1: al% = al%+1: END_WHILE
r% = w%/2-10: xc% = x%+r%+5: yc% = y%+r%+5
ALPHA al%: TOP al%,yc%+r%+5: LEFT al%,xc%-2*r%/3: COLOR al%,164,164,164
FONT_NAME al%,"Digital-7 Mono": sz% = r%/5: FONT_SIZE al%,sz%: FONT_BOLD al%
rs% = 9*r%/10: rm% = 9*rs%/10: rh% = 7*rm%/10: ' aiguilles sec, min, heures
et% = r%/20: ' épaisseur trait (secondes)
2D_TARGET_IS pic%
2D_FILL_COLOR 192,128,0: 2D_PEN_WIDTH 3
2D_RECTANGLE xc%-r%-10,yc%-r%-10,xc%+r%+10,yc%+r%+sz%+25: 2D_FILL_COLOR 255,255,255
2D_PEN_WIDTH 3: 2D_CIRCLE xc%,yc%,r%+2
2D_PEN_WIDTH 1: 2D_CIRCLE xc%,yc%,rs%+5
as = 2*PI/60: ' angle 1 seconde
ah = 2*PI/12
am = 2*PI/60
FOR s% = 0 TO 59
    a = s%*as: x1% = xc%+(rs%-5)*SIN(a): y1% = yc%-(rs%-5)*COS(a)
    x% = xc%+r%*SIN(a): y% = yc%-r%*COS(a)
    2D_PEN_WIDTH 1: IF s%/5 = INT(s%/5) THEN 2D_PEN_WIDTH 5
    2D_LINE x1%,y1%,x%,y%
NEXT s%
WHILE 2>1
  tm$ = TIME$: tt$ = tm$
  WHILE tm$ = tt$: PAUSE 100: tm$ = TIME$: END_WHILE
  CAPTION al%," "+TIME$+" "
  h% = VAL(LEFT$(tm$,2)): m%=VAL(MID$(tm$,4,2)): s%=VAL(RIGHT$(tm$,2))
  IF h%>11 THEN h% = h%-12
  2D_PEN_WIDTH 1: 2D_CIRCLE xc%,yc%,rs%+5
  a = ah*(h%+m%/60): x% = xc%+rh%*SIN(a): y% = yc%-rh%*COS(a)
  2D_PEN_WIDTH r%/10: 2D_LINE xc%,yc%,x%,y%
  a = am*(m%+s%/60): x% = xc%+rm%*SIN(a): y% = yc%-rm%*COS(a)
  2D_LINE xc%,yc%,x%,y%
  a = as*s%: x% = xc%+rs%*SIN(a): y% = yc%-rs%*COS(a)
  2D_PEN_WIDTH et%: 2D_PEN_COLOR 255,0,0
  2D_FILL_COLOR 255,0,0: 2D_CIRCLE xc%,yc%,r%/10: 2D_FILL_COLOR 255,255,255
  2D_LINE xc%,yc%,x%,y%: 2D_PEN_COLOR 0,0,0
END_WHILE
Finpend:
PAUSE 250: DELETE al%: CLS
END_SUB
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5531
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Une petite pendule pour Noël   Jeu 22 Déc 2016 - 15:16

... Et en attendant Noël ...

Code:

rem ============================================================================
rem           Compte à rebours
rem              Par Papydall
rem ============================================================================

label compte_a_rebours
dim dat1,dat2,sec,j,h,mn,n
dim result,dif,temp,t$
dim heure,minute,seconde,jour,mois,annee
dim heure2,minute2,seconde2,jour2,mois2,annee2

top 0,50 : left 0,screen_x-500 : width 0,480 : height 0,100
color 0,220,150,50 : font_color 0,0,0,255 : font_bold 0: font_size 0,14
caption 0,"Compte à rebours : Noël 2016"
alpha 10 : top 10,20 : left 10,10
timer 20 : on_timer 20, compte_a_rebours
n = 24*3600 : ' nombre de secondes dans une journée
rem ============================================================================
'  Indiquer ici la date et l'heure du compte à rebours
rem ============================================================================
' jour2 = 01 : mois2 = 01 : annee2 = 2017  : t$ =  "Nouvel an 2017," : ' Nouvel an
jour2 = 25 : mois2 = 12 : annee2 = 2016  : t$ =  "Noël 2016, " : ' Noël
heure2 = 00 : minute2 = 00 : seconde2 = 00
rem ============================================================================
Jour_Julien(jour2,mois2,annee2)    : dat2 = result
Frac_Jour(heure2,minute2,seconde2) : dat2 = dat2 + result
end
rem ============================================================================
compte_a_rebours:
  Get_Date_heure()
  Jour_Julien(jour,mois,annee)    : dat1 = result
  Frac_Jour(heure,minute,seconde) : dat1 = dat1 + result
  dif = (dat2-dat1) * n

  if dif > 0
      j = int(dif/n) : temp = dif - j*n
      h = int(temp/3600) : temp = temp -h*3600
      mn = int(temp/60) : temp = temp - mn*60
      sec = int(temp)
      caption 10, t$ + " c'est dans : " + str$(j) +" j "+str$(h)+" h "+str$(mn)+" mn " +str$(sec)+" s"
  else
      timer_off 20
      caption 10, "L'heure de " + t$ + " est déjà dépassée !"
  end_if
return

rem ============================================================================
' Déterminer le Jour Julien à partir d'une date
SUB Jour_Julien(jour,mois,annee)
    dim_local a,b,d,m,y
    d = jour : m = mois : y = annee
    if m < 3 then y = y - 1 : m = m + 12
    a = int(y/100) : b = 2 - a + int(a/4)
    result = int(365.25*(y+4716)) + int(30.6001*(m+1)) + d + b - 1524.5
END_SUB
rem ============================================================================
' Lire la date et l'heuree système
SUB Get_Date_heure()
    heure = val(mid$(time$,1,2)) : minute  = val(mid$(time$,4,2)) : seconde = val(mid$(time$,7,4))
    jour  = val(mid$(date$,1,2)) : mois    = val(mid$(date$,4,2)) : annee   = val(mid$(date$,7,4))
END_SUB
rem ============================================================================
SUB Frac_Jour(heure,minute,seconde)
    result = (seconde + minute*60 + heure*3600)/n
END_SUB
rem ============================================================================
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
mindstorm

avatar

Nombre de messages : 533
Age : 48
Localisation : charente
Date d'inscription : 13/02/2013

MessageSujet: Re: Une petite pendule pour Noël   Jeu 22 Déc 2016 - 20:28

Peut On l'accélérer pour avoir les cadeaux plus vite?

Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5531
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Une petite pendule pour Noël   Jeu 22 Déc 2016 - 20:51

mindstorm a écrit:
Peut On l'accélérer pour avoir les cadeaux plus vite?

De cette façon, tu perds le goût de l’attente !
Laisse les choses arriver en leur temps pour mieux les apprécier.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Contenu sponsorisé




MessageSujet: Re: Une petite pendule pour Noël   

Revenir en haut Aller en bas
 
Une petite pendule pour Noël
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» Petite demande pour mon formulaire
» Petite changement pour ma barre de navigation
» Une petite cloune
» petite chanson pour les fans de st gab
» petite aide pour quelques détails d'une PA.

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Vos sources, vos utilitaires à partager-
Sauter vers: