FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» KGF.dll - demandes ou suggestions de modifications ou ajouts
par Klaus Aujourd'hui à 19:48

» KGF_dll - nouvelles versions
par pascal10000 Aujourd'hui à 17:27

» Mah-Jong européen new-look
par Minibug Hier à 22:31

» track_bar circulaire
par Klaus Hier à 13:54

» API Windows
par Klaus Hier à 3:21

» Cartes de voeux, menus, etc.
par JL35 Lun 11 Déc 2017 - 17:48

» a l'aide klaus
par Minibug Lun 11 Déc 2017 - 11:42

» bug SYNEDIT_TARGET_IS_OBJECT
par Jack Lun 11 Déc 2017 - 0:16

» Jukebox : Serge Reggiani
par papydall Sam 9 Déc 2017 - 5:58

» Ecouter la radio fm sur votre pc
par pascal10000 Sam 9 Déc 2017 - 3:42

» anomalie
par Klaus Sam 9 Déc 2017 - 3:21

» hommage
par Jicehel Ven 8 Déc 2017 - 11:29

» Logiciel de soutien scolaire en langues.
par Pedro Alvarez Ven 8 Déc 2017 - 10:43

» carte son
par Klaus Ven 8 Déc 2017 - 2:37

» mise a jour calculatrice
par joeeee2017 Mer 6 Déc 2017 - 22:19

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Décembre 2017
LunMarMerJeuVenSamDim
    123
45678910
11121314151617
18192021222324
25262728293031
CalendrierCalendrier

Partagez | 
 

 Art-ithmétique pour vous faire aimer les maths

Voir le sujet précédent Voir le sujet suivant Aller en bas 
AuteurMessage
papydall

avatar

Nombre de messages : 5613
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Art-ithmétique pour vous faire aimer les maths   Sam 5 Sep 2015 - 0:27

Art-ithmétique pour vous faire aimer les maths
Les faces cachées des tables de multiplication.


Ref : https://www.youtube.com/watch?v=-X49VQgi86E

Représentation graphique des tables de multiplications :
Soit un cercle de centre O et de rayon R.
Sur ce cercle plaçons un certain nombre de points équitablement repartis.
Par exemple 10 points numérotés de 0 à 9 (0 en haut du cercle, puis en tournant dans le sens des aiguilles d'une montre, les nombres 1, 2, 3, jusqu’ à 9.
Si on veut continuer cette numérotation au-delà de 9, le 10 se trouverait au même endroit que le 0, le 11 au même endroit que le 1, le 12 au même endroit que le 2 et ainsi de suite.
Cette façon de représenter les nombres de façon cyclique représente ce qu'on appelle l'arithmétique modulaire. C'est-à-dire une arithmétique dans laquelle les nombres tournent en rond.


Spoiler:
 

Dans cet exemple on a 10 points et les nombres tournent avec un cycle de 10.
On dit que l'on a représenté les nombres modulo 10.
Sur ce cercle on va représenter nos tables de multiplication.
Commençons par la plus simple : la table de 2.
Pour représenter dans ce cercle la table de 2, nous allons relier chaque nombre à son résultat par la multiplication par 2.
Par exemple, le nombre 1, si on fait 1 fois 2 on obtient 2. Nous allons relier le nombre 1 au nombre 2

Spoiler:
 

Puis 2 fois 2, ça fait 4. Nous allons donc relier le 2 au 4.


Spoiler:
 

3 fois 2, ça fait 6, nous relions donc le 3 au 6.


Spoiler:
 

4 fois 2, ça fait 8, nous relions le 4 au 8.


Spoiler:
 

5 fois 2, ça fait 10 et rappelons-nous que le 10 se trouve au même endroit que le 0, nous relions donc le 5 au 0


Spoiler:
 
et ainsi de suite avec tous les nombres du  cercle.
Le 6 au 2 (qui est le 12)

Spoiler:
 

Le 7 au 4 (qui est le 14)

Spoiler:
 

Le 8 au 6 (qui est le 16)

Spoiler:
 

Le 9 au 8 (qui est le 18)

Spoiler:
 

On a donc obtenu la représentation de la table de 2  modulo 10.

Mais rien ne nous empêche de représenter la table de 2 modulo 11 ou modulo 12 ou modulo un nombre aussi grand que l'on veut.
Par exemple voici la table de 2 modulo 50


Spoiler:
 

La table de 2  modulo 100


Spoiler:
 

La table de 2  modulo 200


Spoiler:
 
La table de 2  modulo 500



Spoiler:
 


Pour un nombre grand, la figure obtenue semble sortir de nulle part puisque d'après notre procédé de construction, ce dessin ne contient que des lignes droites.
C'est donc une illusion d'optique et que l'enchevêtrement de toutes ces lignes droites  nous donne l'impression de cette figure courbe qui apparaît.

On procède de la même façon avec les autres tables :
Avec la table de 3, on obtient une figure qui semble composée de deux pétales.
Avec la table de 4, trois pétales; avec la table de 5, quatre pétales; avec la table de 6, cinq pétales.
On peut conclure que pour une table d'un nombre n, on obtient une sorte de fleur ayant une pétale de moins que le nombre de la table de multiplication.
Tout ça est beau et même très beau, mais pourquoi nous n'essayons pas avec des tables des nombres non pas entiers mais décimaux comme par exemple la table de 2.3 ou 2.5 ?
Servez-vous! Donnez libre court à votre imagination!

Et pour terminer, voici le code qui réalise tout ça.

Code:

rem ============================================================================
REM       Art-ithmétique pour vous faire aimer les maths
REM       Les faces cachées des tables de multiplication
rem                 Par Papydall
rem     Ref : https://www.youtube.com/watch?v=-X49VQgi86E
REM ============================================================================
' Représentation graphique des tables de multiplications :
' Soit un cercle de centre O et de rayon R.
' Sur ce cercle plaçons un certain nombre de points équitablement repartis.
' Par exemple 10 points numérotés de 0 à 9 (0 en haut du cercle, puis en
' tournant dans le sens des aiguilles d'une montre,les nombres 1,2,3,jusqu à 9.
' Si on veut continuer cette numérotation au-delà de 9,le 10 se trouverait au
' même endroit que le 0, le 11 au même endroit que le 1, le 12 au même endroit
' que le 2 et ainsi de suite.
' Cette façon de représenter les nombres de façon cyclique représente ce qu'on
' appelle l'arithmétique modulaire. C'est-à-dire une arithmétique dans laquelle
' les nombres tournent en rond.
' Dans cet exemple on a 10 points et les nombres tournent avec un cycle de 10.
' On dit que l'on a représenté les nombres modulo 10.
' Sur ce cercle on va représenter nos tables de multiplication.
' Commençons par la plus simple : la table de 2.
' Pour représenter dans ce cercle la table de 2, nous allons relier chaque nombre
' à son résultat par la multiplication par 2.
' Par exemple, le nombre 1, si on fait 1 fois 2 on obtient 2. Nous allons relier
' le nombre 1 au nombre 2; puis 2 fois 2, ça fait 4. Nous allons donc relier
' le 2 au 4.
' 3 fois 2, ça fait 6, nous relions donc le 3 au 6.
' 4 fois 2, ça fait 8, nous relions le 4 au 8.
' 5 fois 2, ça fait 10 et rappelons-nous que le 10 se trouve au même endroit que
' le 0, nous relions donc le 5 au 0 et ainsi de suite avec tous les nombres du
' cercle.
' On a donc obtenu la représentation de la table de 2 modulo 10.
' Mais rien ne nous empêche de représenter la table de 2 modulo 11 ou modulo 12
' ou modulo un nombre aussi grand que l'on veut.
' Pour un nombre grand, la figure obtenue semble sortir de nulle part puisque
' d'après notre procédé de construction, ce dessin ne contient que des lignes droites.
' C'est donc une illusion d'optique et que l'enchevêtrement de toutes ces lignes
' droites  nous donne l'impression de cette figure courbe qui apparait.
' Avec la table de 3, on obtient une figure qui semble composée de deux pétales.
' Avec la table de 4, trois pétales; avec la table de 5, quatre pétales;
' avec la table de 6, cinq pétales.
' On peut conclure que pour une table d'un nombre n , on obtient une sorte de
' fleur ayant une pétale de moins que le nombre de la table de multiplication.
' Tout ça est beau et même très beau, mais pourquoi nous n'essayons pas avec
' des tables des nombres non pas entiers mais décimaux comme par exemple
' la table de 2.3 ou 2.5 ?
' Servez-vous! Donnez libre court à votre imagination!
rem ============================================================================

Run()

END
REM ============================================================================
SUB Run()
    dim xc,yc,r,pi,twopi,halfpi,modulo,multiplicande,increment,t$
    full_space 0
    picture 10 : height 10,height(0)-100 : width 10,height(10)
    top 10,30 : left 10,(width(0)-width(10))/2 : 2d_target_is 10 : print_target_is 10
    color 10,100,150,0
    alpha 20 : top 20,050 : left 20,10 : font_bold 20 : font_size 20,14
    alpha 30 : top 30,100 : left 30,10 : font_bold 30 : font_size 30,14
    xc = width(10)/2 : yc = height(10)/2 : r = width(10)/2 - 50
    pi = acos(-1) : twopi = 2*pi : halfpi = pi/2
    caption 0,"Art-ithmétique"
    t$ = t$ + chr$(13) + chr$(13) + "A R T - I T H M E T I Q U E"
    t$ = t$ + chr$(13) + chr$(13) + "Rappelez-vous que toutes ces figures" +chr$(13)
    t$ = t$ + "ont été obtenues uniquement" + chr$(13)
    t$ = t$ + "avec des droites !!!"+chr$(13)
    t$ = t$ + "Les formes courbes que vous voyez"+chr$(13)
    t$ = t$ + "ne sont que des illusions d'optique."+chr$(13)
    t$ = t$ + "Votre cerveau vous joue des tours !!!!"  +chr$(13) + chr$(13)
    t$ = t$ + "<CLICK> Pour arrêter ....."
    caption 30,t$
    modulo        = 500 : ' essayer avec 1000
    multiplicande = 2
    increment     = 1   : ' essayer avec 0.1 ou 0.01
    repeat
        Cercle(modulo,multiplicande)  : multiplicande = multiplicande + increment
        pause 500   : ' Vous pouvez virer purement et simplement cette pause
    until scancode <> 0
END_SUB
REM ============================================================================
SUB Cercle(modulo,multiplicande)
    dim_local i,a,x,y,x1,y1,x2,y2
    a = twopi/modulo
    t$ = "Table de multiplication de :"+chr$(13) + str$(multiplicande)+ " modulo " +str$(modulo)
    caption 20,t$
    2d_fill_on : 2d_fill_color 255,0,0 : 2d_pen_color 255,255,0 : 2d_circle xc,yc,r
    for i = 0 to modulo-1
        x1 = xc+r*cos(halfpi-a*i) : y1 = yc-r*sin(halfpi-a*i)
        x2 = xc+r*cos(halfpi-a*i*multiplicande) : y2 = yc-r*sin(halfpi-a*i*multiplicande)
        2d_line x1,y1,x2,y2
    next i
END_SUB
REM ============================================================================
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Klaus

avatar

Nombre de messages : 10257
Age : 68
Localisation : Ile de France
Date d'inscription : 29/12/2009

MessageSujet: Re: Art-ithmétique pour vous faire aimer les maths   Sam 5 Sep 2015 - 0:47

Magnifique, Papydall, et stupéfiant !

As-tu l'équation de la courbe qui pourrait dessiner directement la figure qui semble se préciser (cette fleur à n-1 pétales), un peu à la manière d'une courbe "enveloppante" ? Je pose cette question par pure curiosité, sans intérêt concret immédiat.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://klauspanoramic.comxa.com/index.html
papydall

avatar

Nombre de messages : 5613
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Art-ithmétique pour vous faire aimer les maths   Sam 5 Sep 2015 - 1:07

Salut Klaus.

En vérité, il ne s’agit pas de courbe.
L’image obtenue est un enchevêtrement des lignes droites qui donne l’impression de courbe.
Ce ne sont que des enveloppes de droite.
On peut obtenir la même figure (à une rotation près de 90°) en reliant les points de coordonnées polaires (r,theta) et (r,n*theta) tout en variant theta d’un angle donné.

Voici un code (plus concis) qui réalise la même figure qui est, je rappelle, formée uniquement des droites.

Code:

rem ============================================================================
rem Enveloppes de droite
rem sur un cercle de rayon r, on joint les points de coordonnées polaires
rem (r,a) et (r,n*a) en faisant varier a de p en p
rem ============================================================================

dim xc,yc,r, pi,p,n
full_space 0 : xc = width(0)/2 : yc = height(0)/2 : r = yc-100
pi = acos(-1) : p = pi/180
caption 0,"<CLICK> pour arrêter ...."
font_bold 0 : font_size 0,14
for n = 2 to 50
    Enveloppe(n) : pause 1000
    if scancode <> 0 then end
next n
print "T E R M I N E"
end
rem ============================================================================
SUB Enveloppe(n)
    dim_local a
    cls
    2d_fill_on : 2d_fill_color 255,0,0 : 2d_pen_color 255,255,0 : 2d_circle xc,yc,r
    for a = 0 to 2*pi step p
        2d_line xc+r*cos(a),yc+r*sin(a),xc+r*cos(n*a), yc+r*sin(n*a)
    next a
END_SUB
rem ============================================================================
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Klaus

avatar

Nombre de messages : 10257
Age : 68
Localisation : Ile de France
Date d'inscription : 29/12/2009

MessageSujet: Re: Art-ithmétique pour vous faire aimer les maths   Sam 5 Sep 2015 - 1:37

Certes, je vois bien ce que tu veux dire. Le terme de "courbe enveloppante" est mal choisi, et je ne l'ai employé que par analogie. Je veux dire par là l'équation d'une courbe qu épouse directement le tracé exact de la speudo-courbe qui apparaît en trompe-l'oeil.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://klauspanoramic.comxa.com/index.html
papydall

avatar

Nombre de messages : 5613
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Art-ithmétique pour vous faire aimer les maths   Sam 5 Sep 2015 - 2:39

Je vois ce que tu voulais dire.
La courbe qui épouse le tracé est une épicycloïde d’équation paramétrique :

x = r*((q+1)*cos(theta)-cos((q+1)*theta))
y = r*((q+1)*sin(theta)-sin((q+1)*theta))

La valeur de q détermine le nombre de point de rebroussement de la courbe (et donc le nombre de pétales)
Pour q = 1, on a une cardioïde ===> 1 point de rebroussement
Pour q = 2, on a une néphroïde ===> 2 points de rebroussement, etc

Code:

dim xc,yc,r, pi,p,n,theta ,x,y
full_space 0 : xc = width(0)/2 : yc = height(0)/2 : r = 100
pi = acos(-1) : p = pi/180

for n = 1 to 10 : cls : Epicycloide(n,r/n)  : pause 1000 : next n
end
rem ============================================================================
' Equation paramétrique de l'épicycloïde
' x = r*((q+1)*cos(theta)-cos((q+1)*theta))
' y = r*((q+1)*sin(theta)-sin((q+1)*theta))
' La valeur de q détermine le nombre de point de rebroussement de la courbe
' Pour q = 1, on a une cardioïde ===> 1 point de rebroussement
' Pour q = 2, on a une néphroïde ===> 2 points de rebroussement, etc
SUB Epicycloide(q,r)
    2d_poly_from xc+q*r,yc
    for theta = 0 to 2*pi step p
        x = r*((q+1)*cos(theta)-cos((q+1)*theta))
        y = r*((q+1)*sin(theta)-sin((q+1)*theta))
' Essayer l'une ou l'autre des lignes suivantes
      ' 2d_poly_to xc+x,yc+y
      2d_line xc,yc,xc+x,yc+y
next theta
END_SUB
rem ============================================================================
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Klaus

avatar

Nombre de messages : 10257
Age : 68
Localisation : Ile de France
Date d'inscription : 29/12/2009

MessageSujet: Re: Art-ithmétique pour vous faire aimer les maths   Sam 5 Sep 2015 - 3:48

Ouaouhhh ! Ca, c'est super ! Merci, Papydall. Je mettrai cela dans ma bibliothèque personnelle. J'ai toujours eu du respect et de l'admiration pour les personnes qui étaient capables de manier les mathématiques théoriques comme ça. Ces formules ont une beauté intrinsèque, et cela me fascine.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://klauspanoramic.comxa.com/index.html
Minibug

avatar

Nombre de messages : 2410
Age : 51
Localisation : Vienne (86)
Date d'inscription : 10/02/2012

MessageSujet: Re: Art-ithmétique pour vous faire aimer les maths   Sam 5 Sep 2015 - 8:03

Bonjour Papydall !

Je suis heureux de te retrouver permis nous. Wink

Encore BRAVO pour ce programme.
Mais ou vas tu chercher tout cela ?? peut importe c'est super et continu comme ça !!! cheers
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://gpp.panoramic.free.fr
Jicehel

avatar

Nombre de messages : 5863
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Art-ithmétique pour vous faire aimer les maths   Sam 5 Sep 2015 - 8:48

Bravo, c'est chouette et bien expliqué. PS: Tu as le texte, les illustrations et le code Panoramic pour fair un joli article sur les maths amusantes Wink
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5613
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Art-ithmétique pour vous faire aimer les maths   Sam 5 Sep 2015 - 13:10

Merci à vous tous.

Code:

rem ============================================================================
rem Courbes (lieux géométriques) décrites par un point M d un cercle (C)
rem roulant sans glisser sur l extérieur (épicycloïde) ou l intérieur
rem (hypocycloïde) d un cercle (C0)
rem
rem Equation paramétrique des épicycloïdes:
rem x = r*((n+1)*cos(t) - r*cos((n+1)*t)
rem y = r*((n+1)*sin(t) - r*sin((n+1)*t)
rem où r est le rayon du cercle de base
rem
rem Épicycloïde raccourcie ou allongée :
rem L épicycloïde est dite raccourcie si le point M est un point du disque de
rem bord (c)
rem L épicycloïde est dite allongée si le point M est un point attaché au disque
rem mais hors du disque.
rem
rem L équation générale des épicycloïdes allongées (resp. raccourcies) s obtient
rem en remplaçant le rayon r dans le terme en cos((n+1)*t) (resp. sin((n+1)*t) )
rem par k < r avec 0 < k < r  (resp. -k avec k > r) :
rem x = r*(n + 1)*cos(t) - k*cos((n + 1)*t)
rem y = r*(n + 1)*sin(t) - k*sin((n + 1)*t)
rem
rem Équation générale des hypocycloïdes :
rem L hypocycloïde est le lieu géométrique d un point M d un cercle (c) de
rem rayon r roulant sans glisser sur un cercle (C) de rayon R < r à l intérieur
rem de celui-ci.
rem
rem  x = r*(n - 1)*cos(t) + r*cos((n - 1)*t)
rem  y = r*(n - 1)*sin(t) - r*sin((n - 1)*t)
rem
rem Lorsque r = 1 et n = 4, on obtient l astroïde :
rem x = 3*cos(t) + cos(3*t)
rem y = 3*sin(t) - sin(3*t)
rem Lorsque r = 1 et n = 3, on obtient le deltoïde :
rem x = 2*cos(t) + cos(2*t)
rem y = 2*sin(t) - sin(2*t)
rem
rem Comme pour l épicycloïde, on parlera d hypocycloïde raccourcie ou allongée.
rem Exemples :
rem Hypocycloïde allongée d équation :
rem x = 4*cos(t) + 2*cos(4*t)
rem y = 4*sin(t) - 2*sin(4*t)
rem Hypocycloïde raccourcie d équation :
rem x = 4*cos(t) + cos(4*t)/2
rem y = 4*sin(t) - sin(4*t)/2
rem Et pour le plaisir des yeux:
rem x = 2*cos(t) + cos(3*t)
rem y = 2*sin(t) - sin(3*t)
rem ============================================================================

rem C est à vous de coder maintenant .............
rem ============================================================================


Et maintenant, régalez-vous !

Spoiler:
 
Spoiler:
 
Spoiler:
 
Spoiler:
 
Spoiler:
 
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Klaus

avatar

Nombre de messages : 10257
Age : 68
Localisation : Ile de France
Date d'inscription : 29/12/2009

MessageSujet: Re: Art-ithmétique pour vous faire aimer les maths   Sam 5 Sep 2015 - 19:50

Eblouissant, Papydall !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://klauspanoramic.comxa.com/index.html
papydall

avatar

Nombre de messages : 5613
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Art-ithmétique pour vous faire aimer les maths   Sam 5 Sep 2015 - 20:16

Merci à vous tous : Klaus, Minibug, Jicehel et les autres.

Minibug a écrit:
Mais ou vas tu chercher tout cela ?? peut importe c'est super et continu comme ça !!!  

Parfois,  pour les connaissances acquises quand j’avais le tiers de l’âge que j’ai aujourd’hui,  je sollicite le peu de neurones qui me restent.
Et souvent, elles (mes neurones restantes) ne me faisaient pas défaut, Dieu merci !
Pour le reste, mon fidèle ami Google est toujours là pour me venir à l’aide.

Et puis je te dévoile un secret.
Quand on parle (ou quand on écrit), on ne fait que répéter ce que l’on sait déjà.
Quand on écoute (ou quand on lit), il y a une forte chance que l’on apprenne quelque chose qu'on ignorait !
Alors écouter plus que parler et  lire plus qu’écrire, c’est enrichir ses connaissances.

sunny
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Minibug

avatar

Nombre de messages : 2410
Age : 51
Localisation : Vienne (86)
Date d'inscription : 10/02/2012

MessageSujet: Re: Art-ithmétique pour vous faire aimer les maths   Sam 5 Sep 2015 - 20:19

Bien dit Papydall !

Tu m'épates toujours... cheers
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://gpp.panoramic.free.fr
papydall

avatar

Nombre de messages : 5613
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Art-ithmétique pour vous faire aimer les maths   Sam 5 Sep 2015 - 20:29

Bon, récapitulons :
Aujourd’hui, j’ai fasciné Klaus ; j’ai amusé Jicehel ; j’ai épaté Minibug. king Quel bonheur!
Au suivant ! Laughing
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Contenu sponsorisé




MessageSujet: Re: Art-ithmétique pour vous faire aimer les maths   

Revenir en haut Aller en bas
 
Art-ithmétique pour vous faire aimer les maths
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» Art-ithmétique pour vous faire aimer les maths
» J'ai testé pour vous: la chute libre du Zümo.
» Que représente un ami pour vous?
» rien à voir avec rrtc mais...pour vous faire profiter !
» [Léo's tuts] Faire des jolis cadres pour les messages texte

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Vos sources, vos utilitaires à partager-
Sauter vers: