FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» KGF.dll - demandes ou suggestions de modifications ou ajouts
par pascal10000 Aujourd'hui à 17:49

» Cartes de voeux, menus, etc.
par JL35 Aujourd'hui à 17:48

» Mah-Jong européen new-look
par jjn4 Aujourd'hui à 15:48

» a l'aide klaus
par Minibug Aujourd'hui à 11:42

» KGF_dll - nouvelles versions
par Minibug Aujourd'hui à 1:48

» bug SYNEDIT_TARGET_IS_OBJECT
par Jack Aujourd'hui à 0:16

» Jukebox : Serge Reggiani
par papydall Sam 9 Déc 2017 - 5:58

» Ecouter la radio fm sur votre pc
par pascal10000 Sam 9 Déc 2017 - 3:42

» anomalie
par Klaus Sam 9 Déc 2017 - 3:21

» hommage
par Jicehel Ven 8 Déc 2017 - 11:29

» Logiciel de soutien scolaire en langues.
par Pedro Alvarez Ven 8 Déc 2017 - 10:43

» carte son
par Klaus Ven 8 Déc 2017 - 2:37

» API Windows
par Klaus Jeu 7 Déc 2017 - 21:03

» mise a jour calculatrice
par joeeee2017 Mer 6 Déc 2017 - 22:19

» j'ai un petit problème
par JL35 Mer 6 Déc 2017 - 21:58

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Décembre 2017
LunMarMerJeuVenSamDim
    123
45678910
11121314151617
18192021222324
25262728293031
CalendrierCalendrier

Partagez | 
 

 Boutons (un peu) fantaisie

Voir le sujet précédent Voir le sujet suivant Aller en bas 
AuteurMessage
JL35



Nombre de messages : 6018
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Boutons (un peu) fantaisie   Ven 18 Nov 2016 - 17:57

Une petite sub pour des boutons un peu plus variés:
Code:
BUTTON 1: TOP 1,10: LEFT 1,20: WIDTH 1,100: CAPTION 1,"Bouton Panoramic"
Bouton(2,20,45,100,25,"Bouton perso")
Bouton(3,20,80,40,25,"Wingdings,14;"+CHR$(231))
Bouton(4,70,80,40,25,"Wingdings,14;"+CHR$(232))
Bouton(5,120,80,50,25,"Wingdings,14;"+CHR$(231)+CHR$(232))
Bouton(6,180,80,50,40,"Webdings,20;"+CHR$(71))
Bouton(7,20,120,80,35,"Au clair<de la lune")
END


SUB Bouton(n%,x%,y%,w%,h%,txt$)
  ' Dessin d'un bouton multilignes, en x%,y%, taille w% x h% -> Picture n%
  ' texte txt$ centré H et V, lignes séparées par le caractère '<'
  ' Texte police Arial taille 9 implicites, modulables:
  ' txt$ = [Police,taille;]Texte
  ' Exemple: Bouton(n,x,y,w,h,"Wingdings,14;"+CHR$(232)): -> flèche graphique
  '      ou  Bouton(n,x,y,w,h,"Titre du bouton")
  DIM_LOCAL i%,k%,b$,nl%,a$(10),lg%,wt%,ht%,hl%
  DIM_LOCAL n2d%,npt%: n2d% = NUMBER_2D_TARGET: npt% = NUMBER_PRINT_TARGET
  PICTURE n%: TOP n%,y%: LEFT n%,x%: WIDTH n%,w%: HEIGHT n%,h%
  2D_TARGET_IS n%: 2D_FILL_COLOR 215,215,215: 2D_PEN_COLOR 180,180,180
  2D_RECTANGLE 0,0,w%-1,h%-1
  2D_PEN_COLOR 0,0,0: 2D_LINE 1,h%-1,w%-1,h%-1: 2D_POLY_TO w%-1,1
  PRINT_TARGET_IS n%: FONT_NAME n%,"Arial": FONT_SIZE n%,9
  k% = INSTR(txt$,";")
  IF k% > 0
      b$ = LEFT$(txt$,k%-1): txt$ = RIGHT_POS$(txt$,k%+1): k% = INSTR(b$,",")
      FONT_NAME n%,LEFT$(b$,k%-1): FONT_SIZE n%,VAL(RIGHT_POS$(b$,k%+1))
  END_IF
  nl% = 1: b$ = txt$: a$(1) = txt$: hl% = TEXT_HEIGHT(txt$,n%)
  k% = INSTR(txt$,"<")
  WHILE k%>0
    a$(nl%)=LEFT$(b$,k%-1): nl%=nl%+1: b$=RIGHT_POS$(b$,k%+1): k%=INSTR(b$,"<")
  END_WHILE
  a$(nl%) = b$: hl% = hl%-2: ht% = nl%*hl%: k% = (h%-ht%)/2-2
  FOR i% = 1 TO nl%
      wt% = TEXT_WIDTH(a$(i%),n%)
      PRINT_LOCATE (w%-wt%)/2,k%: PRINT a$(i%): k%=k%+hl%
  NEXT i%
  PRINT_TARGET_IS npt%: 2D_TARGET_IS n2d%
END_SUB


Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 5086
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Boutons (un peu) fantaisie   Ven 18 Nov 2016 - 20:47

Super tes boutons, JL35 !

Tiens, je propose un plus: une animation du click (Une sub que j'avais déjà et que j'ai juste copiée/collée)

Code:
' Boutons JL35

LABEL Acdll
BUTTON 1: TOP 1,10: LEFT 1,20: WIDTH 1,100: CAPTION 1,"Bouton Panoramic"
Bouton(2,20,45,100,25,"Bouton perso")
Bouton(3,20,80,40,25,"Wingdings,14;"+CHR$(231))
Bouton(4,70,80,40,25,"Wingdings,14;"+CHR$(232))
Bouton(5,120,80,50,25,"Wingdings,14;"+CHR$(231)+CHR$(232))
Bouton(6,180,80,50,40,"Webdings,20;"+CHR$(71))
Bouton(7,20,120,80,35,"Au clair<de la lune")
on_click 7,Acdll
END
rem ============================================================================

Acdll:
  anime_bouton(number_click)
  message "Au clair<de la lune"
RETURN

SUB Bouton(nobj%,locx%,locy%,locw%,loch%,loctxt$)
  ' Dessin d'un bouton multilignes, en locx%,locy%, taille locw% x loch% -> Picture nobj%
  ' texte loctxt$ centré H et V, lignes séparées par le caractère '<'
  ' Texte police Arial taille 9 implicites, modulables:
  ' loctxt$ = [Police,taille;]Texte
  ' Exemple: Bouton(n,x,y,w,h,"Wingdings,14;"+CHR$(232)): -> flèche graphique
  '      ou  Bouton(n,x,y,w,h,"Titre du bouton")
  DIM_LOCAL i%,k%,b$,nl%,a$(10),lg%,wt%,ht%,hl%
  DIM_LOCAL n2d%,npt%: n2d% = NUMBER_2D_TARGET: npt% = NUMBER_PRINT_TARGET
  PICTURE nobj%: TOP nobj%,locy%: LEFT nobj%,locx%: WIDTH nobj%,locw%: HEIGHT nobj%,loch%
  2D_TARGET_IS nobj%: 2D_FILL_COLOR 215,215,215: 2D_PEN_COLOR 180,180,180
  2D_RECTANGLE 0,0,locw%-1,loch%-1
  2D_PEN_COLOR 0,0,0: 2D_LINE 1,loch%-1,locw%-1,loch%-1: 2D_POLY_TO locw%-1,1
  PRINT_TARGET_IS nobj%: FONT_NAME nobj%,"Arial": FONT_SIZE nobj%,9
  k% = INSTR(loctxt$,";")
  IF k% > 0
      b$ = LEFT$(loctxt$,k%-1): loctxt$ = RIGHT_POS$(loctxt$,k%+1): k% = INSTR(b$,",")
      FONT_NAME nobj%,LEFT$(b$,k%-1): FONT_SIZE nobj%,VAL(RIGHT_POS$(b$,k%+1))
  END_IF
  nl% = 1: b$ = loctxt$: a$(1) = loctxt$: hl% = TEXT_HEIGHT(loctxt$,nobj%)
  k% = INSTR(loctxt$,"<")
  WHILE k%>0
    a$(nl%)=LEFT$(b$,k%-1): nl%=nl%+1: b$=RIGHT_POS$(b$,k%+1): k%=INSTR(b$,"<")
  END_WHILE
  a$(nl%) = b$: hl% = hl%-2: ht% = nl%*hl%: k% = (loch%-ht%)/2-2
  FOR i% = 1 TO nl%
      wt% = TEXT_WIDTH(a$(i%),nobj%)
      PRINT_LOCATE (locw%-wt%)/2,k%: PRINT a$(i%): k%=k%+hl%
  NEXT i%
  PRINT_TARGET_IS npt%: 2D_TARGET_IS n2d%
END_SUB

SUB anime_bouton(num_bouton%)
    if object_type(number_click)=9 or object_type(number_click)=6
       ' laisse passer
    else
       exit_sub
    end_if
    dim_local top_bouton%,left_bouton%
    top_bouton%=top(num_bouton%) : left_bouton%=left(num_bouton%)
    top num_bouton%,top_bouton%+2 : left num_bouton%,left_bouton%+2
    pause 150
    top num_bouton%,top_bouton% : left num_bouton%,left_bouton%
END_SUB


A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 5086
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Boutons (un peu) fantaisie   Ven 18 Nov 2016 - 21:07

Allez ! encore un petit plus.

Code:
' Boutons JL35

LABEL Acdll
BUTTON 1: TOP 1,10: LEFT 1,20: WIDTH 1,100: CAPTION 1,"Bouton Panoramic"
Bouton(2,20,45,100,25,"Bouton perso",200,100,50,225,225,225)
Bouton(3,20,80,40,25,"Wingdings,14;"+CHR$(231),0,0,0,225,225,255)
Bouton(4,70,80,40,25,"Wingdings,14;"+CHR$(232),0,0,0,225,225,255)
Bouton(5,120,80,50,25,"Wingdings,14;"+CHR$(231)+CHR$(232),255,0,0,225,225,0)
Bouton(6,180,80,50,40,"Webdings,20;"+CHR$(71),0,100,0,225,225,225)
Bouton(7,20,120,80,35,"Au clair<de la lune",0,0,200,0,225,225)
on_click 7,Acdll
END
rem ============================================================================

Acdll:
  anime_bouton(number_click)
  message "Au clair<de la lune"
RETURN

SUB Bouton(nobj%,locx%,locy%,locw%,loch%,loctxt$,ColorTxtR%,ColorTxtG%,ColorTxtB%,ColorBtR%,ColorBtG%,ColorBtB%)
  ' Dessin d'un bouton multilignes, en locx%,locy%, taille locw% x loch% -> Picture nobj%
  ' texte loctxt$ centré H et V, lignes séparées par le caractère '<'
  ' Texte police Arial taille 9 implicites, modulables:
  ' loctxt$ = [Police,taille;]Texte
  ' Exemple: Bouton(n,x,y,w,h,"Wingdings,14;"+CHR$(232)): -> flèche graphique
  '      ou  Bouton(n,x,y,w,h,"Titre du bouton")
  DIM_LOCAL i%,k%,b$,nl%,a$(10),lg%,wt%,ht%,hl%
  DIM_LOCAL n2d%,npt%: n2d% = NUMBER_2D_TARGET: npt% = NUMBER_PRINT_TARGET
  PICTURE nobj%: TOP nobj%,locy%: LEFT nobj%,locx%: WIDTH nobj%,locw%: HEIGHT nobj%,loch%
  2D_TARGET_IS nobj%: 2D_FILL_COLOR ColorBtR%,ColorBtG%,ColorBtB%: 2D_PEN_COLOR 180,180,180
  2D_RECTANGLE 0,0,locw%-1,loch%-1
  2D_PEN_COLOR 0,0,0: 2D_LINE 1,loch%-1,locw%-1,loch%-1: 2D_POLY_TO locw%-1,1
  PRINT_TARGET_IS nobj%: FONT_NAME nobj%,"Arial": FONT_SIZE nobj%,9
  font_color nobj%,ColorTxtR%,ColorTxtG%,ColorTxtB%
  k% = INSTR(loctxt$,";")
  IF k% > 0
      b$ = LEFT$(loctxt$,k%-1): loctxt$ = RIGHT_POS$(loctxt$,k%+1): k% = INSTR(b$,",")
      FONT_NAME nobj%,LEFT$(b$,k%-1): FONT_SIZE nobj%,VAL(RIGHT_POS$(b$,k%+1))
  END_IF
  nl% = 1: b$ = loctxt$: a$(1) = loctxt$: hl% = TEXT_HEIGHT(loctxt$,nobj%)
  k% = INSTR(loctxt$,"<")
  WHILE k%>0
    a$(nl%)=LEFT$(b$,k%-1): nl%=nl%+1: b$=RIGHT_POS$(b$,k%+1): k%=INSTR(b$,"<")
  END_WHILE
  a$(nl%) = b$: hl% = hl%-2: ht% = nl%*hl%: k% = (loch%-ht%)/2-2
  FOR i% = 1 TO nl%
      wt% = TEXT_WIDTH(a$(i%),nobj%)
      PRINT_LOCATE (locw%-wt%)/2,k%: PRINT a$(i%): k%=k%+hl%
  NEXT i%
  PRINT_TARGET_IS npt%: 2D_TARGET_IS n2d%
END_SUB

SUB anime_bouton(num_bouton%)
    if object_type(number_click)=9 or object_type(number_click)=6
      ' laisse passer
    else
      exit_sub
    end_if
    dim_local top_bouton%,left_bouton%
    top_bouton%=top(num_bouton%) : left_bouton%=left(num_bouton%)
    top num_bouton%,top_bouton%+2 : left num_bouton%,left_bouton%+2
    pause 150
    top num_bouton%,top_bouton% : left num_bouton%,left_bouton%
END_SUB


Y sont pas beaux tes boutons... Very Happy

A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
JL35



Nombre de messages : 6018
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Boutons (un peu) fantaisie   Ven 18 Nov 2016 - 21:30

Sallut Jean Claude,

Certes on peut faire de la fantaisie tant qu'on veut, couleurs, tailles, etc. tu penses bien que j'y ai pensé, mais ça complique sérieusement les paramètres à passer à la sub !

Ce qui est pas mal c'est de visualiser l'enfoncement du bouton au clic...
Dommage que le on_click ne réagisse qu'au relâchement du bouton, et non pas au clic lui-même.

PS Autant pour moi !
Le bouton Panoramic réagit bien lui au moment du clic, et le bouton Picture seulement au moment du relâchement du bouton.
Ou plutôt le bouton Panoramic s'enfonce au moment du clic, mais ne donne la main au s/p [on_click] qu'au moment du relâchement...
Donc c'est bien ce que je disais, l'action ne peut avoir lieu qu'au relâchement.

L'intéressant serait de pouvoir simuler l'enfoncement au clic, comme pour les boutons panoramic. Mais comme on n'est pas prévenu...
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 5086
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Boutons (un peu) fantaisie   Ven 18 Nov 2016 - 23:28

Pour la simulation du click, on peut se rapprocher du bouton Panoramic en changeant le temps de pause dans la SUB anime_bouton(num_bouton%) voir code ci-dessous.

Pour ce qui est de la complexité de la SUB avec tout ces ajouts de paramètres supplémentaires, je suis d'accord avec toi. Mais là c'est au programmeur de faire son choix entre ta version simplifiée ou la mienne plus compliquée.

En tout cas, je suis certain que je vais m'en servir car ça change des boutons Panoramic qui sont assez austères.
Et de plus l'emploi des couleurs peut être très intéressant pour avertir l'utilisateur d'un programme d'un danger (Ex: couleur du texte en rouge = attention !)

Merci et bravo pour ce partage.


Code:
' SUB Bouton(,,,,,,,,,,,,) de JL35 adaptée (pour/et) par Jean Claude  (11/2016)
'
LABEL Acdll
BUTTON 1: TOP 1,10: LEFT 1,20: WIDTH 1,100: CAPTION 1,"Bouton Panoramic"

' SUB  Bouton(nobj%,LeftBt%,ToptBt%,WidthBt%,HeightBt%,CaptionBt$,ColorTxtR%,ColorTxtG%,ColorTxtB%,ColorBtR%,ColorBtG%,ColorBtB%)
' nobj% = numéro du picture (bouton)
' LeftBt%,ToptBt%,WidthBt%,HeightBt% = Position et taille du picture (bouton)
' CaptionBt$ = texte affiché dans le bouton (Titre)
' ColorTxtR%,ColorTxtG%,ColorTxtB% = Couleurs R,G,B du Caption (Titre) du bouton
' ColorBtR%,ColorBtG%,ColorBtB% = Couleurs R,G,B de remplissage du bouton

Bouton(2,20,45,100,25,"Bouton perso",200,100,50,225,225,225)
Bouton(3,20,80,40,25,"Wingdings,14;"+CHR$(231),0,0,0,225,225,255)
Bouton(4,70,80,40,25,"Wingdings,14;"+CHR$(232),0,0,0,225,225,255)
Bouton(5,120,80,50,25,"Wingdings,14;"+CHR$(231)+CHR$(232),255,0,0,225,225,0)
Bouton(6,180,80,50,40,"Webdings,20;"+CHR$(71),0,100,0,225,225,225)

' exemple d'utilisation
Bouton(7,20,120,80,35,"Au clair<de la lune",0,0,200,0,225,225) : on_click 7,Acdll
END
rem ============================================================================

Acdll:
  anime_bouton(number_click)
  message "Au clair de la lune"
RETURN

SUB Bouton(nobj%,LeftBt%,ToptBt%,WidthBt%,HeightBt%,CaptionBt$,ColorTxtR%,ColorTxtG%,ColorTxtB%,ColorBtR%,ColorBtG%,ColorBtB%)
  DIM_LOCAL i%,k%,b$,nl%,a$(10),lg%,wt%,ht%,hl%
  DIM_LOCAL n2d%,npt%: n2d% = NUMBER_2D_TARGET: npt% = NUMBER_PRINT_TARGET
  PICTURE nobj%: TOP nobj%,ToptBt%: LEFT nobj%,LeftBt%: WIDTH nobj%,WidthBt%: HEIGHT nobj%,HeightBt%
  2D_TARGET_IS nobj%: 2D_FILL_COLOR ColorBtR%,ColorBtG%,ColorBtB%: 2D_PEN_COLOR 180,180,180
  2D_RECTANGLE 0,0,WidthBt%-1,HeightBt%-1
  2D_PEN_COLOR 0,0,0: 2D_LINE 1,HeightBt%-1,WidthBt%-1,HeightBt%-1: 2D_POLY_TO WidthBt%-1,1
  PRINT_TARGET_IS nobj%: FONT_NAME nobj%,"DejaVu Sans Mono": FONT_SIZE nobj%,9
  font_color nobj%,ColorTxtR%,ColorTxtG%,ColorTxtB%
  k% = INSTR(CaptionBt$,";")
  IF k% > 0
      b$ = LEFT$(CaptionBt$,k%-1): CaptionBt$ = RIGHT_POS$(CaptionBt$,k%+1): k% = INSTR(b$,",")
      FONT_NAME nobj%,LEFT$(b$,k%-1): FONT_SIZE nobj%,VAL(RIGHT_POS$(b$,k%+1))
  END_IF
  nl% = 1: b$ = CaptionBt$: a$(1) = CaptionBt$: hl% = TEXT_HEIGHT(CaptionBt$,nobj%)
  k% = INSTR(CaptionBt$,"<")
  WHILE k%>0
    a$(nl%)=LEFT$(b$,k%-1): nl%=nl%+1: b$=RIGHT_POS$(b$,k%+1): k%=INSTR(b$,"<")
  END_WHILE
  a$(nl%) = b$: hl% = hl%-2: ht% = nl%*hl%: k% = (HeightBt%-ht%)/2-2
  FOR i% = 1 TO nl%
      wt% = TEXT_WIDTH(a$(i%),nobj%)
      PRINT_LOCATE (WidthBt%-wt%)/2,k%: PRINT a$(i%): k%=k%+hl%
  NEXT i%
  PRINT_TARGET_IS npt%: 2D_TARGET_IS n2d%
END_SUB

SUB anime_bouton(num_bouton%)
    if object_type(number_click)=9 or object_type(number_click)=6
       ' laisse passer
    else
       exit_sub :' objet non concerné
    end_if
    dim_local top_bouton%,left_bouton%
    top_bouton%=top(num_bouton%) : left_bouton%=left(num_bouton%)
    top num_bouton%,top_bouton%+2 : left num_bouton%,left_bouton%+2
    pause 20
    top num_bouton%,top_bouton% : left num_bouton%,left_bouton%
END_SUB


A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
JL35



Nombre de messages : 6018
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Boutons (un peu) fantaisie   Sam 19 Nov 2016 - 0:26

C'est bien certain que chacun peut faire à son idée et selon ses besoins, c'est bien l'esprit de la chose, c'est une idée en l'air, et chacun en fait ce qu'il veut (on est programmeurs après tout !).
Pour moi ce qui m'intéressait surtout c'est les boutons à plusieurs lignes de texte, mais tu as raison, la couleur peut être bien utile dans certains cas.

Quant à l'animation, la tempo ne change pas grand chose, tu n'as le mouvement du bouton qu'au relâchement de la souris, et ce n'est pas logique, tu appuies sur le bouton et il ne s'enfonce que quand tu le relâches... bon, on ne va pas pinailler, c'est un gadget.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Minibug

avatar

Nombre de messages : 2408
Age : 51
Localisation : Vienne (86)
Date d'inscription : 10/02/2012

MessageSujet: Re: Boutons (un peu) fantaisie   Sam 19 Nov 2016 - 1:34

Bonsoir tout le monde !

Voila une bonne idée JL35, il sont beaux tes boutons. Wink
C'est vrai que l'histoire du bouton enfoncé est toujours une complication supplémentaire à simulé.

Pour ma part, même si je sais que c'est réalisable, j'ai laissé tombé.

Maintenant, le plus souvent, je réalise mes boutons sous forme d’icônes à partir de PICTURE avec une image adapté.
Et tant pis pour l’effet d'enfoncement du bouton... drunken
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://gpp.panoramic.free.fr
papydall

avatar

Nombre de messages : 5613
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Boutons (un peu) fantaisie   Sam 19 Nov 2016 - 2:10

Et moi, et moi !
Et mes boutons, et mes boutons !

Tout d’abord,  enregistrez les boutons que vous trouvez dans le spoiler ci-dessous dans l’ordre : Normal / Survole / Appuye
Puis testez ce code.
Adaptez les noms des fichiers des boutons :
normal1.jpg /survole1.jpg / appuye1.jpg  pour les petits boutons (dimensions 48)
normal2.jpg /survole2.jpg / appuye2.jpg  pour les grands boutons (dimensions 96)

Survolez le bouton : il change d'aspect.
Cliquez-droit sans relâcher : il change d'aspect.
Lâchez le bouton de la souris : il change d'aspect.



petits boutons:
 



grands boutons:
 



Code:

rem ============================================================================
label Anime_bouton
dim x,y,w
color 0,255,255,255
picture 10 : top 10,50 : left 10,50
 file_load 10,"normal1.jpg" : w = 48
' file_load 10,"normal2.jpg" : w = 95
timer 99 : timer_interval 99,100 : on_timer 99,Anime_bouton
end
rem ============================================================================
Anime_bouton:
    timer_off 99
    x = mouse_x_position(10)
    y = mouse_y_position(10)
    file_load 10,"normal1.jpg"
    if x > 0 and x < w and y > 0 and y < w
       file_load 10,"survole1.jpg"
       hint 10,"Bouton survolé"
       if mouse_left_down(10) > 0
          file_load 10,"appuye1.jpg"
          hint 10,"bouton appyué"
          while mouse_left_up(10) = 0 : end_while
          file_load 10,"normal1.jpg"
       end_if
    end_if
    timer_on 99
return
rem ============================================================================
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Minibug

avatar

Nombre de messages : 2408
Age : 51
Localisation : Vienne (86)
Date d'inscription : 10/02/2012

MessageSujet: Re: Boutons (un peu) fantaisie   Sam 19 Nov 2016 - 10:49

Jolis boutons et joli code.
J'ai testé et j'avoue qu'on peut difficilement faire plus simple...

Le seul soucis (si l'on bon dire), c'est l'emploi du TIMER...
Encore une fois, si l'on reste sur l'usage d'un petit programme, tout va bien mais si cela concerne intégration dans un gros programme c'est plus délicat ! On connais les soucis rencontrés avec les TIMERs...

Mais cela reste possible et n'enlève rien à la qualité de ton code Papydall. Bravo. cheers
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://gpp.panoramic.free.fr
JL35



Nombre de messages : 6018
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Boutons (un peu) fantaisie   Sam 19 Nov 2016 - 14:56

Joli papydall, mais évidemment que c'est faisable avec un timer !
Pour ma part je fuis le timer autant que je peux (c'est parfois obligatoire), mais comme le laisse entendre minibug c'est une bonne source d'emm... euh, d'embêtements, dans le contexte d'un programme !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
silverman

avatar

Nombre de messages : 475
Age : 45
Localisation : Picardie
Date d'inscription : 19/03/2015

MessageSujet: Re: Boutons (un peu) fantaisie   Sam 19 Nov 2016 - 16:03

1 timer, ça va, plusieurs timers, bonjour les dégats Very Happy
Solution pour ne plus en avoir peur et en gérer pleins facilement, allez voir ICI

Sympa tous ces boutons!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
JL35



Nombre de messages : 6018
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Boutons (un peu) fantaisie   Sam 19 Nov 2016 - 16:40

C'est vrai que les boutons c'est sans limites, du fait que ce sont des pictures on peut y mettre ce qu'on veut, images, etc.

Quant aux timers, merci silverman pour le lien, je vais regarder ça de plus près, ayant été échaudé plusieurs fois ça m'intéresse beaucoup.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Contenu sponsorisé




MessageSujet: Re: Boutons (un peu) fantaisie   

Revenir en haut Aller en bas
 
Boutons (un peu) fantaisie
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» probleme pour faire un lien avec mes boutons
» boutons à la place du dispatcher
» [Resolu] Disparitions de boutons et autres !
» Infos pour racoorder mon FR1B avec un E66 à boutons accordéo
» Remplacer la tête des boutons des basses !!

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Vos sources, vos utilitaires à partager-
Sauter vers: