FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» Mah-Jong européen new-look
par jjn4 Aujourd'hui à 15:48

» KGF.dll - demandes ou suggestions de modifications ou ajouts
par pascal10000 Aujourd'hui à 13:46

» a l'aide klaus
par Minibug Aujourd'hui à 11:42

» KGF_dll - nouvelles versions
par Minibug Aujourd'hui à 1:48

» bug SYNEDIT_TARGET_IS_OBJECT
par Jack Aujourd'hui à 0:16

» Jukebox : Serge Reggiani
par papydall Sam 9 Déc 2017 - 5:58

» Ecouter la radio fm sur votre pc
par pascal10000 Sam 9 Déc 2017 - 3:42

» anomalie
par Klaus Sam 9 Déc 2017 - 3:21

» hommage
par Jicehel Ven 8 Déc 2017 - 11:29

» Logiciel de soutien scolaire en langues.
par Pedro Alvarez Ven 8 Déc 2017 - 10:43

» carte son
par Klaus Ven 8 Déc 2017 - 2:37

» API Windows
par Klaus Jeu 7 Déc 2017 - 21:03

» mise a jour calculatrice
par joeeee2017 Mer 6 Déc 2017 - 22:19

» j'ai un petit problème
par JL35 Mer 6 Déc 2017 - 21:58

» source vumetre avec delphi
par Klaus Mar 5 Déc 2017 - 23:22

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Décembre 2017
LunMarMerJeuVenSamDim
    123
45678910
11121314151617
18192021222324
25262728293031
CalendrierCalendrier

Partagez | 
 

 Une histoire de fou ou j'ai besoin de vacances (résolu)

Voir le sujet précédent Voir le sujet suivant Aller en bas 
Aller à la page : 1, 2  Suivant
AuteurMessage
Jean Claude

avatar

Nombre de messages : 5086
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Une histoire de fou ou j'ai besoin de vacances (résolu)   Sam 12 Sep 2015 - 14:42

Bonjour à tous,

Une histoire de fou ou alors j'ai besoin de vacances !

Comme ce titre l'indique, soit je ne vois pas ce qui crève les yeux, soit il y a un problème avec Panoramic V09.26.

Pour pouvoir tester, vous devez télécharger sur mon Webdav le ZIP "Calculette"
1) => (après avoir décompressé) vous lancez "Calculette_Enfant.bas" avec Panoramic_editor V09.26.
2) => lancez le programme par F9 ou l’éclair rouge.
3) => essayez de faire une division.
4) => en principe, vous constaterez que le bouton division du programme ne fonctionne pas.
        Précision: c'est le cas chez moi sous W10.
5) => Si vous avez le même problème:
         5.1) Allez à la ligne 37 du programme et décomposez la en 2 lignes comme ci_dessous
Code:
    Ctrl_bouton()
    set_focus 0
          5.2) Relancez le programme, et là vous constaterez que maintenant la division fonctionne.  drunken  drunken  Question
          5.3) transformez le fichier.bas en exe (par l'option application du menu fichier de Panoramic_Editor)
          5.4) lancez l'exécutable.

Et vous constaterez que la division ne marche pas en exe, alors que ça marche en bas. !  drunken  drunken  drunken  Question  Question  Question

J'ai tous essayez, je n'y comprends rien.

Avant de crier au bug, j'espère que quelqu'un va découvrir le problème.

A+

PS: Si le programme fonctionne d'entrée chez vous, merci de me dire avec quel OS et quel Panoramic.


Dernière édition par Jean Claude le Dim 13 Sep 2015 - 21:03, édité 1 fois
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 8002
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Sam 12 Sep 2015 - 19:52


Windows 7 édition familiale
Panoramic-Editor 0.9.26 du 30/06/2015

Tout se passe bien... Twisted Evil
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 5086
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Sam 12 Sep 2015 - 20:11

Merci Ygeronimi.
Une précision svp: as-tu transformé en exécutable et si oui marche-t-il aussi ?

Bon, si ça marche chez toi du premier coup il me reste 2 possibilités:
Soit c'est à cause de W10, soit j'ai un souci avec Panoramic_Editor.

Demain je ré-installerais Panoramic_Editor car ce soir je dois vous abandonner.

A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
RMont



Nombre de messages : 184
Age : 75
Localisation : charente maritime
Date d'inscription : 29/12/2008

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Sam 12 Sep 2015 - 20:35


bonjour a tous.
@ jean-claude
j'ai suivit ta demande .j'ai coupé la ligne 37 en 2 .j'ai essayé : la division se fait correctement.
par contre en version application.exe il y a effectivement un problème . les deux points de la division ne se mettent pas en place . le chiffre diviseur s'ajoute aux autres déja en place . donc je confirme qu'il y a donc un problème.
je suit sous vista édition basique
a plus

Revenir en haut Aller en bas
Voir le profil de l'utilisateur
RMont



Nombre de messages : 184
Age : 75
Localisation : charente maritime
Date d'inscription : 29/12/2008

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Sam 12 Sep 2015 - 20:40


je rajoute : je suis sous panoramic v09.26
a+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 5086
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Sam 12 Sep 2015 - 22:06

Une petite escapade rapide pour te répondre RMont.

Merci RMont, pour la précision de ton test..

Ton intervention change ma vision du problème.
Du coup, l'OS ne semble plus en cause.

Ce qui est incompréhensible c'est que initialement cette ligne ne fonctionne pas:
Code:
 Ctrl_bouton() : set_focus 0
Et si on change par:
Code:
 Ctrl_bouton()
    set_focus 0
là ça fonctionne.
on est dans Panoramic_Editor v09.26 donc en source.bas.

J'attends que Ygeronimi précise comment il a fait son test.

J'ai beau regarder et triturer mon code, je ne vois pas d'erreur. C'est ZARBI !

A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 8002
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Sam 12 Sep 2015 - 22:28

Je confirme les dires de Rmont.

Cela fonctionne très bien depuis l' éditeur
mais cela bug comme pour Rmont en *.exe


W7 édition familiale
PE 0.9.26 du 30/06/2015
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5613
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Sam 12 Sep 2015 - 23:07

Chez moi, ça marche du 1er coup !
Mais ça ne marche plus avec l’exe !
Pour la ligne à couper en deux, il y a pire !
Si je modifie cette SUB ne serait-ce que par l’ajout d’une ligne vide, ça ne MARCHERA PLUS !!!!!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Cobra

avatar

Nombre de messages : 13
Localisation : France
Date d'inscription : 05/11/2009

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Sam 12 Sep 2015 - 23:34

Bonjour à tous,

Essai avec Panoramic_Editor v09.26

Sous W10 :

- Programme original : problème au lancement depuis l'éditeur et problème avec l'exe
- Programme corrigé : Ok au lancement depuis l'éditeur mais problème avec l'exe

Sous XP :

- Programme original : Ok au lancement depuis l'éditeur mais problème avec l'exe
- Programme corrigé : problème au lancement depuis l'éditeur et problème avec l'exe

C'est en effet très bizarre comme comportement !!!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 8002
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Sam 12 Sep 2015 - 23:40

Content de te revoir parmis nous Cobra !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Cobra

avatar

Nombre de messages : 13
Localisation : France
Date d'inscription : 05/11/2009

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Sam 12 Sep 2015 - 23:50

Merci ygeronimi
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5613
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Dim 13 Sep 2015 - 0:42

J’ai modifié le S/P clics comme ceci :
Je préfère la structure SELECT …. CASE …. END_SELECT à la cascade de IF. (Simple gout personnel !  Laughing )


Code:

clics:
    select number_click
         case 03 : reinit()
         case 04 : divise()
         case 05 : multipli()
         case 06 : moins()
         case 07 : bt("7")
         case 08 : bt("8")
         case 09 : bt("9")
         case 10 : bt("4")
         case 11 : bt("5")
         case 12 : bt("6")
         case 13 : bt("1")
         case 14 : bt("2")
         case 15 : bt("3")
         case 16 : bt("0")
         case 17 : PC()
         case 18 : Virg()
         case 19 : Plus()
         case 20 : Egal()
    end_select
RETURN
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Jean Claude

avatar

Nombre de messages : 5086
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Dim 13 Sep 2015 - 10:42

Merci pour vos réponses.

Je vais revoir mon code car j'ai une petite idée derrière la tête.
Ce sera ce soir ou demain car j'ai des invites à midi et c'est moi qui cuisine. Very Happy

@Papydall,
j'ai adopté SELECT/CASE, je n'y pense jamais.
Bien que, du coup, ma numérotation des objets par variable ne sert plus à rien.

A+ pour la suite
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
silverman

avatar

Nombre de messages : 475
Age : 45
Localisation : Picardie
Date d'inscription : 19/03/2015

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Dim 13 Sep 2015 - 12:37

bonjour à tous,

@jean-claude
tu es victime du bug de panoramic; si tu ajoutes des lignes vides dans ton source, la division va surement refonctionner, mais d'autres boutons ne marcheront plus. C'est arrivé à quelqu'un d'autre déjà, mais je ne souviens plus de qui.
J'ai obtenu ce bug en ajoutant une ligne vide dans la sub divise(), avec l'editeur. Peut-être qu'en réécrivant ton source d'une autre manière, tu arriveras à le contourner. Ou bien tu envoi un mp à jack, car tu as là un source qui montre le bug et qui pourrait aider jack à comprendre ce qui se passe dans son logiciel
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Marc



Nombre de messages : 549
Age : 56
Localisation : TOURS
Date d'inscription : 18/03/2014

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Dim 13 Sep 2015 - 12:49

Bonjour à tous !

Jean-Claude : Elle est super mignonne ta calculette !

Merci !

Ton bug me rappelle mes déboires avec mon programme CIBUS : le fait d'ajouter une ligne vide dans le code, à n'importe quel endroit, suffit à créer ou ôter le bug.

J'ai commencé aussi une calculatrice, pas aussi mignonne que la tienne !
Je vais essayer de la finir et de la poster... dans les jours qui suivent.

Bon dimanche !

Marc

Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Klaus

avatar

Nombre de messages : 10243
Age : 68
Localisation : Ile de France
Date d'inscription : 29/12/2009

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Dim 13 Sep 2015 - 13:19

Je viens de prendre ton source du WebDav, et j'ai testé. Je sous sous W10 64 bits, avec PAnoramic V0.9.26, donc dernière version.

Constat:
1. le bouton "division" est inactif en lançant dans Panoramic_Editor.
2. insérer une ligne quelconque, même un commentaire, peut débloquer la situation, mais pas toujours. Et l'emplacement de la ligne n'a pas d'importance
3. J'ai modifié la procédure reinit() comme suit, en mettant set_focus en commentaire:
Code:
rem ============================================================================
SUB reinit()
    tour%=0 : nb=0 : nbP=0 : nombre$="" : lig$="" : op$="" : mode$="" : inactive bt_PC%
    clear afi_op% : clear afi_result% : inactive bt_egal% : inactive_boutons() : active bt_virg%
    Ctrl_bouton() : ' set_focus 0
END_SUB
4. cela fonctionne maintenant parfaitement à partir de Panoramic_Editor
5. cela fonctionne également avec l'exécutable généré

Conclusion:
C'est bien le set_focus qui pose problème, et qui est parfaitement inutile à cet endroit. Mais à l'évidence, il y a un bug.

EDIT

L'arrêt de l'exécutable par la croix rouge généré semble fonctionner, mais laisse le processus en mémoire, visible dans l'onglet "Détails" (liste des processus) du gestionnaire des tâches. Il faut le tuer manuellement...
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://klauspanoramic.comxa.com/index.html
Jean Claude

avatar

Nombre de messages : 5086
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Dim 13 Sep 2015 - 17:42

Merci à Sylverman, Marc37 et à Klaus pour vos réponses.

@Klaus,
Le set_focus 0 n'est pas là par hasard. Il permet d'avoir l'afficheur du haut (qui est un LIST) vierge. C'est à dire sans les pointillés.

Mais le problème, c'est pas SET_FOCUS.

Essai ce changer la SUB reinit, comme ceci:
Code:
SUB reinit()
    tour%=0 : nb=0 : nbP=0 : nombre$="" : lig$="" : op$="" : mode$="" : inactive bt_PC%
    clear afi_op% : clear afi_result% : inactive bt_egal% : inactive_boutons() : active bt_virg%
    Ctrl_bouton()
    set_focus 0
END_SUB
Là au lancement dans l'éditeur, la division ne fonctionne pas.


Maintenant ajoute une ligne vide après set_focus 0
Et là ça marche et la transformation en exe aussi.
Et à la fermeture par la croix rouge, il n'y a plus de processus en mémoire.


J'en conclu qu'il y a un bug dans Panoramic.

Je vais voir avec Jack.

A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Klaus

avatar

Nombre de messages : 10243
Age : 68
Localisation : Ile de France
Date d'inscription : 29/12/2009

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Dim 13 Sep 2015 - 19:21

J'ai fait ceci:
Code:
' Calculette_Basique par JC 08/2015
hide 0
application_title "CALCULETTE (Basique)"
' message string$(51," ")+"INFORMATION"+chr$(13)+"Cette calculette est destinée aux enfants. Elle ne fait qu'un calcul à la fois."
Retourne_Dimension_Bandeau_Et_Bord()
Dim_Label()
Objets()
show 0
reinit()
END
rem ============================================================================
clics:
  if number_click=bt_CE% then reinit()
  if number_click=bt_divise% then divise()
  if number_click=bt_multipli% then multipli()
  if number_click=bt_moins% then moins()
  if number_click=bt_virg% then virg()
  if number_click=bt_PC% then PC()
  if number_click=bt_plus% then plus()
  if number_click=bt_egal% then egal()
  if number_click=bt_0% then bt("0")
  if number_click=bt_1% then bt("1")
  if number_click=bt_2% then bt("2")
  if number_click=bt_3% then bt("3")
  if number_click=bt_4% then bt("4")
  if number_click=bt_5% then bt("5")
  if number_click=bt_6% then bt("6")
  if number_click=bt_7% then bt("7")
  if number_click=bt_8% then bt("8")
  if number_click=bt_9% then bt("9")
RETURN

rem ============================================================================
SUB reinit()
    tour%=0 : nb=0 : nbP=0 : nombre$="" : lig$="" : op$="" : mode$="" : inactive bt_PC%
    clear afi_op% : clear afi_result% : inactive bt_egal% : inactive_boutons() : active bt_virg%
    Ctrl_bouton() : set_focus 0
END_SUB
SUB Ctrl_bouton()
    if active(bt_egal%)=0 then file_load bt_egal%,"egal_nb.bmp"
    if active(bt_egal%)=1 then file_load bt_egal%,"egal.bmp"
    if active(bt_virg%)=0 then file_load bt_virg%,"virgule_nb.bmp"
    if active(bt_virg%)=1 then file_load bt_virg%,"virgule.bmp"
    if active(bt_PC%)=0 then file_load bt_PC%,"Pourcentage_nb.bmp"
    if active(bt_PC%)=1 then file_load bt_PC%,"Pourcentage.bmp"
    if active(bt_plus%)=0 then file_load bt_plus%,"plus_nb.bmp"
    if active(bt_plus%)=1 then file_load bt_plus%,"plus.bmp"
    if active(bt_moins%)=0 then file_load bt_moins%,"moins_nb.bmp"
    if active(bt_moins%)=1 then file_load bt_moins%,"moins.bmp"
    if active(bt_multipli%)=0 then file_load bt_multipli%,"multiplication_nb.bmp"
    if active(bt_multipli%)=1 then file_load bt_multipli%,"multiplication.bmp"
    if active(bt_divise%)=0 then file_load bt_divise%,"division_nb.bmp"
    if active(bt_divise%)=1 then file_load bt_divise%,"division.bmp"
END_SUB

' les 4 opérations
SUB divise()
    tour%=0 : active bt_virg%
    inactive_boutons() : op$="/" : clear afi_result% : lig$=lig$+" : " : affiche_lig()
    if mode$="" then nb=val(nombre$) : mode$="C" : nbP=nb : nb=0 : nombre$=""
END_SUB
SUB multipli()
    tour%=0 : active bt_virg% : active bt_PC%
    inactive_boutons() : op$="*" : clear afi_result% : lig$=lig$+" x " : affiche_lig()
    if mode$="" then nb=val(nombre$) : mode$="C" : nbP=nb : nb=0 : nombre$=""
END_SUB
SUB plus()
    tour%=0 : active bt_virg% : active bt_PC%
    inactive_boutons() : op$="+" : clear afi_result% : lig$=lig$+" + " : affiche_lig()
    if mode$="" then nb=val(nombre$) : mode$="C" : nbP=nb : nb=0 : nombre$=""
END_SUB
SUB moins()
    tour%=0 : active bt_virg% : active bt_PC%
    inactive_boutons() : op$="-" : clear afi_result% : lig$=lig$+" - " : affiche_lig()
    if mode$="" then nb=val(nombre$) : mode$="C" : nbP=nb : nb=0 : nombre$=""
END_SUB
' résultat
SUB egal()
  if numeric(nombre$)=1
    nb=val(nombre$)
  else
    if right$(nombre$,1)="%" and op$="*"
        nombre$=left$(nombre$,len(nombre$)-1) : nb=val(nombre$) : op$="%*"
    end_if
    if right$(nombre$,1)="%" and op$="+"
        nombre$=left$(nombre$,len(nombre$)-1) : nb=val(nombre$) : op$="%+"
    end_if
    if right$(nombre$,1)="%" and op$="-"
        nombre$=left$(nombre$,len(nombre$)-1) : nb=val(nombre$) : op$="%-"
    end_if
  end_if
  inactive bt_egal% : tour%=0 : active bt_virg%
  if op$="%*" then nbP=(nbP*nb)/100
  if op$="%+" then nbP=nbP+((nbP*nb)/100)
  if op$="%-" then nbP=nbP-((nbP*nb)/100)
  if op$="+" then nbP=nbP+nb
  if op$="-" then nbP=nbP-nb
  if op$="*" then nbP=nbP*nb
  if op$="/"
    if nb<>0
        nbP=nbP/nb
    else
        message "La division par zéro n'existe pas" : reinit() : EXIT_SUB
    end_if
  end_if
  clear afi_result% : lig$=lig$+" = "+str$(nbP) : affiche_lig()
  nb=0 : nombre$="" : mode$="F" : clear afi_result% : item_add afi_result%,str$(nbP)
  Ctrl_bouton()
END_SUB
' la touche %
SUB PC()
    inactive bt_PC%
    Ctrl_Mode() : nombre$=nombre$+"%" : affiche() : lig$=lig$+"%" : affiche_lig()
    Ctrl_bouton()
END_SUB
' la virgule
SUB virg()
    inactive bt_virg% : Ctrl_bouton()
    if tour%=0 or mode$="F" then nombre$="0" : lig$=lig$+"0"
    nombre$=nombre$+"." : affiche() : lig$=lig$+"," : affiche_lig()
    if mode$="F"  then inactive bt_egal% :  mode$="" : lig$="0," : nbP=0 : affiche_lig()
END_SUB
' les chiffres
SUB bt(n$)
    Ctrl_Mode() : nombre$=nombre$+n$ : lig$=lig$+n$ : n$="" : affiche() : affiche_lig()
END_SUB
SUB Ctrl_Mode()
    Ctrl_bouton()
    if mode$="F" then inactive bt_egal% : mode$="" : lig$="" : nbP=0 : affiche_lig()
    if mode$="C" then active bt_egal% : inactive_boutons()
    if mode$="" then active_boutons()
    tour%=tour%+1
END_SUB
' l'affichage
SUB affiche()
    if len(nombre$)>14 then message "  14 chiffres maximum !  " : reinit() : Exit_Sub
    clear afi_result% : item_add afi_result%,nombre$
END_SUB
SUB affiche_lig()
    clear afi_op%
    if len(lig$)>26 then Exit_Sub
    item_add afi_op%,lig$
END_SUB
' contrôle des boutons
SUB inactive_boutons()
    inactive bt_divise% : inactive bt_multipli% : inactive bt_moins% : inactive bt_plus%
    Ctrl_bouton()
END_SUB
SUB active_boutons()
    active bt_divise% : active bt_multipli% : active bt_moins% : active bt_plus%
    Ctrl_bouton()
END_SUB
rem ============================================================================
SUB Dim_Label()
    dim no%,tour%
    dim nb,nbP
    dim virgul$,nombre$,lig$,op$,mode$
    virgul$="."
    dim afi_result%,afi_op%
    dim bt_CE%,bt_divise%,bt_multipli%,bt_moins%,bt_virg%,bt_PC%,bt_plus%,bt_egal%
    dim bt_0%,bt_1%,bt_2%,bt_3%,bt_4%,bt_5%,bt_6%,bt_7%,bt_8%,bt_9%
    label fin,clics
END_SUB
' ------------------------------------------------------------------------------
SUB Objets()
    ' Form 0
    border_small 0 : caption 0,"CALCULETTE (Basique)" : width 0,400
    height 0,302 : width 0,187 : top 0,(screen_y/2)-(height(0)/2) : left 0,(screen_x/2)-(width(0)/2)
    color 0,150,240,255
    ' Afficheurs
    no%=no%+1 : afi_op%=no% : list no% :' font_bold no%
                width no%,width(0)-(bord%*2)-8 : left no%,4 : height no%,20 : top no%,5
    no%=no%+1 : afi_result%=no% : list no% : color no%, 255,255,0
                font_color no%,0,100,255
                font_bold no% : font_size no%,14
                width no%,width(0)-(bord%*2)-8 : left no%,4 : height no%,30 : top no%,top(afi_op%)+height(afi_op%)+2
    ' les boutons
    ' la première rangée
    no%=no%+1 : bt_CE%=no% : picture no% : width no%,40 : height no%,40 : file_load no%,"clear.bmp"
                  top no%,top(afi_result%)+height(afi_result%)+2 : left no%,left(afi_result%)
                  on_click no%,clics
    no%=no%+1 : bt_divise%=no% : picture no% : width no%,40 : height no%,40 : file_load no%,"division.bmp"
                  top no%,top(afi_result%)+height(afi_result%)+2 : left no%,left(bt_CE%)+width(bt_CE%)+1
                  on_click no%,clics
    no%=no%+1 : bt_multipli%=no% : picture no% : width no%,40 : height no%,40 : file_load no%,"multiplication.bmp"
                  top no%,top(afi_result%)+height(afi_result%)+2 : left no%,left(bt_divise%)+width(bt_divise%)+1
                  on_click no%,clics
    no%=no%+1 : bt_moins%=no% : picture no% : width no%,40 : height no%,40 : file_load no%,"moins.bmp"
                  top no%,top(afi_result%)+height(afi_result%)+2 : left no%,left(bt_multipli%)+width(bt_multipli%)+1
                  on_click no%,clics
    ' la deuxième rangée
    no%=no%+1 : bt_7%=no% : picture no% : width no%,40 : height no%,40 : file_load no%,"7.bmp"
                  top no%,top(afi_result%)+height(afi_result%)+height(bt_CE%)+2 : left no%,left(bt_CE%)
                  on_click no%,clics
    no%=no%+1 : bt_8%=no% : picture no% : width no%,40 : height no%,40 : file_load no%,"8.bmp"
                  top no%,top(afi_result%)+height(afi_result%)+height(bt_CE%)+2 : left no%,left(bt_7%)+width(bt_7%)+1
                  on_click no%,clics
    no%=no%+1 : bt_9%=no% : picture no% : width no%,40 : height no%,40 : file_load no%,"9.bmp"
                  top no%,top(afi_result%)+height(afi_result%)+height(bt_CE%)+2 : left no%,left(bt_8%)+width(bt_8%)+1
                  on_click no%,clics
    ' la troisième rangée
    no%=no%+1 : bt_4%=no% : picture no% : width no%,40 : height no%,40 : file_load no%,"4.bmp"
                  top no%,top(afi_result%)+height(afi_result%)+(height(bt_CE%)*2)+2 : left no%,left(bt_7%)
                  on_click no%,clics
    no%=no%+1 : bt_5%=no% : picture no% : width no%,40 : height no%,40 : file_load no%,"5.bmp"
                  top no%,top(afi_result%)+height(afi_result%)+(height(bt_CE%)*2)+2 : left no%,left(bt_8%)
                  on_click no%,clics
    no%=no%+1 : bt_6%=no% : picture no% : width no%,40 : height no%,40 : file_load no%,"6.bmp"
                  top no%,top(afi_result%)+height(afi_result%)+(height(bt_CE%)*2)+2 : left no%,left(bt_9%)
                  on_click no%,clics
    ' quatrième rangée
    no%=no%+1 : bt_1%=no% : picture no% : width no%,40 : height no%,40 : file_load no%,"1.bmp"
                  top no%,top(afi_result%)+height(afi_result%)+(height(bt_CE%)*3)+2 : left no%,left(bt_4%)
                  on_click no%,clics
    no%=no%+1 : bt_2%=no% : picture no% : width no%,40 : height no%,40 : file_load no%,"2.bmp"
                  top no%,top(afi_result%)+height(afi_result%)+(height(bt_CE%)*3)+2 : left no%,left(bt_5%)
                  on_click no%,clics
    no%=no%+1 : bt_3%=no% : picture no% : width no%,40 : height no%,40 : file_load no%,"3.bmp"
                  top no%,top(afi_result%)+height(afi_result%)+(height(bt_CE%)*3)+2 : left no%,left(bt_6%)
                  on_click no%,clics
    ' cinquième rangée
    no%=no%+1 : bt_0%=no% : picture no% : width no%,40 : height no%,40 : file_load no%,"0.bmp"
                  top no%,top(afi_result%)+height(afi_result%)+(height(bt_CE%)*4)+2 : left no%,left(bt_1%)
                  on_click no%,clics
    no%=no%+1 : bt_PC%=no% : picture no% : width no%,40 : height no%,40 : file_load no%,"Pourcentage.bmp"
                  top no%,top(afi_result%)+height(afi_result%)+(height(bt_CE%)*4)+2 : left no%,left(bt_2%)
                  on_click no%,clics
    no%=no%+1 : bt_virg%=no% : picture no% : width no%,40 : height no%,40 : file_load no%,"virgule.bmp"
                  top no%,top(afi_result%)+height(afi_result%)+(height(bt_CE%)*4)+2 : left no%,left(bt_3%)
                  on_click no%,clics
    ' Bouton +
    no%=no%+1 : bt_plus%=no% : picture no% : width no%,40 : height no%,80 : file_load no%,"plus.bmp"
                  top no%,top(afi_result%)+height(afi_result%)+height(bt_moins%)+2 : left no%,left(bt_multipli%)+width(bt_multipli%)+1
                  on_click no%,clics
    ' Bouton =
    no%=no%+1 : bt_egal%=no% : picture no% : width no%,40 : height no%,80 : file_load no%,"egal.bmp"
                  top no%,top(bt_3%) : left no%,left(bt_plus%)
                  on_click no%,clics
END_SUB
rem ============================================================================
SUB Retourne_Dimension_Bandeau_Et_Bord()
    ' controle de la position de la procédure dans le programme
    IF NUMBER_OBJECTS>0
      message "La SUB 'Retourne_Dimension_Bandeau_Et_Bord' doit être placée avant la création du premier objet !"
      terminate
    END_IF
    ' création des VARIABLES GLOBALES
    IF VARIABLE("bandeau%")=0 then DIM bandeau%
    IF VARIABLE("bord%")=0 then DIM bord%
    ' Calcul de bandeau% et bord%
    dim_local w0%,h0%,w1%,h1%,w2%,h2%
    w0%=WIDTH(0) : h0%=HEIGHT(0)
    picture 1 : full_space 1 : w1%=WIDTH(1) : h1%=HEIGHT(1)
    w2%=w0%-w1% : h2%=h0%-h1% : bandeau%=h2%-(w2%/2) : bord%=w2%/2
    ' Suppression du Picture devenu inutile
    delete 1
END_SUB
rem ============================================================================
fin:
  terminate
RETURN

Chez moi, ça marche aussi bien sous l'éditeur que sous forme de EXE généré.

La différence, c'est que j'ai retiré toutes les commandes "parent no%,0"...
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://klauspanoramic.comxa.com/index.html
Jean Claude

avatar

Nombre de messages : 5086
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Dim 13 Sep 2015 - 21:02

Oui, j'ai fait le test et le problème a disparu.

Cela reste un mystère car même si c'était inutile de déclarer parent N,0, le code reste valable (je veux dire qu'il n'est pas faux).

Pour moi ce sujet est clos vu que c'est résolu.

A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Klaus

avatar

Nombre de messages : 10243
Age : 68
Localisation : Ile de France
Date d'inscription : 29/12/2009

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Dim 13 Sep 2015 - 22:02

Certes, c'est résolu pour ton programme. Reste qu'il y a bien un big dans Panoramic, dès lors qu'on utilise la commande "parent N,0" sur tous les objets. Certes, la form 0 est le parent par défaut. Mais cela ne devrait rien déranger. Or, ce n'est pas le cas... C'est un cas pour Jack.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://klauspanoramic.comxa.com/index.html
Jean Claude

avatar

Nombre de messages : 5086
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Mar 15 Sep 2015 - 9:39

@Klaus,
Je continu ma recherche ici pour garder le dialogue avec Jack clair ...(sur l'autre post) .

Si tu as le temps,
essai d'insérer cette ligne au début du label clics (dans le code d'origine)
Code:
message "ACTIVE de "+str$(number_click)+" est égale à"+str$(active(number_click))

dis-moi ce que tu en penses.

on a un problème d’événement...
A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Klaus

avatar

Nombre de messages : 10243
Age : 68
Localisation : Ile de France
Date d'inscription : 29/12/2009

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Mar 15 Sep 2015 - 12:18

Je l'avais déjà fait, cela, pendant mes tests. Constat: les valeurs de number_click sont bonnes, et le problème a disparu. Comme tu dis, c'est une histoire de fou...
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://klauspanoramic.comxa.com/index.html
Yannick

avatar

Nombre de messages : 8002
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Mar 15 Sep 2015 - 12:37

Dans mes programmes pour éviter ce problème qui m' a rendu dingo
une fois ou deux, j' en suis venu à ceci :

déclaration de variables événement : nclic%, ndclic%, nchange%

puis un label pour chacun : Clic,DClic,Change

puis la gestion des click :

CLIC:
   nclic% = number_click
   if nclic% = NumObjet% : Procedure() : return : end_if
return

de même pour le reste.

Depuis que je procède ainsi je n' ai plus de soucis.

Ps: tu peux te servir de Select...Case...End_select si les objets sont numérotés en dur.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Klaus

avatar

Nombre de messages : 10243
Age : 68
Localisation : Ile de France
Date d'inscription : 29/12/2009

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Mar 15 Sep 2015 - 12:56

J'ai essayé, Ygeronimi. J'ai déclaré une variable nb_click%, et j'ai modifié la routine ON_CLICK de la manière suivante:
Code:
clics:
  nb_click% = number_click
  if nb_click%=bt_CE% then reinit()
  if nb_click%=bt_divise% then divise()
  if nb_click%=bt_multipli% then multipli()
  if nb_click%=bt_moins% then moins()
  if nb_click%=bt_virg% then virg()
  if nb_click%=bt_PC% then PC()
  if nb_click%=bt_plus% then plus()
  if nb_click%=bt_egal% then egal()
  if nb_click%=bt_0% then bt("0")
  if nb_click%=bt_1% then bt("1")
  if nb_click%=bt_2% then bt("2")
  if nb_click%=bt_3% then bt("3")
  if nb_click%=bt_4% then bt("4")
  if nb_click%=bt_5% then bt("5")
  if nb_click%=bt_6% then bt("6")
  if nb_click%=bt_7% then bt("7")
  if nb_click%=bt_8% then bt("8")
  if nb_click%=bt_9% then bt("9")
RETURN
Mais le résultat est le même: le bouton "Divise" ne marche pas. Son évènement ON_CLICK ne se déclenche pas, tout simplement, et on n'arrive même pas dans la routine clics.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://klauspanoramic.comxa.com/index.html
Jean Claude

avatar

Nombre de messages : 5086
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   Mar 15 Sep 2015 - 13:11

Ton, astuce, Ygeronimi est intéressante.

Mais là, c'est le délire What a Face

La ligne 111 du code d'origine est un commentaire (' la touche %), il suffit d'enlever % pour que ça marche, mais à la condition qu'il n'y ai pas de ligne vide entre la 127 et la 128. Exclamation Question Exclamation Question

Il semble qu'il y a un problème de lecture du code par Panoramic_Editor.

C'est une piste à suivre.

A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Contenu sponsorisé




MessageSujet: Re: Une histoire de fou ou j'ai besoin de vacances (résolu)   

Revenir en haut Aller en bas
 
Une histoire de fou ou j'ai besoin de vacances (résolu)
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 1 sur 2Aller à la page : 1, 2  Suivant
 Sujets similaires
-
» Besoin d'avis sur un chalet!
» L'histoire d'une vie, l'histoire d'une envie.
» [Résolu] histoire de souris
» Histoire d'une migration ?
» C'est l'histoire d'une cerise qui bouffait des pastèques.

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: A l'aide!-
Sauter vers: