FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» Panoramic et ses curiosités
par Klaus Aujourd'hui à 2:20

» Synedit Parameters
par Klaus Aujourd'hui à 1:33

» Utilitaire de suppression de fichiers
par Yannick Hier à 23:03

» Code à vérifier SVP (Oups ! résolu)
par Jean Claude Jeu 22 Juin 2017 - 21:16

» Compilateur FBPano
par jean_debord Jeu 22 Juin 2017 - 9:56

» Bienvenue à Virtualalan !
par UltraVox Jeu 22 Juin 2017 - 9:18

» Concours de Morpions
par jjn4 Jeu 22 Juin 2017 - 0:04

» ShortName$(F) [Cloturé]
par papydall Mer 21 Juin 2017 - 16:19

» Remplacer espace par tiret dans noms des dossiers / fichiers
par papydall Mer 21 Juin 2017 - 15:27

» Menu personalisé avec icones et menu contextuel
par Laurent (Minibug) Mer 21 Juin 2017 - 12:44

» La liste des choses à faire ...
par Jack Mar 20 Juin 2017 - 22:49

» Quoi de neuf à propos de Goric 3D ? (@Jack)
par UltraVox Mar 20 Juin 2017 - 21:06

» Nom court et anti fenetre dos
par silverman Mar 20 Juin 2017 - 18:31

» Ludothèque Panoramic
par jjn4 Mar 20 Juin 2017 - 18:09

» Proposition à la communauté
par Yannick Mar 20 Juin 2017 - 15:02

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Juin 2017
LunMarMerJeuVenSamDim
   1234
567891011
12131415161718
19202122232425
2627282930  
CalendrierCalendrier

Partagez | 
 

 Equation d’un œuf

Voir le sujet précédent Voir le sujet suivant Aller en bas 
AuteurMessage
papydall

avatar

Nombre de messages : 5384
Age : 66
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Equation d’un œuf   Mar 3 Mai 2016 - 17:06

Si quelqu’un peut inventer l’équation d’une omelette ?  Evil or Very Mad
En attendant voici l’équation d’un œuf. cheers



Code:

rem ============================================================================
rem         OVE
rem ============================================================================
' Ref : http://serge.mehl.free.fr/anx/ovale.html
' L'ovale ne possède pas d'équation mathématique simple
' Une étude de l'équation de l'ove aboutit à une équation paramétrique au moyen
' des fonctions logiques pas vraiment simple.
rem ============================================================================
rem x(t) = cos(t)*(t<=p)+(1+2cos(t))*(t>p)*(t<=5p/4)+(2-sqrt(2))cos(t)*(t>5p/4)*(t<=7p/4)
rem      +(-1+2cos(t))*(t>7p/4)
rem y(t) = sin(t)*(t<=p)+2sin(t)*(t>pi)*(t<=5p/4)+(-1+(2-sqrt(2))*sin(t))*(t>5p/4)*(t<=7p/4)
rem        +2sin(t)*(t>7p/4)
rem ============================================================================
' Panoramic ne permettant pas de manipuler des telles équations logiques, on
' peut les transformer sous une autre forme utilisant la partie entière (INT)
' que Panoramic sait très bien s'en servir.
' on obtient :
rem ============================================================================
rem  x(t) = cos(t)*(1-int(t/pi))+(1+2cos(t))*int(t/pi)*(1-int(4t/5/pi))
rem         +(2-sqrt(2))cos(t)*int(4t/5/pi)*(1-int(4t/7/pi))+(-1+2cos(t))*int(4t/7/pi)*(1-int(t/2/pi))
rem  y(t) = sin(t)*(1-int(t/pi))+2sin(t)*int(t/pi)*(1-int(4t/5/pi))
rem         +(-1+(2-sqrt(2))sin(t))*int(4t/5/pi)*(1-int(4t/7/pi))+2sin(t)*int(4t/7/pi)*(1-int(t/2/pi))
rem ============================================================================
rem &&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&
rem ============================================================================
Ove(300,250,150)
Ove(80,100,50) : Ove(530,100,50)
Ove(80,240,50) : Ove(530,240,50)
Ove(80,380,50) : Ove(530,380,50)
end
rem ============================================================================
SUB Ove(xc,yc,r)
    dim_local x,y,t,p
    p = pi/180
    color 0,0,0,0 : 2d_pen_color 200,150,100 : 2d_poly_from xc+r,yc
    for t = 0 to 2*pi step p
        x = cos(t)*(1-int(t/pi))+(1+2*cos(t))*int(t/pi)*(1-int(4*t/5/pi))
        x = x +(2-sqr(2))*cos(t)*int(4*t/5/pi)*(1-int(4*t/7/pi))
        x = x +(-1+2*cos(t))*int(4*t/7/pi)*(1-int(t/2/pi))
        y = sin(t)*(1-int(t/pi))+2*sin(t)*int(t/pi)*(1-int(4*t/5/pi))
        y = y +(-1+(2-sqr(2))*sin(t))*int(4*t/5/pi)*(1-int(4*t/7/pi))
        y = y +2*sin(t)*int(4*t/7/pi)*(1-int(t/2/pi))
        2d_poly_to xc+r*x,yc+r*y
    next t
    2d_flood xc,yc,200,150,100
END_SUB
rem ============================================================================
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/ En ligne
Jean Claude

avatar

Nombre de messages : 4933
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Equation d’un œuf   Mar 3 Mai 2016 - 17:22

Bon, ben avec ça je vais pouvoir fabriquer un Sprite pour Pâque 2017. Very Happy

Papydall a écrit:
Si quelqu’un peut inventer l’équation d’une omelette ?
Ouai ! je suis pour, ça m'évitera de taper sur mon écran pour casser l’œuf...

lol!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5384
Age : 66
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Equation d’un œuf   Mar 3 Mai 2016 - 18:07

On peut même tourner ces oves par rapport à la verticale d’un angle quelconque (de 0 à 360 °) dans le sens horaire.

Code:

rem ============================================================================
rem         OVE
rem ============================================================================
' Ref : http://serge.mehl.free.fr/anx/ovale.html
' L'ovale ne possède pas d'équation mathématique simple
' Une étude de l'équation de l'ove aboutit à une équation paramétrique au moyen
' des fonctions logiques pas vraiment simple.
rem ============================================================================
rem x(t) = cos(t)*(t<=p)+(1+2cos(t))*(t>p)*(t<=5p/4)+(2-sqrt(2))cos(t)*(t>5p/4)*(t<=7p/4)
rem      +(-1+2cos(t))*(t>7p/4)
rem y(t) = sin(t)*(t<=p)+2sin(t)*(t>pi)*(t<=5p/4)+(-1+(2-sqrt(2))*sin(t))*(t>5p/4)*(t<=7p/4)
rem        +2sin(t)*(t>7p/4)
rem ============================================================================
' Panoramic ne permettant pas de manipuler des telles équations logiques, on
' peut les transformer sous une autre forme utilisant la partie entière (INT)
' que Panoramic sait très bien s'en servir.
' on obtient :
rem ============================================================================
rem  x(t) = cos(t)*(1-int(t/pi))+(1+2cos(t))*int(t/pi)*(1-int(4t/5/pi))
rem         +(2-sqrt(2))cos(t)*int(4t/5/pi)*(1-int(4t/7/pi))+(-1+2cos(t))*int(4t/7/pi)*(1-int(t/2/pi))
rem  y(t) = sin(t)*(1-int(t/pi))+2sin(t)*int(t/pi)*(1-int(4t/5/pi))
rem         +(-1+(2-sqrt(2))sin(t))*int(4t/5/pi)*(1-int(4t/7/pi))+2sin(t)*int(4t/7/pi)*(1-int(t/2/pi))
rem ============================================================================
rem &&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&
rem ============================================================================

 Ove(300,250,100,000)

 Ove(080,080,50,045) : Ove(500,080,50,135)
 Ove(080,220,50,090) : Ove(500,220,50,270)
 Ove(080,360,50,180) : Ove(500,360,50,225)

end
rem ============================================================================
' inclinaison en degrés de l'ove par rapport à la verticale dans le sens horaire
SUB Ove(cx,cy,r,Inclideg)
    dim_local x,y,xp,yp,t,p
    p = pi/180
    color 0,0,0,0 : 2d_pen_color 200,150,100
    for t = 0 to 2*pi step p
        x = cos(t)*(1-int(t/pi))+(1+2*cos(t))*int(t/pi)*(1-int(4*t/5/pi))
        x = x +(2-sqr(2))*cos(t)*int(4*t/5/pi)*(1-int(4*t/7/pi))
        x = x +(-1+2*cos(t))*int(4*t/7/pi)*(1-int(t/2/pi))
        y = sin(t)*(1-int(t/pi))+2*sin(t)*int(t/pi)*(1-int(4*t/5/pi))
        y = y +(-1+(2-sqr(2))*sin(t))*int(4*t/5/pi)*(1-int(4*t/7/pi))
        y = y +2*sin(t)*int(4*t/7/pi)*(1-int(t/2/pi))
        
         ' Application de la matrice de rotation par rapport au centre cx,cy
        xp = (x*cos(p*IncliDeg) - y*sin(p*IncliDeg))
        yp = (x*sin(p*IncliDeg) + y*cos(p*IncliDeg))
        if t = 0
           2d_poly_from cx+r*xp,cy+r*yp
        else
           2d_poly_to cx+r*xp,cy+r*yp
        end_if
    next t
    2d_flood cx,cy,200,150,100
END_SUB
rem ============================================================================
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/ En ligne
mindstorm

avatar

Nombre de messages : 530
Age : 48
Localisation : charente
Date d'inscription : 13/02/2013

MessageSujet: Re: Equation d’un œuf   Mar 3 Mai 2016 - 20:02

Citation :
Une étude de l'équation de l'ove
Alors Là, c'est de l'amour....pour les Maths
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5384
Age : 66
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Equation d’un œuf   Mar 3 Mai 2016 - 20:27

Je suis un éternel amoureux  I love you  … pour les maths et pour bien d’autres choses, en particulier les belles courbes.
Pour une fois, vous pouvez laisser votre imagination aller loin, voire très loin. tongue
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/ En ligne
Jicehel

avatar

Nombre de messages : 5838
Age : 44
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Equation d’un œuf   Mar 3 Mai 2016 - 21:41

C'est très bien fait comme d'hab Papydall.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5384
Age : 66
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Equation d’un œuf   Mar 3 Mai 2016 - 23:22

Hé oui. L'habitude est une seconde nature.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/ En ligne
papydall

avatar

Nombre de messages : 5384
Age : 66
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Equation d’un œuf   Mer 4 Mai 2016 - 0:23

Un autre œuf dont l’équation est beaucoup plus simple.


Code:

rem ============================================================================
rem         Quartique ovoïde proposée par Massimo Vaglieco
rem                       Par Papydall
rem Ref : http://www.mathcurve.com/courbes2d/oeuf/oeufgranville.shtml
rem ============================================================================

Oeuf_De_Massimo_Vaglieco(300,250,3,2,0.25,60)

end
rem ============================================================================
SUB Oeuf_De_Massimo_Vaglieco(xc,yc,a,b,c,z)
    dim_local x,y,t
    2d_pen_color 200,150,100
    degrees
    2d_poly_from xc,yc-(a+c)*z
    for t = 0 to 360
      x = b*sin(t) : y = a*cos(t) + c*cos(2*t)
      2d_poly_to xc+x*z,yc-y*z
    next t
    2d_flood xc,yc,200,150,100
END_SUB
rem ============================================================================
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/ En ligne
jjn4

avatar

Nombre de messages : 1592
Date d'inscription : 13/09/2009

MessageSujet: +++   Mer 4 Mai 2016 - 18:38

Et en attendant de trouver l'équation de l'omelette,
l'imbattable papydall peut toujours trouver l'équation
de la poule qui a pondu l'œuf qui, en éclosant, a donné
la poule qui... etc...
lol! alien lol!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://jjn4.e-monsite.com
Yannick

avatar

Nombre de messages : 7825
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Mer 4 Mai 2016 - 19:02

Moi je les aime que brouillés les oeufs...
...elles est où l' équation ?
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
JL35



Nombre de messages : 5882
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Equation d’un œuf   Mer 4 Mai 2016 - 19:16

C'est simple, tu prends le programme de papydall, tu mélanges bien les lignes, ça commence par brouiller les yeux, et puis ça devrait marcher.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
jjn4

avatar

Nombre de messages : 1592
Date d'inscription : 13/09/2009

MessageSujet: +++   Mer 4 Mai 2016 - 19:17

Ah oui, pour les œufs brouillés,
il faut construire une équation
faisant appel à la théorie du chaos !
Laughing Laughing Laughing alien Laughing Laughing Laughing
(papydall va nous faire ça
les doigts dans le nez)
lol! alien lol!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://jjn4.e-monsite.com
Jean Claude

avatar

Nombre de messages : 4933
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Equation d’un œuf   Mer 4 Mai 2016 - 19:20

Laisser l’œuf éclore, c'est bien, mais alors le poussin deviendra poulet, et bêtement il va traverser la route.
Cela nous fera donc une omelette de poulet.

lol!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5384
Age : 66
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Equation d’un œuf   Mer 4 Mai 2016 - 20:22

Spoiler:
 
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/ En ligne
Yannick

avatar

Nombre de messages : 7825
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Mer 4 Mai 2016 - 20:48

Ca y est, c' est reparti en cacahuètes...
Mais peut on  appliquer cette équation pour ce fruit ?...
lol!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5384
Age : 66
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Equation d’un œuf   Jeu 5 Mai 2016 - 2:08

Des cacahuètes  en équation ?
Difficile pour moi.
En y réfléchissant un peu (beaucoup) …
Peut-être que l’ovale de Cassini  avec des paramètres appropriés fera-t-elle l’affaire.


Code:

rem ============================================================================

Ovale_De_Cassini(6.75,7)

end

rem ============================================================================
SUB Ovale_De_Cassini(a,k)
    dim_local r,r2,a2,a4,k4,radical,sradic,s,t,x,y,x0,y0
    degrees
    x0 = width(0)/2 : y0 = height(0)/2 : color 0,0,0,0 : 2d_pen_color 150,125,100
    a2 = a*a : a4 = a2*a2 : k4 = k*k*k*k : s = 20
    2d_poly_from x0+s*sqr(a2+k*k),y0
    for t = 0 to 360
        r2 = a2*cos(2*t) : radical = abs(k4-a4*sin(2*t)*sin(2*t))
        sradic = sqr(radical) : r = sqr(abs(r2 + sradic))
        x = x0+s*r*cos(t) : y = y0-s*r*sin(t)
        2d_poly_to x,y
    next t
    2d_flood x0,y0,150,125,100
END_SUB
rem ============================================================================
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/ En ligne
jjn4

avatar

Nombre de messages : 1592
Date d'inscription : 13/09/2009

MessageSujet: +++   Jeu 5 Mai 2016 - 17:20

Ah oui, c'est bien l'équation de la cacahuète !
Scotché, Ygeronimi !!!
Et 1 point à zéro pour papydall !
Laughing Laughing alien Laughing Laughing
(et pour les œufs brouillés, alors ?... Laughing )
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://jjn4.e-monsite.com
Yannick

avatar

Nombre de messages : 7825
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Jeu 5 Mai 2016 - 19:15

Je vois que mes boutades font avancer le sujet.
cheers Laughing
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5384
Age : 66
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Equation d’un œuf   Jeu 5 Mai 2016 - 20:45

Pour les œufs brouillés, il fallait demander ça à un chef-cuisinier.
Je connais au moins un sur ce forum qui prétend être le meilleur Pano-cuisinier maniant aussi bien les œufs que Panoramic.
Quant à moi, je me contente de présenter  «un flan aux œufs dans une assiette creuse avec une morille au centre.»

Code:

rem ============================================================================
rem      Flan aux œufs dans une assiette creuse avec une morille au centre
rem ============================================================================
width 0,700 : picture 10 : full_space 10 : 2d_target_is 10 : color 10,0,0,0
Assiette()
print_target_is 10 : font_bold 10 : font_name 10,"tahoma" : font_size 10,14
2d_fill_color 0,0,0 : font_color 10,200,100,50 : print_locate 20,20
print "Flan aux œufs dans une assiette creuse avec une morille au centre"
end
rem ============================================================================
SUB Assiette()
    dim_local x1,x2,x4,y1,y2,x,y,i,a,l,r,f,cr,cg,cb
    x1 = 330 : y1 = 300 : x2 = x1*x1 : y2 = 200
    For x = 0 to x1
        x4 = x*x : L = 0-y1 :  A = sqr(abs(x2 - x4))
        For I = 0-A to A
            cr = mod((abs(i/2)+x/2),255)
            cg = abs(255-abs(i/2))
            cb = mod(abs(a/2),255)
            2d_pen_color cr,cg,cb
            R = sqr(X4+I*I)/x1 : F = (1-R)*cos(12*R) : Y = I/5+F*y2
            If Y > L then L = y : y = y1-y : 2d_point x1-x,y : 2d_point x1+x,y
            display
        Next I
    Next x
END_SUB
rem ============================================================================

Bon appétit!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/ En ligne
jjn4

avatar

Nombre de messages : 1592
Date d'inscription : 13/09/2009

MessageSujet: +++   Ven 6 Mai 2016 - 18:38

Pas vraiment appétissant, ton flan aux œufs et aux morilles,
on dirait plutôt une gélatine anglaise à la mente verte, berk !
Laughing alien Laughing
Le match est à 1 partout...
Laughing Laughing Laughing alien Laughing Laughing Laughing
(notons cependant que c'est mathématiquement joli !)
cheers alien king
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://jjn4.e-monsite.com
papydall

avatar

Nombre de messages : 5384
Age : 66
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Equation d’un œuf   Ven 6 Mai 2016 - 19:24

jjn4 a écrit:
(notons cependant que c'est mathématiquement joli !)

Ha! Ha! king

+1
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/ En ligne
Contenu sponsorisé




MessageSujet: Re: Equation d’un œuf   

Revenir en haut Aller en bas
 
Equation d’un œuf
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» AX^3 + BX^2 + CX + D = 0
» Les Bolygones
» Equation d’un œuf

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC 32 bits :: Vos sources, vos utilitaires à partager-
Sauter vers: