FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» Button_picture
par pascal10000 Aujourd'hui à 11:41

» Pourquoi le compilateur stagne
par Minibug Aujourd'hui à 11:09

» 4 (en analyse): SYNEDIT_TARGET_IS_OBJECT devient inactif
par Jack Aujourd'hui à 10:09

» 3 (en analyse): Mauvaise interprétation du string "THEN"
par Jack Aujourd'hui à 10:03

» KGF.dll - demandes ou suggestions de modifications ou ajouts
par Marc Aujourd'hui à 10:00

» KGF_dll - nouvelles versions
par pascal10000 Hier à 17:27

» Mah-Jong européen new-look
par Minibug Mar 12 Déc 2017 - 22:31

» track_bar circulaire
par Klaus Mar 12 Déc 2017 - 13:54

» API Windows
par Klaus Mar 12 Déc 2017 - 3:21

» Cartes de voeux, menus, etc.
par JL35 Lun 11 Déc 2017 - 17:48

» a l'aide klaus
par Minibug Lun 11 Déc 2017 - 11:42

» bug SYNEDIT_TARGET_IS_OBJECT
par Jack Lun 11 Déc 2017 - 0:16

» Jukebox : Serge Reggiani
par papydall Sam 9 Déc 2017 - 5:58

» Ecouter la radio fm sur votre pc
par pascal10000 Sam 9 Déc 2017 - 3:42

» anomalie
par Klaus Sam 9 Déc 2017 - 3:21

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Décembre 2017
LunMarMerJeuVenSamDim
    123
45678910
11121314151617
18192021222324
25262728293031
CalendrierCalendrier

Partagez | 
 

 Où est la tortue ?

Voir le sujet précédent Voir le sujet suivant Aller en bas 
AuteurMessage
Parpaiun

avatar

Nombre de messages : 192
Age : 78
Localisation : HERAULT
Date d'inscription : 15/04/2015

MessageSujet: Où est la tortue ?   Mar 30 Juin 2015 - 11:53

Papydall bonjour ! Je me sens complètement égaré par tous ces sous-programmes morcelés à souhait et concernant l'utilisation de la tortue LOGO.

J'ai beau les lancer, il me tombe toujours le même message d'erreur qui rappelle ce qui manque ci-dessous:
' !!!!! LA COMMANDE A NE PAS OUBLIER !!!!! #Include "Include_Turtle.bas":
 

Où dois je pêcher ce fameux "Turtle.bas" s'il te plaît ? (pas pour le bouffer, juste pour le caresser !) Merci d'avance . Question scratch

P.S.: Tu es le maître incontesté de la tortue. Donc je m'incline devant ta personne et je te félicite pour ton initiative et tes programmes !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 5086
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Où est la tortue ?   Mar 30 Juin 2015 - 12:46

La voici:

Attention: pour essayer tous les codes du sujet "Les routines tortue", il faut que tu crées un dossier sur ton bureau (tortue par exemple).
Ensuite tu colles le code ci_dessous dans l'éditeur Panoramic et tu l'enregistres avec ce nom: Include_Turtle.bas
Et à chaque fois que tu essaieras un code, à l'aide de Panoramic, tu seras obligé de l'enregistrer pour que ce code trouve Include_Turtle.bas pour fonctionner.

Code:
rem ============================================================================
rem     Include_Turtle.bas
rem     Auteur : Papydall
rem ============================================================================
rem Fichier à inclure à la fin de votre code
rem Votre programme doit avoir la structure suivante:
rem ============================================================================
Init_Turtle()  : ' Indispensable
' Votre programme débute ici

end
rem ============================================================================
' Vos procédures ici
rem
rem
rem
' Fin des procédures
rem ============================================================================
' #Include "Include_Turtle.bas"
rem ============================================================================
'Voici le fichier Include_Turtle.bas
rem ############################################################################
rem ============================================================================
rem                    LES PROCEDURES DE LA TORTUE
rem ============================================================================
rem ############################################################################
rem Les variables globales Turtle_XXX sont prédéfinies pour les routines TORTUE.
rem Votre programme ne doit ni les redéfinir ni les modifier.
rem Ce sont :
rem Turtle_Xorigine,Turtle_Yorigine : coordonnées de l origine (le centre de l écran)
rem Turtle_X,Turtle_Y : coordonnées relatives de la tortue (par rapport à l origine)
rem Turtle_Heading : direction initiale du déplacement de la tortue : vers le haut
rem Turtle_PI  : la constante Pi
rem Turtle_rad : multiplicateur pour transformer les degrés en radians
rem ============================================================================
rem REMARQUE IMPORTANTE :
rem L origine des axes est le centre de la fenêtre
rem Le sens positif sur l axe des X est dirigé vers la droite (négatif vers la gauche)
rem Le sens positif sur l axe des Y est dirigé vers le haut (négatif vers le bas)
rem ============================================================================
' Initialisation de la tortue graphique
' La tortue se trouve au centre de la fénêtre et est dirigée vers le Nord (cap 0)
SUB Init_Turtle()
    dim Turtle_Xorigine,Turtle_Yorigine :' coordonnées de l'origine (le centre de l'écran)
    dim Turtle_X,Turtle_Y : ' coordonnées relatives de la tortue (par rapport à l'origine)
    dim Turtle_Heading    : ' direction initiale du déplacement de la tortue vers le haut
    dim New_Turtle_Heading: ' Nouveau cap de la tortue
    dim Turtle_PI         : ' la constante Pi
    dim Turtle_rad        : ' multiplicateur pour transformer les degrés en radians
    dim Turtle_PR, Turtle_PG, Turtle_PB : ' RGB du tracé
    dim Turtle_FR, Turtle_FG, Turtle_FB : ' RGB du fond
    dim Turtle_Flood_R, Turtle_Flood_G, Turtle_Flood_B : ' RGB du remplissage
    dim Turtle_R, Turtle_G,Turtle_B : ' RGB
    dim Turtle_Pen_Up_Down  : ' Etat du crayon (0 = baissé) ; (1 = levé)
    dim Turtle_Return_value : ' Valeur de retour d'une SUB exploitée comme une fonction
' ------------------------------------------------------------------------------
    full_space 0   : ' Utiliser tout l'écran
    Turtle_Pen_Up_Down = 0           : ' crayon baissé au départ
    Turtle_Xorigine = width(0)/2     : ' L'origine de ...
    Turtle_Yorigine = height(0)/2-20 : ' ... l'écran graphique
    Turtle_PI  = acos(-1)      : ' pi
    Turtle_Heading = Turtle_PI/2   : ' La tortue est dirigée vers le haut
    Turtle_rad = Turtle_PI/180 : ' Facteur multiplicateur pour les angles (degrés --> radians)

    Nouveau()                  : ' Pour débuter un nouveau dessin
END_SUB
rem ============================================================================
rem ============================================================================
' Pour débuter un nouveau dessin
' Effacer l'écran et remettre la tortue à sa place
' (au centre de la fenêtre et dirigée vers le nord)
SUB Nouveau()
    CouleurCrayon(255,255,255) : ' Tracé en blanc
    CouleurFond(0,0,0)         : ' Fond noir Origine()
    cls : Origine()            : ' Ramener la tortue à l'origine
END_SUB
rem ============================================================================
' Ramener la tortue à l'origine (c-à-d au centre de la fenêtre)
' Ce qui est déjà tracé n'est pas effacé.
SUB Origine()
    Turtle_X = Turtle_Xorigine : Turtle_Y = Turtle_Yorigine
    2d_poly_from Turtle_X,Turtle_Y
    New_Turtle_Heading = Turtle_Heading
END_SUB
rem ============================================================================
' Avancer de pas pixels
' Si le crayon est baissé (Pen_Down), la tortue trace un trait avec la couleur en cours
' Si le crayon est levé (Pen_Up), la tortue se déplace sans laisser de trace
' ------------------------------------------------------------------------------
' Autres syntaxes :
' AV(pas)
' Foreward(pas)
' ------------------------------------------------------------------------------
SUB Avance(pas)
    dim_local x1,y1,x2,y2,a
    x1 = Turtle_X : y1 = Turtle_Y : a  = New_Turtle_Heading
    x2 = Turtle_X + pas * cos(a)  : y2 = Turtle_Y - pas * sin(a)

    if Turtle_Pen_Up_Down = 0 : ' crayon baissé ?
       2d_poly_to x2,y2       : ' on trace le trait avec la couleur en cours
    else                      : ' crayon levé
       2d_poly_from x2,y2     : ' on se déplace sans trace
    end_if
    Turtle_X = x2 : Turtle_Y = y2  : ' Mise à jour des variables

END_SUB
rem ============================================================================
' Réculer de pas pixels
' Si le crayon est baissé (Pen_Down), la tortue trace un trait avec la couleur en cours
' Si le crayon est levé (Pen_Up), la tortue se déplace sans laisser de trace
' ------------------------------------------------------------------------------
' Autres syntaxes :
' RE(pas)
' Back(pas)
' ------------------------------------------------------------------------------
SUB Recule(pas)
    Avance(0-pas)
END_SUB
rem ============================================================================
' Tourner à gauche (sens trigonométrique) de a degrés
' ------------------------------------------------------------------------------
' Autres syntaxes :
' TG(a)
' Turn_Left(a)
' ------------------------------------------------------------------------------
SUB Gauche(a)
    New_Turtle_Heading = New_Turtle_Heading + a * Turtle_rad
END_SUB
rem ============================================================================
' Tourner à droite (sens horaire) de a degrés
' ------------------------------------------------------------------------------
' Autres syntaxes :
' TD(a)
' Turn_Right(a)
' ------------------------------------------------------------------------------
SUB Droite(a)
    New_Turtle_Heading = New_Turtle_Heading - a * Turtle_rad
END_SUB
rem ============================================================================
' Fixer le Cap de la tortue de manière absolue selon l'angle de a degrés
' Le Cap est la direction du déplacement de la tortue selon la rose du vent
' ------------------------------------------------------------------------------
' 0   c'est vers le haut (NORD)
' 90  c'est vers la droite (EST)
' 180 c'est vers le bas (SUD)
' 270 c'est vers la gauche (OUEST)
' 360 c'est identique à 000
' ------------------------------------------------------------------------------
' Autre syntaxe :
' Set_Heading(a)
' ------------------------------------------------------------------------------
SUB Cap(a)
    New_Turtle_Heading = Turtle_Heading - a * Turtle_rad
END_SUB
rem ============================================================================
' Fixer la position X de la tortue par rapport à l'origine
' Déplacement horizontal
SUB Pos_X(n)
    Turtle_X = Turtle_Xorigine + n : 2d_poly_from Turtle_X,Turtle_Y
END_SUB
rem ============================================================================
' Fixer la position Y de la tortue par rapport à l'origine
' Déplacement vertical
rem ############################################################################
rem   REMARQUE IMPORTANTE : le sens posif pour les Y est le sens vers le haut
rem ############################################################################
SUB Pos_Y(n)
    Turtle_Y = Turtle_Yorigine - n : 2d_poly_from Turtle_X,Turtle_Y
END_SUB
rem ============================================================================
' Fixer la position de la tortue
' Déplacer la tortue au point (X,Y) par rapport au centre de la
' fenêtre qui est l'origine.
' X et/ou Y peuvent être positives, négatives ou nules
SUB Position_XY(x,y)
    Turtle_X = Turtle_Xorigine + x : Turtle_Y = Turtle_Yorigine - y
    2d_poly_from Turtle_X,Turtle_Y
END_SUB
rem ============================================================================
' Tracer l'axe des X
' Si unite > 0 , l'axe sera gradué en unité, sinon l'axe ne sera pas gradué
SUB DrawAxisX(unite)
    dim i
    2d_line 0,Turtle_Yorigine,2*Turtle_Xorigine,Turtle_Yorigine
    Origine()
    for i = 0 to width(0)/2  step  unite
        Position_XY(i,0)   : AV(5) : RE(10)
        Position_XY(0-i,0) : AV(5) : RE(10)
    next i
    Position_XY(0,0) : Origine()
END_SUB
rem ============================================================================
' Tracer l'axe des Y
' Si unite > 0 , l'axe sera gradué en unité, sinon l'axe ne sera pas gradué
SUB DrawAxisY(unite)
    dim_local i
    2d_line Turtle_Xorigine,0,Turtle_Xorigine,2*Turtle_Yorigine
    Origine() : cap(90)
    for i = 0 to height(0)/2  step  unite
        Position_XY(0,i)   : AV(5) : RE(10)
        Position_XY(0,0-i) : AV(5) : RE(10)
    next i
    Position_XY(0,0) : Origine()
END_SUB
rem ============================================================================
' Tracer les 2 axes X et Y
' Si unite > 0 , les axes seront gradués en unité, sinon ils ne seront pas gradués
SUB DrawAxis(unite)
    DrawAxisX(unite) : DrawAxisY(unite)
END_SUB
rem ============================================================================
' Tracer un grille
SUB Grille(unite)
    dim_local i
    for i = 0 to width(0)/2  step  unite
        2d_line 0,Turtle_Yorigine-i,2*Turtle_Xorigine,Turtle_Yorigine-i
        2d_line 0,Turtle_Yorigine+i,2*Turtle_Xorigine,Turtle_Yorigine+i
    next i
    for i = 0 to width(0)/2  step  unite
        2d_line Turtle_Xorigine+i,0,Turtle_Xorigine+i,2*Turtle_Yorigine
        2d_line Turtle_Xorigine-i,0,Turtle_Xorigine-i,2*Turtle_Yorigine
    next i
END_SUB
rem ============================================================================
' On modifie l'état du crayon
' Lever le stylo : le déplacement de la tortue ne laisse pas de trace
' ------------------------------------------------------------------------------
' Autres syntaxes :
' LC()
' Pen_UP()
' ------------------------------------------------------------------------------
SUB LeveCrayon()
    Turtle_Pen_Up_Down = 1
END_SUB
rem ============================================================================
' On modifie l'état du crayon
' Baisser le stylo : le déplacement de la tortue laisse une trace
' ------------------------------------------------------------------------------
' Autres syntaxes :
' BC()
' Pen_Down()
' ------------------------------------------------------------------------------
SUB BaisseCrayon()
    Turtle_Pen_Up_Down = 0
END_SUB
rem ============================================================================
' Fixer la couleur du tracé
' ------------------------------------------------------------------------------
' Autres syntaxes :
' CC(r,g,b)
' Set_Pen_Color(r,g,b)
' ------------------------------------------------------------------------------
SUB CouleurCrayon(r,g,b)
    Turtle_PR = R : Turtle_PG = G :Turtle_PB = B
    2d_pen_color Turtle_PR, Turtle_PG, Turtle_PB
END_SUB
rem ============================================================================
' Fixer la couleur du fond
' ------------------------------------------------------------------------------
' Autres syntaxes :
' CF(r,g,b)
' Set_BG_Color(r,g,b)
' ------------------------------------------------------------------------------
SUB CouleurFond(r,g,b)
    Turtle_FR =  R :  Turtle_FG = G :  Turtle_FB = B
    color 0, Turtle_FR, Turtle_FG, Turtle_FB
END_SUB
rem ============================================================================
' Gomme : La tortue efface tous les traits qu’elle rencontre
' ------------------------------------------------------------------------------
' Autres syntaxes :
' GO()
' Pen_Erase()
' ------------------------------------------------------------------------------
SUB Gomme()
    2d_pen_color Turtle_FR, Turtle_FG, Turtle_FB
END_SUB
rem ============================================================================
' Inverser la couleur du crayon
' ------------------------------------------------------------------------------
' Autres syntaxes :
' IC(_
' Pen_Invert()
' ------------------------------------------------------------------------------
SUB InverseCrayon()
    2d_pen_color 255 - Turtle_PR, 255 - Turtle_PG, 255 - Turtle_PB
END_SUB
rem ============================================================================
' Remplissage de la zone où se trouve la tortue avec la couleur transmise en
' paramètres r,g,b
' ------------------------------------------------------------------------------
' Autres syntaxes :
' CO(r,g,b)
' Pen_Paint(r,g,b)
' ------------------------------------------------------------------------------
SUB Colorie(r,g,b)
    Turtle_Flood_R = R :  Turtle_Flood_G = G : Turtle_Flood_B = B
    2d_flood Turtle_X, Turtle_Y, Turtle_Flood_R, Turtle_Flood_G, Turtle_Flood_B
END_SUB
rem ============================================================================
' Tracer un cercle de rayon r centré à la position de la tortue
' Autres syntaxes :
' ------------------------------------------------------------------------------
' DI(r)
' Draw_circle(r)
' ------------------------------------------------------------------------------
SUB Disque(r)
    2D_FILL_OFF : 2d_circle Turtle_X,Turtle_Y,r
END_SUB
rem ============================================================================
' Tracer une ellipse de demi-axes Rx et Ry centrée à la position de la tortue
' Autres syntaxes :
' ------------------------------------------------------------------------------
' OV(Rx,Ry)
' Draw_Ellipse(Rx,Ry)
' ------------------------------------------------------------------------------
SUB Ovale(Rx,Ry)
    dim_local i,x,y
    2d_poly_from Turtle_X + Rx, Turtle_Y
    for i = 0 to 360
        x = Turtle_X + Rx*cos(i*Turtle_Rad) : y = Turtle_Y + Ry*sin(i*Turtle_Rad)
        2d_poly_to x,y
    next i
END_SUB
rem ============================================================================
' Le cercle orthoptique de l'ellipse est l'ensemble des points qui "regardent"
' l'ellipse suivant un angle droit, c-à-d dont partent deux tagentes à l'ellipse
' perpendiculaires.
' Ce cercle a le même centre que l'ellipse et son rayon vaut sqr(Rx*Rx + Ry*Ry)
' ------------------------------------------------------------------------------
' Autre syntaxe :
' Draw_Orthoptic_Circle(Rx,Ry)
' ------------------------------------------------------------------------------
SUB Cercle_Orthoptique(Rx,Ry)
    dim_local r
    r = sqr(Rx*Rx + Ry*Ry)
    2D_FILL_OFF : 2d_circle Turtle_X,Turtle_Y,r
END_SUB
rem ============================================================================
' Calculer la distance entre le centre de l'ellipse et l'un de ses foyers
SUB Distance_Centre_Ellipse_O_Foyer(Rx,Ry)
    Turtle_Return_value = sqr(abs(Rx*Rx - Ry*Ry))
END_SUB
rem ============================================================================
' Calculer l'excentricité de l'ellipse.
' L'exentricité de l'ellipse exprime l'écart de forme entre l'ellipse et le
' cercle parfait dont l'excentricité est nulle.
SUB Excentricite_Ellipse(Rx,Ry)
    dim_local c,e
    Distance_Centre_Ellipse_O_Foyer(Rx,Ry) : c = Turtle_Return_value : e = c/Rx
    Turtle_Return_value = e
END_SUB
rem ============================================================================
rem ############################################################################
' Routines en abrégé
rem ============================================================================
SUB AV(pas)
    Avance(pas)
END_SUB
rem ============================================================================
SUB RE(pas)
    Recule(pas)
END_SUB
rem ============================================================================
SUB TG(a)
    Gauche(a)
END_SUB
rem ============================================================================
SUB TD(a)
    Droite(a)
END_SUB
rem ============================================================================
SUB LC()
    LeveCrayon()
END_SUB
rem ============================================================================
SUB BC()
    BaisseCrayon()
END_SUB
rem ============================================================================
SUB CC(r,g,b)
    CouleurCrayon(r,g,b)
END_SUB
rem ============================================================================
SUB CF(r,g,b)
    CouleurFond(r,g,b)
END_SUB
rem ============================================================================
SUB GO()
    Gomme()
END_SUB
rem ============================================================================
SUB IC()
    InverseCrayon()
END_SUB
rem ============================================================================
SUB CO(r,g,b)
    Colorie(r,g,b)
END_SUB
rem ============================================================================
SUB DI(r)
    Disque(r)
END_SUB
rem ============================================================================
SUB OV(Rx,Ry)
    Ovale(Rx,Ry)
END_SUB
rem ============================================================================

' Anglais

rem ============================================================================
rem ############################################################################
rem ============================================================================

SUB Forward(pas)
    Avance(pas)
END_SUB
rem ============================================================================
SUB Back(pas)
    Recule(pas)
END_SUB
rem ============================================================================
SUB Turn_Left(a)
    Gauche(a)
END_SUB
rem ============================================================================
SUB Turn_Right(a)
    Droite(a)
END_SUB
rem ============================================================================
SUB Set_Heading(a)
    Cap(a)
END_SUB
rem ============================================================================
SUB Pen_Up()
    LeveCrayon()
END_SUB
rem ============================================================================
SUB Pen_Down()
    BaisseCrayon()
END_SUB
rem ============================================================================
SUB Set_Pen_Color(r,g,b)
    CouleurCrayon(r,g,b)
END_SUB
rem ============================================================================
SUB Set_BG_Color(r,g,b)
    CouleurFond(r,g,b)
END_SUB
rem ============================================================================
SUB Pen_Erase()
    Gomme()
END_SUB
rem ============================================================================
SUB Pen_Invert()
    InverseCrayon()
END_SUB
rem ============================================================================
SUB Pen_Paint(r,g,b)
    CO(r,g,b)
END_SUB
rem ============================================================================
SUB Draw_circle(r)
    Disque(r)
END_SUB
rem ============================================================================
SUB Draw_Ellipse(Rx,Ry)
    Ovale(Rx,Ry)
END_SUB
rem ============================================================================
SUB Draw_Orthoptic_Circle(Rx,Ry)
    Cercle_Orthoptique(Rx,Ry)
END_SUB
rem ============================================================================
rem ############### FIN DU FICHIER #############################################
rem ============================================================================


Dernière édition par Jean Claude le Mar 30 Juin 2015 - 17:11, édité 1 fois
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5863
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Où est la tortue ?   Mar 30 Juin 2015 - 14:35

ou de mettre le chemin d'accès complet au fichier turtle ou le chemin relatif par rapport à là où tu enregistre ton programme ou de mettre le fichier dans un emplacement figurant dans le chemin de recherche de Windows (ce que je te déconseille pour cet usage).
Personnellement je la ramène mais j'ai fais comme Jean-Claude, j'ai un répertoire Tortue ...
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5613
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Où est la tortue ?   Mer 1 Juil 2015 - 5:17

@Parpaiun

Tu as trouvé ta tortue ou tu te tortures encore ? Smile
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Parpaiun

avatar

Nombre de messages : 192
Age : 78
Localisation : HERAULT
Date d'inscription : 15/04/2015

MessageSujet: Revue du sujet   Mer 1 Juil 2015 - 10:22

@papydall, grand merci cher professeur pour ton bon conseil !
Cette fois, dame tortue a bien voulu fonctionner à ma plus grande joie ! Les programmes ont donné un résultat OK.

J'ai pris la précaution de copier ton long programme Include_turtle.bas. Je l'ai trouvé vachement long et j'explique facilement cela par le fait que la majeure partie des panoramiciens ne sait pas à quoi sert le langage LOGO. Moi, je sais ça depuis 1981.

J'ai déjà utilisé le langage LOGO  dans le package GFA Basic 32 qui en est pourvu et j'en ai profité à merveille. Par exemple:
SETDRAW x,y,ang + 90    'Positionne le plot origine sur l'écran
DRAW "RT100FD80"  'La tortue tourne de 100 degrés à droite et avance de 80 pixels de long.  C'est très facile à imaginer, écrire et c'est tout dire !

Je possède plusieurs bouquins sur le sujet dont: "Jaillissement de l'esprit, Ordinateurs et apprentissage", éditions Flammarion 1980,  par Seymour Papert, le génial créateur du langage LOGO, à qui je rends hommage en pensée.

Voilà, cher prof, avec mes sincères remerciements pour ton aide.
lol!    lol!    lol!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Nardo26

avatar

Nombre de messages : 2294
Age : 49
Localisation : Valence
Date d'inscription : 02/07/2010

MessageSujet: Re: Où est la tortue ?   Mer 1 Juil 2015 - 11:37

Parpaiun a écrit:
j'explique facilement cela par le fait que la majeure partie des panoramiciens ne sait pas à quoi sert le langage LOGO
Ne soit pas si sûr de cela...
Je pense qu'une grande partie des Panoramiciens connaissent déjà plusieurs langages et basculent d'un langage à un autre en fct des besoins...
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://nardo26.lescigales.org
Klaus

avatar

Nombre de messages : 10259
Age : 68
Localisation : Ile de France
Date d'inscription : 29/12/2009

MessageSujet: Re: Où est la tortue ?   Mer 1 Juil 2015 - 12:06

Exact, Nardo26 !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://klauspanoramic.comxa.com/index.html
Jicehel

avatar

Nombre de messages : 5863
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Où est la tortue ?   Mer 1 Juil 2015 - 12:18

J'ai utilisé
le basic et l'assembleur sur mon Hector pour faire de petits programmes puis l'assembleur (principalement pour le Z80 mais aussi pour des routines pour PC) , le Pascal, le C, Ada il y a près de 30 ans maintenant, le GFA Basic, le Pascal et le Dark Basic (et le Blitz aussi) sur mon Atari, le Quick Basic sur mon PC pour mon boulot et je continuaient aussi avec le Turbo Pascal plus tard, pour le boulot puis j'ai fais mes applications avec visual Basic (à l'époque c'était la version 3 et je l'ai utilisé jusqu'à la version 6). J'ai programmé en VBA car j'en avais tout le temps besoin pour mes stats ou pour faire des taches répétitives, gérer les comptes sur l'AD etc ... et puis je suis tombé sur Panoramic à un moment ou je pensais à me refaire des programmes. J'ai testé en faisant des petits jeux, j'ai apprécié la communauté et je suis resté depuis... Smile

Voilà. J'ai donc quelques notions de différents langages... Wink
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Nardo26

avatar

Nombre de messages : 2294
Age : 49
Localisation : Valence
Date d'inscription : 02/07/2010

MessageSujet: Re: Où est la tortue ?   Mer 1 Juil 2015 - 12:53

Lol !
Et t'as jamais utilisé du Fortran ou du turbo prolog ?
C’était marrant le turbo prolog : l'équivalent du "hello world" dans ce langage c'était... les tours de hanoi ! (pour se familiariser avec la notion de prédicat)

Comme quoi, ce jeu aura inspiré bien des personnes... Laughing

PS: Je ne donne pas ma liste de langage car cela n'a pas d’intérêt et puis mon boulot fait que je n'arrête pas d'en apprendre et d'en désapprendre...
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://nardo26.lescigales.org
Jicehel

avatar

Nombre de messages : 5863
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Où est la tortue ?   Mer 1 Juil 2015 - 13:30

Non, j'ai échappé au Fortran et au Cobol (enfin le Cobol j'ai eu une initiation mais je n'ai pas poussé plus loin).
J'ai sans doute oublié quelques essais aussi mais rien d'important
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 5086
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Où est la tortue ?   Mer 1 Juil 2015 - 14:19

Pour moi, c'est beaucoup plus modeste et facile à énumérer.

Le Basic Amstrad avec un cpc6128, puis Quick Basic pour les ordinateurs qui ont suivis.
j'ai essayé PureBasic, et d'autres, mais mon anglais étant ce qu'il est j'ai abandonné.

Et en 2007 je découvre Panoramic, un langage en français et une communauté d'une quarantaine de membres à l'époque, qui m'a d’emblée intégré.
Il y avait déjà JL35, Jean Debord, Rmont, Puis d'autres en recherche d'un Basic, Georges, Cosmos70, JJN4.
Depuis ça a bien évolué....

A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Minibug

avatar

Nombre de messages : 2412
Age : 51
Localisation : Vienne (86)
Date d'inscription : 10/02/2012

MessageSujet: Re: Où est la tortue ?   Mer 1 Juil 2015 - 16:26

Un peu pareil pour moi. bounce

J'ai commencé sur Basic Amstrad CPC464. J'ai fait quelques incursions dans l'assembleur Z80... scratch

Puis je me suis retrouvé sous GFA BASIC avec ATARI 520ST. Le GFA était un langage très bien développé.
Il me semble même qu'il était récursif. Très stable et très complet. J'ai passé de grands moments en sa compagnie.I love you

Puis vint l'heure du PC et de Windows ou j'ai trouvé de nombreux langages a tester (Avec plus ou moins de facilités)
Pour me retrouver aujourd'hui sous Panoramic, que j'apprécie surtout pour sa simplicité de sa syntaxe et de sa programmation.
C'est aujourd'hui mon langage de prédilection.cheers

Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://gpp.panoramic.free.fr
Nardo26

avatar

Nombre de messages : 2294
Age : 49
Localisation : Valence
Date d'inscription : 02/07/2010

MessageSujet: Re: Où est la tortue ?   Mer 1 Juil 2015 - 22:42

Minibug a écrit:
Puis je me suis retrouvé sous GFA BASIC avec ATARI 520ST.
Je pense qu'on est nombreux à avoir connu la période Hebdogiciel avec des milliers de lignes de code à taper pour se rendre compte au final que cela ne fonctionnait pas... Laughing geek
Remarque on finissait par devenir des specialistes du debug. geek
A chaque numéro, c'était un grand moment !
Je me souviens bien de celui là :

ils étaient couillus à l'époque Very Happy

Aaaah nostalgie quand tu nous tiens....
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://nardo26.lescigales.org
Jicehel

avatar

Nombre de messages : 5863
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Où est la tortue ?   Mer 1 Juil 2015 - 23:50

oui, c'était un des premiers magazines informatique que j'ai lu de façon régulière. Je dévorais mes hebdogiciels maintenant on a le canard qui est un peu dans l'esprit mais ce n'est plus pareil, à moins que ce soit moi qui ait vieilli ... Wink
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Parpaiun

avatar

Nombre de messages : 192
Age : 78
Localisation : HERAULT
Date d'inscription : 15/04/2015

MessageSujet: Revue du sujet   Jeu 2 Juil 2015 - 8:04

Merci Nardo26, jicehel, jean-claude et Minibug pour vos infos. J'avais une collection presque complète du magazine papier HEBDOGICIEL que j'ai bêtement jeté direct à la poubelle faute de temps et de place lors de mon dernier déménagement en 2002 ! Ne vous ayant pas connu à temps comme membres de Panoramic, flanquez moi une grosse baffe si je le mérite !

Heureusement, on peut retrouver ces précieux magazines en archives par Internet dans :
www.abandonware-magazines.org , site qui contient plein de trésors de programmes pour d'autres machines, si le coeur vous en dit !

Rafraichissez vous bien les idées sous cette grosse canicule ! lol!



Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5863
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Où est la tortue ?   Jeu 2 Juil 2015 - 9:12

oui, ça nous rajeunit de quelques années et c'est plutôt agréable Wink
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Nardo26

avatar

Nombre de messages : 2294
Age : 49
Localisation : Valence
Date d'inscription : 02/07/2010

MessageSujet: Re: Où est la tortue ?   Jeu 2 Juil 2015 - 16:51

Merci Parpaiun pour le lien !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://nardo26.lescigales.org
Contenu sponsorisé




MessageSujet: Re: Où est la tortue ?   

Revenir en haut Aller en bas
 
Où est la tortue ?
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» Dame Tortue
» C'est l'histoire d'une tortue, qui se tord et qui se tue ? Euphemia
» Quand la mouse tachée bricole...
» Aki' la tortue

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: A l'aide!-
Sauter vers: