FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» 3D_LINE How to ?
par papydall Aujourd'hui à 6:51

» mise a jour calculatrice
par joeeee2017 Hier à 23:00

» supprimé
par joeeee2017 Dim 15 Oct 2017 - 20:02

» calculatrice avec touches movibles
par joeeee2017 Dim 15 Oct 2017 - 1:11

» Convertisseur de base 10 de 2 à 36
par gigi75 Sam 14 Oct 2017 - 21:54

» CORTANA
par gigi75 Sam 14 Oct 2017 - 16:32

» supprimé
par Jean Claude Sam 14 Oct 2017 - 12:30

» Compilateur FBPano
par jean_debord Jeu 12 Oct 2017 - 9:53

» KGF_dll - nouvelles versions
par Klaus Mar 10 Oct 2017 - 18:49

» à propos de Panoramic_Editor [Résolu]
par Klaus Mar 10 Oct 2017 - 3:19

» Un petit "coucou" à tous les Panoramiciens !
par Jack Ven 6 Oct 2017 - 10:24

» Pourquoi le compilateur stagne
par mindstorm Mer 4 Oct 2017 - 20:38

» Panoramic ?
par Marc37 Mer 4 Oct 2017 - 0:39

» Premiers pas avec Arduino
par Marc37 Mer 4 Oct 2017 - 0:29

» Mise à jour PANOMAND
par jean_debord Mar 26 Sep 2017 - 11:33

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Octobre 2017
LunMarMerJeuVenSamDim
      1
2345678
9101112131415
16171819202122
23242526272829
3031     
CalendrierCalendrier

Partagez | 
 

  La Maison qui s'approche et qui s'éloigne

Voir le sujet précédent Voir le sujet suivant Aller en bas 
AuteurMessage
papydall

avatar

Nombre de messages : 5537
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: La Maison qui s'approche et qui s'éloigne   Mer 9 Déc 2015 - 15:58




Code:

rem ============================================================================
'                La Maison qui s'approche et qui s'éloigne
rem ============================================================================
Init()
La_Maison(e) : pause 2000
repeat
   Maison_Approche_toi() : Maison_Eloigne_Toi()
until scancode <> 0
cls : La_Maison(4) : Copy_Image()
end
rem ============================================================================
SUB Init()
    dim e : e = 4 : ' Facteur d'aggrandissement / rapetissement
    dim p : p = 0.025
    dim size
    full_space 0 : caption 0,"<CLICK> pour arrêter ..."
    picture 10 : full_space 10 : 2d_target_is 10 : print_target_is 10
    font_name 10,"arial": font_bold 10 : font_color 10,255,255,0 : 2d_fill_on
    image 20
END_SUB
rem ============================================================================
SUB La_Maison(e)
    color 10,92,128,128
    2d_pen_color 0,0,255 : 2d_poly_from 80*e,20*e
    2d_poly_to 220*e,20*e : 2d_poly_to 280*e,80*e
    2d_poly_to 140*e,80*e : 2d_poly_to 80*e,20*e
    2d_flood 220*e,20*e+5,0,0,255
    2d_pen_color 100,50,20  : 2d_fill_color 100,50,20
    2d_rectangle 140*e,80*e,270*e,170*e

    2d_pen_color 50,100,50 : 2d_poly_from 87*e,27*e
    2d_poly_to 140*e,80*e : 2d_poly_to 140*e,170*e : 2d_poly_to 30*e,170*e
    2d_poly_to 30*e,80*e : 2d_poly_to 87*e,27*e
    2d_flood 30*e+10,80*e, 200,200,50

    2d_pen_color 0,0,0 : 2d_poly_from 80*e,20*e
    2d_poly_to 87*e,27*e : 2d_poly_to 30*e,80*e
    2d_poly_to 20*e,80*e : 2d_poly_to 80*e,20*e
    2d_flood 80*e,20*e+2,0,0,0
    2d_fill_color 0,0,0
    2d_rectangle 20*e,170*e,280*e,180*e : 2d_rectangle 170*e,90*e,240*e,155*e

    2d_fill_color 255,255,0
    2d_rectangle 175*e,95*e,202*e,120*e  : 2d_rectangle 208*e,95*e,235*e,120*e
    2d_rectangle 175*e,125*e,202*e,150*e : 2d_rectangle 208*e,125*e,235*e,150*e
    
    2d_fill_color 0,200,200 : 2d_rectangle 60*e,80*e,110*e,170*e
    2d_fill_color 0,0,0     : 2d_rectangle 195*e,15*e,205*e,30*e
    2d_poly_from 200*e,10*e
    2d_poly_to 210*e,15*e : 2d_poly_to 190*e,15*e : 2d_poly_to 200*e,10*e
    2d_flood 200*e,10*e+2,0,0,0
    2d_fill_color 255,255,0 : 2d_circle 100*e,120*e,5*e
    
    2d_fill_color 255,0,0
    if e >= 4
      size = 16 : font_size 10, size
      print_locate 100*e,172*e : print "Nul n'entre ici s'il n'est PANORAMICIEN !"
    end_if
END_SUB
rem ============================================================================
SUB Maison_Approche_toi()
    for e = 0.1 to 4.5 step p
        cls : La_Maison(e) : Copy_Image() : pause 5
        if scancode <> 0 then exit_for
    next e
END_SUB
rem ============================================================================
SUB Maison_Eloigne_Toi()
   for e = 4.5 to .1 step 0-p
        cls : La_Maison(e) : Copy_Image() : pause 5
        if scancode <> 0 then exit_for
    next e
END_SUB
rem ============================================================================
SUB Copy_Image()
    hide 10
    2d_image_copy 20,left(10),top(10),width(10),height(10)
    2d_target_is 0: 2d_image_paste 20,left(10),top(10) : 2d_target_is 10
END_SUB
rem ============================================================================

Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Yannick

avatar

Nombre de messages : 7994
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Mer 9 Déc 2015 - 16:51

cheers
Bel effet de zoom avant/arrière .
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5537
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: La Maison qui s'approche et qui s'éloigne   Mer 9 Déc 2015 - 19:47

Nul n'entre dans la maison qui-s'approche-et-qui-s'éloigne s'il n'est PANORAMICIEN !
C'est utilement inutile tongue
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Jean Claude

avatar

Nombre de messages : 5031
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: La Maison qui s'approche et qui s'éloigne   Mer 9 Déc 2015 - 22:06

C'et bleffant !

Bravo, même pas de scintillement...

A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
mindstorm

avatar

Nombre de messages : 534
Age : 48
Localisation : charente
Date d'inscription : 13/02/2013

MessageSujet: Re: La Maison qui s'approche et qui s'éloigne   Mer 9 Déc 2015 - 23:37

bravo Papydall
j'ai juste un problème ligne 19 avec Panoramic Editor V 0.9.25
je l'ai réglé avec un rem
il manque aussi un bonhomme de neige santa
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5857
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: La Maison qui s'approche et qui s'éloigne   Jeu 10 Déc 2015 - 1:43

Excellent. Je mets une version gérée par timer pour un choix de type de programmation.
Elle n'apporte rien de plus, c'est juste une façon différente de procéder.

Code:
rem ============================================================================
'                La Maison qui s'approche et qui s'éloigne
rem ============================================================================
label trace
Init()
La_Maison(debut) : Copy_Image(): pause 1000
timer_on 3
end
rem ============================================================================
SUB Init()
    dim e : ' Facteur d'aggrandissement / rapetissement
    dim p : p = 0 - 0.05
    dim debut : debut = 3.7
    dim fin  : fin  = 0.05
    dim size
    full_space 0 : caption 0,"<CLICK> pour arrêter ..."
    picture 10 : full_space 10 : 2d_target_is 10 : print_target_is 10
    font_name 10,"arial": font_bold 10 : font_color 10,255,255,0 : 2d_fill_on
    size = 16 : font_size 10, size
    image 20
    timer 3 : timer_off 3: timer_interval 3,50 : on_timer 3,trace
    e = debut
END_SUB
rem ============================================================================
SUB La_Maison(e)
    color 10,92,128,128
    2d_pen_color 0,0,255  : 2d_poly_from 80*e,20*e :  2d_poly_to 220*e,20*e
    2d_poly_to 280*e,80*e : 2d_poly_to 140*e,80*e : 2d_poly_to 80*e,20*e
    2d_flood 220*e,20*e+5,0,0,255
    2d_pen_color 100,50,20  : 2d_fill_color 100,50,20
    2d_rectangle 140*e,80*e,270*e,170*e

    2d_pen_color 50,100,50 : 2d_poly_from 87*e,27*e : 2d_poly_to 140*e,80*e
    2d_poly_to 140*e,170*e : 2d_poly_to 30*e,170*e  : 2d_poly_to 30*e,80*e
    2d_poly_to 87*e,27*e  : 2d_flood 30*e+10,80*e, 200,200,50

    2d_pen_color 0,0,0    : 2d_poly_from 80*e,20*e :  2d_poly_to 87*e,27*e
    2d_poly_to 30*e,80*e  : 2d_poly_to 20*e,80*e : 2d_poly_to 80*e,20*e
    2d_flood 80*e,20*e+2,0,0,0
    2d_fill_color 0,0,0
    2d_rectangle 20*e,170*e,280*e,180*e : 2d_rectangle 170*e,90*e,240*e,155*e

    2d_fill_color 255,255,0
    2d_rectangle 175*e,95*e,202*e,120*e  : 2d_rectangle 208*e,95*e,235*e,120*e
    2d_rectangle 175*e,125*e,202*e,150*e : 2d_rectangle 208*e,125*e,235*e,150*e

    2d_fill_color 0,200,200 : 2d_rectangle 60*e,80*e,110*e,170*e
    2d_fill_color 0,0,0    : 2d_rectangle 195*e,15*e,205*e,30*e
    2d_poly_from 200*e,10*e
    2d_poly_to 210*e,15*e : 2d_poly_to 190*e,15*e : 2d_poly_to 200*e,10*e
    2d_flood 200*e,10*e+2,0,0,0
    2d_fill_color 255,255,0 : 2d_circle 100*e,120*e,5*e

    if e >= 3.2 then 2d_fill_color 255,0,0 : print_locate 100*e,172*e : print "Nul n'entre ici s'il n'est PANORAMICIEN !"

END_SUB
rem ============================================================================
SUB Copy_Image()
    hide 10
    2d_image_copy 20,left(10),top(10),width(10),height(10)
    2d_target_is 0: 2d_image_paste 20,left(10),top(10) : 2d_target_is 10
END_SUB
rem ============================================================================

trace:
    e = e+ p
    La_Maison(e) : Copy_Image()
    if e = fin then e = debut : debut = fin : fin = e :  p = 0 - p : e = debut
    if scancode = 0 then return
    if p > 0 : La_Maison(fin) : else :  La_Maison(debut): end_if
    Copy_Image() :  wait 1000  :  terminate
return


Dernière édition par Jicehel le Jeu 10 Déc 2015 - 2:26, édité 1 fois
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Marc37



Nombre de messages : 453
Age : 56
Localisation : TOURS
Date d'inscription : 18/03/2014

MessageSujet: Re: La Maison qui s'approche et qui s'éloigne   Jeu 10 Déc 2015 - 1:55

=> A l'homme qui programme plus vite que son ombre :

Trop cool ! Bravo !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5537
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: La Maison qui s'approche et qui s'éloigne   Jeu 10 Déc 2015 - 2:12

Jean Claude a écrit:
C'et bleffant !

Bravo, même pas de scintillement...

Tu dis scintillement ? Quel scintillement ?
Depuis l’astuce de  Silverman / Cosmos70  (un grand merci à eux) je ne connais plus ce gros mot !
Pour te convaincre, jette un œil sur la SUB Copy_Image()

mindstorm a écrit:
bravo Papydall
j'ai juste un problème ligne 19 avec Panoramic Editor V 0.9.25
je l'ai réglé avec un rem
il manque aussi un bonhomme de neige  

Comment ça ?
La ligne 19 c’est
Code:
image 20

Et cet objet est nécessaire pour que le programme marche.
Le code tel qu’il est posté fonctionne parfaitement.

Jicehel a écrit:
Excellent. Je mets une version gérée par timer pour un choix de type de programmation.
Elle n'apporte rien de plus, c'est juste une façon différente de procéder.

Ligne 6
Code:
La_Maison(debut) : pause 1000
Tu as viré mon Copy_Image() et bonjour les dégats, heu les scintillements !
Cette ligne doit être
Code:
La_Maison(debut) : Copy_Image() : pause 1000

Ligne 70
Code:
if p > 0 then La_Maison(fin) else La_Maison(debut)
Il manque les deux-points : de séparation avant et après else

Marc37 a écrit:
=> A l'homme qui programme plus vite que son ombre :

Trop cool ! Bravo !

A dire vrai, je n'ai plus d'ombre (ou je ne la vois plus), car ces temps-ci , je garde le lit (plutôt) le bureau !  scratch


Merci beaucoup à vous tous.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Jicehel

avatar

Nombre de messages : 5857
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: La Maison qui s'approche et qui s'éloigne   Jeu 10 Déc 2015 - 2:26

J'ai mis les 2 corrections dans le code et bonne nuit à tous


Dernière édition par Jicehel le Jeu 10 Déc 2015 - 11:15, édité 1 fois
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 5031
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: La Maison qui s'approche et qui s'éloigne   Jeu 10 Déc 2015 - 9:47

Papydall a écrit:
Tu dis scintillement ? Quel scintillement ?
Depuis l’astuce de Silverman / Cosmos70 (un grand merci à eux) je ne connais plus ce gros mot !

C'est bien ce que j'ai dit "même pas de scintillement"

Et tu fais bien de rappeler le travail de Silverman et de Cosmos.

A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Invité
Invité



MessageSujet: Re: La Maison qui s'approche et qui s'éloigne   Jeu 10 Déc 2015 - 16:02

Citation :
Et tu fais bien de rappeler le travail de Silverman et de Cosmos.

C'est surtout l'homme d'argent qu'il faut féliciter. J'ai seulement repris son travail.
Revenir en haut Aller en bas
papydall

avatar

Nombre de messages : 5537
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: La Maison qui s'approche et qui s'éloigne   Jeu 10 Déc 2015 - 16:36

Vous êtes tous gentils.
Vive le Forum !
Vive Panoramic
Vive la communauté Panoramicienne !

« Le savoir est la seule chose qui augmente quand on la partage »
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
mindstorm

avatar

Nombre de messages : 534
Age : 48
Localisation : charente
Date d'inscription : 13/02/2013

MessageSujet: Re: La Maison qui s'approche et qui s'éloigne   Jeu 10 Déc 2015 - 20:20

bonjour a tous
papydall pour moi la ligne 19 c'est la définition des écritures "fonte..."
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5537
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: La Maison qui s'approche et qui s'éloigne   Ven 11 Déc 2015 - 2:17

Salut mindstorm

Je vois quel est ton problème.
Tu utilises Panoramic Editor V 0.9.25 alors que la version actuelle est Panoramic Editor V 0.9.27i3

Le problème se trouve dans cette ligne
Code:

font_name 10,"arial": font_bold 10 : font_color 10,255,255,0 : 2d_fill_on


La version  V 0.9.25 ne reconnait pas la commande 2d_fill_on d'où l'erreur.
Cette commande autorise le remplissage des formes 2D_CIRCLE et 2D_RECTANGLE

Pourquoi tu ne passes pas à la dernière version ou à la version V.0.9.26 ?
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Contenu sponsorisé




MessageSujet: Re: La Maison qui s'approche et qui s'éloigne   

Revenir en haut Aller en bas
 
La Maison qui s'approche et qui s'éloigne
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» Retour maison
» rendu intérieur maison
» La Maison de la Nuit-->Ecole de Vampires, intrigue et meurtres...
» Retour maison
» Comment parfumer sa maison?

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Les inutilitaires-
Sauter vers: