FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» PanExpress : l'éditeur Panoramic avec création d'objet
par Jean Claude Aujourd'hui à 11:55

» Projet de planétarium virtuel.
par Pedro Alvarez Hier à 17:29

» Quantité de mémoire utilisée par un exe
par Navigateur Hier à 14:52

» Problème avec 'file_load'.
par Pedro Alvarez Hier à 8:12

» Version instantanée V 0.9.28i20 du 13/06/2018
par jjn4 Sam 16 Juin 2018 - 14:25

» string$(0,chr$(32)) sans erreur
par silverman Ven 15 Juin 2018 - 19:56

» Version instantanée V 0.9.28i19 du 13/06/2018
par Minibug Ven 15 Juin 2018 - 19:14

» Mes souhaits d'amélioration de Panoramic.
par Pedro Alvarez Jeu 14 Juin 2018 - 20:17

» [RÉSOLU] Message d'erreur impossible à indentifier
par Minibug Mer 13 Juin 2018 - 20:52

» Cadre pour image
par Jean Claude Mar 12 Juin 2018 - 16:31

» Créateur d'objets Panoramic
par Minibug Mar 12 Juin 2018 - 14:02

» Planétarium gratuit.
par Jean Claude Sam 9 Juin 2018 - 18:50

» Comment afficher une image sans fond.
par JL35 Sam 9 Juin 2018 - 14:16

» image_width(n) et image_height(n)
par silverman Sam 9 Juin 2018 - 11:22

» Site sur la programmation sympa
par Jean Claude Jeu 7 Juin 2018 - 11:20

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Juin 2018
LunMarMerJeuVenSamDim
    123
45678910
11121314151617
18192021222324
252627282930 
CalendrierCalendrier

Partagez | 
 

 Panorabric (La version PC)

Aller en bas 
AuteurMessage
Jicehel

avatar

Nombre de messages : 5923
Age : 45
Localisation : 77500
Date d'inscription : 18/04/2011

MessageSujet: Panorabric (La version PC)   Mer 26 Nov 2014 - 14:48

Plutôt que de resquatter le jeu fait en test sur Android, je remets ici la version PC du casse briques

Dernière modif: la vitesse de déplacement est réglable par variable, ce qui prépare de toute façon un menu option pour pouvoir modifier les paramètres du jeu plus facilement.

Code:
' Panorabric prévue pour PC (Resolution de l'écran 600 x 380)
' La résolution c'est par ce que je suis parti de la version Android de mon S3...

label clic,fin, boucle_principale, t1, t2

' Déclarations
dim i, j, i2, j2, ecran%, aff_vies%, aff_score%, zdj%, image%
dim pose_question%
dim h,l : h=600: l=380
dim x_r , y_r, hauteur_r, largeur_r : ' Variables de la raquette
hauteur_r = 10 : largeur_r=60 : y_r = h-120-hauteur_r
dim hauteur_b, largeur_b : hauteur_b = 8 : largeur_b=21  : ' constantes des briques
dim xb, yb, Nb_lignes, Nb_briques_restantes : ' variables pour la gestion des briques
Nb_lignes = 6
dim x_ball,y_ball, r_ball, n_ball : r_ball = 10 : ' variables de la balle
dim vies, score : vies = 3 : score = 0
dim nom_couleur$, Nb_couleur% : Nb_couleur% = 18 : ' Tableau des couleurs
dim t_c(Nb_couleur%,3)
dim ombre, lumiere  : ombre=30 : lumiere = 16
dim marge_cote, marge_haut, hauteur_menu : marge_cote = 8 : marge_haut = 30 :hauteur_menu = 100
dim Nb_b_ligne : Nb_b_ligne = int((l - 3*marge_cote)/(largeur_b+5))
dim t_br(Nb_lignes*Nb_b_ligne,5)
dim ctrl_mouse : ctrl_mouse = 0 : ' ctrl_mouse = 0 => clavier / boutons ; ctrl_mouse = 1 => souris
' Réglages des vitesse de déplacement lors d'appuis sur les touches ou les boutons
dim vdtouches : vdtouches = largeur_r / 8 : ' vitesse de déplacement lors d'appuis sur les flèches droite ou gauche
dim vdboutons : vdboutons = largeur_r / 2 : ' vitesse de déplacmenent lorsque l'on clique sur un des boutons à l'écran
'
' ******************* VARIABLES DE DIRECTION DE LA BALLE ********************
'
dim c : ' donne la direction de la balle horizontalement
'        c=1 => la balle va vers la gauche
'        c=2 => elle va à droite
dim r : ' donne la direction de la balle verticalement
'        r=1 => la balle monte
'        r=2 => la balle descend
'
' ****************************** COMMANDES CLAVIER **************************
'
dim esc,cesc : cesc=27 : ' * TOUCHE "ESC" ==> MET FIN AU PROGRAMME:.... 27  *
dim tfg,ctfg : ctfg=37 : ' * FLÈCHE GAUCHE ==> DEPLACER À GAUCHE:...... 37  *
dim tfd,ctfd : ctfd=39 : ' * FLÈCHE DROITE ==> DEPLACER À DROITE:...... 39  *
' ***************************************************************************

' Initialisation de la fenêtre
height 0, h: width 0,l : caption 0, "PANORABRIC Android - V1.0"
border_small 0 : i =  h - hauteur_menu + 20

if ctrl_mouse = 0
' Création des boutons pour les écrans tactiles par exemple si on n'utilise pas la souris
  button 1 : hide 1 : ' Creation du bouton gauche
  top 1, i : left 1,10 : caption 1,"<" : on_click 1,clic
  button 2 : hide 2 : ' Creation du bouton droite
  top 2, i : left 2,50+width(1) : caption 2,">" : on_click 2,clic
  button 3 : hide 3 : ' Creation du bouton quitter
  top 3, i : left 3,l-width(3)-28 : caption 3,"Quitter" : on_click 3,clic
  ' On détecte le changement d'état des touches
end_if

' Données à charger dans le tableau des couleurs
data "0 - Noir", 0,  0,  0,  "1 - Blanc", 255,255,255
data "2 - couleur de fond - kaki foncé", 155,155, 55
data "3 - Kaki", 180,180,80, "4 - gris foncé",  80, 80, 80
data "5 - bleu" ,80, 80,215, "6 - rouge", 215, 80, 80
data "7 - vert", 80,215, 80, "8 - gris", 155,133,155
data "9 - vert clair", 100,215,100, "10 - violet", 215, 80,215
data "11 - kaki clair", 215,215, 80, "12 - bleu cyan", 80,215,215
data "13 - bleu moyen", 100,100,215, "14 - vert moyen",55,215,133
data "15 - violet",133, 55,215,      "16 - marron clair",215,133, 55
data "17 - bleu nuit",  55, 55,133

' Chargement du tableau des couleurs
for i = 1 to Nb_couleur% :  read nom_couleur$
    for j = 1 to 3 : read c : t_c(i,j)=c : next j
next i

' On retire la taille du menu à h pour créer nos objets
h= h - hauteur_menu

' Dessin de l'aire de jeu dans une image cachée qui sert aussi à créer les sprites
ecran% = 5 : picture ecran% : hide ecran%

' Créer l'objet scene2d qui sera notre zone de jeu
zdj% = 6 : scene2d zdj%
top zdj%,0: left zdj%,0
height zdj%, h: width zdj%,l-2*marge_cote

' On creer notre image de transfert
image% = 7 : image image%

' Activer cette ligne pour creer une image de fond basique si besoin (Creer_fond)
' Cette image est modifiable à volonté selon vos goût.
' Je vous en ai fourni une faite rapidement, a vous de faire mieux si vous voulez
'
Creer_fond()

file_load zdj%,"fond.bmp"

x_r = 0.5 * (l - largeur_r - 2*marge_cote) : Dessine_raquette()
Creer_brique()
Trace_balle()

caption 0, " Panorabric version PC  -  Vies restantes: " + str$(vies) + "          Score = "+str$(score)

Init_niveau()

' timer pour deplacements
timer 4 : timer_interval 4,30 : on_timer 4,boucle_principale
on_close 0,fin : ' Si on ferme, on ferme par la procédure de sortie

' Tout est prêt, on affiche les boutons et on attend le démarrage de la boucle
if ctrl_mouse = 0
  show 1: show 2: show 3
end_if
on_key_down 0,t1 : on_key_up 0,t2
end

Sub Dessine_raquette()
  2d_target_is ecran%
  color ecran%,0,0,0 : sprite 1 : sprite_hide 1
  if file_exists("raquette.bmp") = 0
    ' On trace la forme de la raquette
    2d_pen_width 2 :  2d_pen_color t_c(5,1), t_c(5,2), t_c(5,3) :  2d_fill_color t_c(6,1), t_c(6,2), t_c(6,3)
    2d_rectangle 4,4,largeur_r-3,hauteur_r-3
    ' On ajoute la partie claire
    2d_pen_color t_c(5,1)+lumiere, t_c(5,2)+lumiere, t_c(5,3)+lumiere
    2d_poly_from 2,-2 : 2d_poly_to 2,2 : 2d_poly_to largeur_r-2,2
    ' On ajoute les ombres
    2d_pen_color t_c(5,1)-ombre, t_c(5,2)-ombre, t_c(5,3)-ombre
    2d_poly_to largeur_r-2,hauteur_r-2 : 2D_poly_to 2,hauteur_r-2: 2d_pen_width 1
    ' file_save ecran%,"raquette.bmp"
  else
    file_load ecran%,"raquette.bmp"
  end_if
  2d_image_copy image%,0,0, largeur_r,hauteur_r
  sprite_image_load 1,image%
End_sub

Sub init_niveau()
  Dessine_briques() : pose_question% = 0
  set_focus 0
  x_r = 0.5 * (l - largeur_r - 2*marge_cote)
  sprite_position 1,x_r,y_r : sprite_show 1
  Dessine_briques()
  Lance_balle()
End_sub

Sub Creer_fond()
  2d_target_is ecran% :  top ecran%,0: left ecran%,0
  height ecran%, h: width ecran%,l - 2*marge_cote
  ' Créait un fond noir si besoin
  color ecran%,0,0,0
  if file_exists("fond_noir.jpg") = 0 then file_save ecran%,"fond_noir.jpg"
  ' Trace le contour
  if file_exists("fond.bmp")=0
    2d_pen_color t_c(3,1), t_c(3,2), t_c(3,3) : 2d_fill_color t_c(3,1), t_c(3,2), t_c(3,3)
    2d_rectangle 0,h,marge_cote,0 : 2d_rectangle marge_cote,0,l-2*marge_cote,20
    2d_rectangle l-3*marge_cote,h,l-2*marge_cote,0
    2d_image_copy image%,0,0,l-2*marge_cote,h
    file_save ecran%,"fond.bmp"
  end_if
End_sub

Sub Creer_brique()
  dim k: k=0
  ' Trace le contour
  2d_target_is ecran%
  top ecran%,0: left ecran%,0 :  color ecran%,0,0,0
  height ecran%, hauteur_b : width ecran%,largeur_b
  for i= 1 to Nb_lignes
    for j = 1 to Nb_b_ligne
      k=k+1
      t_br(k,2) = t_c(5+i,1): t_br(k,3) = t_c(5+i,2): t_br(k,4) = t_c(5+i,3)
      2d_pen_color t_br(k,2), t_br(k,3), t_br(k,4)
      2d_pen_width 3
      2d_pen_color t_br(k,2), t_br(k,3), t_br(k,4) : 2d_fill_color t_br(k,2), t_br(k,3), t_br(k,4)
      2d_rectangle 2,2,largeur_b-2, hauteur_b-2
      2d_pen_color t_br(k,2)+lumiere, t_br(k,3)+lumiere, t_br(k,4)+lumiere
      2d_poly_from 0, hauteur_b : 2d_poly_to 0,0 : 2d_poly_to largeur_b, 0
      2d_pen_color t_br(k,2)-ombre, t_br(k,3)-ombre, t_br(k,4)-ombre
      2d_poly_to  largeur_b, hauteur_b : 2d_poly_to 0, hauteur_b
      2d_pen_width 1
      2d_image_copy image%,0,0,largeur_b,hauteur_b
      sprite 10+k : sprite_image_load 10+k,image% : sprite_hide 10 + k
    next j
  next i
free k
End_sub

Sub Dessine_briques()
dim k: k=0 : Nb_briques_restantes = 0
for i= 1 to Nb_lignes
  yb = 2*marge_haut + (hauteur_b + 15) * i
  For j = 1 to Nb_b_ligne
    xb = 2*marge_cote + (largeur_b + 5) * (j-1)
    k=k+1 : t_br(k,1) = 1 : t_br(k,5) = 100
    Nb_briques_restantes = Nb_briques_restantes + 1
    sprite_position 10+k, xb, yb : sprite_show 10+k
  next j
next i
free k
End_sub

Sub Lance_balle()
  y_ball = y_r - 2*r_ball :  x_ball = int(rnd(l-60)) + 2*marge_cote : r=1
  sprite_show 2
End_sub

Sub Trace_balle()
  2d_target_is ecran%
  top ecran%,0: left ecran%,0 :  height ecran%, 2*r_ball
  width ecran%,2*r_ball : color ecran%, 0,0,0
'  if file_exists("balle.bmp")=0
    2d_pen_color t_c(3,1) - ombre, t_c(3,2) - ombre, t_c(3,3) - ombre
    2d_fill_color t_c(3,1), t_c(3,2), t_c(3,3) : 2d_circle r_ball, r_ball, r_ball
    2d_fill_color t_c(4,1)+lumiere, t_c(4,2)+lumiere, t_c(4,3)+lumiere
    2d_pen_color t_c(4,1), t_c(4,2), t_c(4,3) :  2d_circle r_ball-3, r_ball-3, r_ball-6
    file_save ecran%,"balle.bmp"
'  else
'    file_load ecran%,"balle.bmp"
'  end_if
  2d_image_copy image%,0,0,2*r_ball,2*r_ball
  sprite 2 : sprite_image_load 2,image% : sprite_hide 2
End_sub

Sub recommence()
  vies = 3 : score = 0 : sprite_hide 1
  sprite_hide 2 : file_load zdj%,"fond.bmp" : Init_niveau()
  timer_on 4
End_sub

Sub Deplace_balle()
  If x_ball> l-4*marge_cote-2*r_ball then x_ball = l-4*marge_cote-2*r_ball : c = 2
  If x_ball < 2* marge_cote  Then x_ball = 2 * marge_cote : c = 1
  If y_ball < (marge_haut + r_ball) Then y_ball = marge_haut + r_ball : r = 2
  If c < 2 Then x_ball = x_ball + 5 : Else: x_ball = x_ball - 5
  If r < 2 Then y_ball = y_ball - 5 : Else: y_ball = y_ball + 5
End_sub

Sub TestCollisionHaut(XT,YT)
    i = int((XT - 2*marge_cote) / (largeur_b + 5))+1 : ' Position en X
    temp = int ((YT - 2*marge_haut - hauteur_b) / (hauteur_b +15))+1 : ' Position en Y
    j = (temp-1)*Nb_b_ligne +i  : ' Calcul le numéro de la brique dans le tableau

    if j <= (Nb_lignes*Nb_b_ligne) and j>0 : ' Controle de validité de l'indice
      if t_br(j,1) = 1 : ' Si le point tester correspond à une brique active
          r=2 : t_br(j,1) = 0 : ' On passe en descente et on casse la brique
          sprite_hide j+10 : Nb_briques_restantes = Nb_briques_restantes - 1 : score = score + t_br(j,5)
      end_if
    end_if
End_sub

Sub TestCollisionBas(XT,YT)
    i = int((XT - 2*marge_cote) / (largeur_b + 5)) +1
    temp = int (((YT+2*r_ball) -2*marge_haut -hauteur_b) / (hauteur_b +15))
    j = (temp-1)*Nb_b_ligne +i
    if j <= (Nb_lignes*Nb_b_ligne) and j>0
      if t_br(j,1) = 1
        r=1 : t_br(j,1) = 0
        sprite_hide j+10 : Nb_briques_restantes = Nb_briques_restantes - 1 : score = score + t_br(j,5)
      end_if
    end_if
End_sub

boucle_principale:
if variable("temp") = 0 then dim temp
  timer_off 4
  Deplace_balle() : sprite_position 2,x_ball,y_ball

  ' Teste si collision avec une brique

  ' Test si on va vers le haut et que l'on a franchit la première ligne de brique)
  if (r= 1 and y_ball <= (2*marge_haut + hauteur_b + (hauteur_b + 15) * Nb_lignes))
    TestCollisionHaut(x_ball,y_ball+r_ball) : TestCollisionHaut(x_ball+0.5*r_ball,y_ball+0.5*r_ball)
    TestCollisionHaut(x_ball+r_ball,y_ball) : TestCollisionHaut(x_ball+1.5*r_ball,y_ball+0.5*r_ball)
    TestCollisionHaut(x_ball+2*r_ball,y_ball+r_ball)
  else
    if (r= 2 and  (y_ball  > (2*marge_haut + hauteur_b)) and (y_ball < (2*marge_haut + hauteur_b + (hauteur_b + 15) * Nb_lignes) ))
      TestCollisionBas(x_ball,y_ball+r_ball) : TestCollisionBas(x_ball+0.5*r_ball,y_ball+1.5*r_ball)
      TestCollisionBas(x_ball+r_ball,y_ball+2*r_ball) : TestCollisionBas(x_ball+1.5*r_ball,y_ball+1.5*r_ball)
      TestCollisionBas(x_ball+2*r_ball,y_ball+r_ball)
    end_if
  end_if

  if ctrl_mouse = 1
      x_r = mouse_x_position(zdj%)
      if x_r < 10 then x_r=10      : ' Mais on ne doit pas dépasser les bords !!
      if x_r > l - largeur_r-26 then x_r = l - largeur_r-26  : ' Mais on ne doit pas dépasser les bords !!
      sprite_x_position 1,x_r
  else
    if tfg=1
      x_r = x_r - vdtouches      : ' Mise à jour de la position de la raquette suite à l'appuie sur la flèche
      if x_r < 10 then x_r=10    : ' Mais on ne doit pas dépasser les bords !!
    end_if
    if tfd=1
      x_r = x_r + vdtouches      : ' Mise à jour de la position de la raquette suite à l'appuie sur la flèche
      if x_r > l - largeur_r-26 then x_r = l - largeur_r-26  : ' Mais on ne doit pas dépasser les bords !!
    end_if
    sprite_x_position 1,x_r
  end_if

' Verifie si la balle touche la raquette
  if r=2 and y_ball > y_r - 2 * r_ball - 4
      if ((x_ball > (x_r - r_ball)) and (x_ball < (x_r + largeur_r)))
        r = 1
            score=score+1
      else
        if r=2 and y_ball > y_r
            ' Balle perdue
            wait 400: Lance_balle()
            vies = vies-1
        end_if
      end_if
  end_if
  caption 0, " Panorabric version PC  -  Vies restantes = " + str$(vies) + "  - Score = "+str$(score)
  if Nb_briques_restantes = 0
    message "Bravo, niveau suivant ..."
    hide 2 :  Init_niveau()
  end_if

  if vies < 1 then pose_question% = 1 : goto fin
  free temp
  timer_on 4
return

clic:
  timer_off 4
  select number_click
  case 1 : ' On test si l'on a appuyé sur la flèche de gauche
    x_r = x_r - vdboutons  : ' Mise à jour de la position de la raquette suite à l'appuie sur la flèche
    if x_r < 10 then x_r=10      : ' Mais on ne doit pas dépasser les bords !!
  case 2 : ' On test si l'on a appuyé sur la flèche de droite
    x_r = x_r + vdboutons  : ' Mise à jour de la position de la raquette suite à l'appuie sur la flèche
    if x_r > l - largeur_r-26 then x_r = l - largeur_r-26  : ' Mais on ne doit pas dépasser les bords !!
  case 3 : goto fin : ' On test si l'on a appuyé sur le bouton pour Quitter
  end_select
  sprite_x_position 1,x_r
  set_focus 0
  timer_on 4
return

' ****** Procédures événementielles de gestion du clavier

t1:
  if key_down_code=cesc then pose_question% = 1 : goto fin
  if key_down_code=ctfg then tfg=1
  if key_down_code=ctfd then tfd=1
return

t2:
  if key_down_code=ctfg then tfg=0
  if key_down_code=ctfd then tfd=0
return

fin:
  timer_off_all : ' Je sais que l'on va faire un terminate, mais arréter les timers évite les messages d'erreur
  caption 0, " Panorabric version PC  -  Vies restantes = " + str$(vies) + "  - Score = "+str$(score)
  wait 2000:  sprite_hide_all
  caption 0, " Panorabric version PC  -  Partie terminée  - Score = "+str$(score)
  file_load zdj%,"fond_noir.jpg"
  if pose_question% = 1
    if message_confirmation_yes_no ("Voulez-vous recommencer une partie ?") = 1
      recommence()
    else
      terminate
    end_if
  else
    terminate
  end_if
return


Dernière édition par Jicehel le Jeu 27 Nov 2014 - 14:25, édité 2 fois
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 8077
Age : 47
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Mer 26 Nov 2014 - 17:47

Je ne sais pas si tu as changé le pas de déplacement avec les flèches mais cette version
est bien.

Une suggestion :

Lorsque l' on perd 3 fois de rang,  Embarassed, le jeu se ferme.
Il serait bien d' avoir une option "Rejouer" et une option "Quitter".

Une petite remarque :

Le form 0, chez moi, se retrouve avec une scroll_bar horizontal 
et une forme avec des coins carrés au lieu des coins arrondis.
Je pense que tu dois avoir un objet plus large que ton form 0 
ou du moins un souci avec les tailles des bordures. ( je suis sous W7 : 8px x 2 )
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5923
Age : 45
Localisation : 77500
Date d'inscription : 18/04/2011

MessageSujet: Re: Panorabric (La version PC)   Jeu 27 Nov 2014 - 9:46

J'ai vu ça aussi sur ma version, en effet, c'est lié au fait que pour une raison obsucre de mon esprit tortueux, j'ai mis un left 1 à la création de zdj% à la place de lemettre en 0 ...
Je vais modifier les 2 tout de suite.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5923
Age : 45
Localisation : 77500
Date d'inscription : 18/04/2011

MessageSujet: Re: Panorabric (La version PC)   Jeu 27 Nov 2014 - 10:39

J'ai rajouté la question en fin de jeu pour demander si on veut rejouer.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 8077
Age : 47
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Jeu 27 Nov 2014 - 12:22

Tu as un petit souci à la ré-initialisation.
Lorsque le jeu propose une nouvelle partie, au départ les touches du clavier sont inactives.
On doit cliquer sur les boutons pour débloquer les touches clavier.

Une petite remarque, le jeu propose de rejouer en cliquant sur quitter.
Si je veux quitter c' est que je ne veux pas rejouer... Very Happy
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5923
Age : 45
Localisation : 77500
Date d'inscription : 18/04/2011

MessageSujet: Re: Panorabric (La version PC)   Jeu 27 Nov 2014 - 14:29

OK, tu as raison sur les 2 points. Merci pour ton debuggage. C'est ça de coder rapidos au bureau pendant les pauses ... Wink
En tout cas, j'ai corrigé dans le source. Pour la question j'ai opté pour une simple variable qui indique selon les cas s'il faut ou non poser la question en quittant.

Pour le problème de la détection des touches, c'était facile puisque c'est le problème que j'avais avant avec les boutons qui faisait perdre le focus. J'ai donc remis un set_focus sur 0 pour quand on rejoue et que l'on a cliqué dans la fenêtre (faisant ainsi perdre le focus).

Tu penses que ce jeu vaudrait un article dans le mag ?
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5951
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Panorabric (La version PC)   Jeu 27 Nov 2014 - 15:09

Jicehel a écrit:
Tu penses que ce jeu vaudrait un article dans le mag ?
Why not ?
Ça sera un article de plus.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Jicehel

avatar

Nombre de messages : 5923
Age : 45
Localisation : 77500
Date d'inscription : 18/04/2011

MessageSujet: Re: Panorabric (La version PC)   Jeu 27 Nov 2014 - 15:19

OK, j'en ferais un plus ou moins développé selon le temps alors Wink
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 8077
Age : 47
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Jeu 27 Nov 2014 - 15:20

Oui à 100%, cela montrera aux nouveaux ce qui est possible en Panoramic.
Une façon ludique d' appendre.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Minibug

avatar

Nombre de messages : 2962
Age : 51
Localisation : Vienne (86)
Date d'inscription : 09/02/2012

MessageSujet: Re: Panorabric (La version PC)   Jeu 27 Nov 2014 - 21:11

bravo Jicehel ! belle réalisation.

Juste une petite chose :
Le déplacement de la raquette se bloque parfois puis après avoir appuyé plusieurs fois de suite ca repart...
Je ne sais pas si je suis le seul a avoir eu ce problème.

En tout cas félicitation, il y a vraiment un bon rendu !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://gpp.panoramic.free.fr
Jicehel

avatar

Nombre de messages : 5923
Age : 45
Localisation : 77500
Date d'inscription : 18/04/2011

MessageSujet: Re: Panorabric (La version PC)   Ven 28 Nov 2014 - 8:13

Hum, je n'ai pas constaté de mon côté mais je pense savoir pourquoi (le fameux focus) => je rajouterais un set_focus dans la boucle principale lors de la prochaine modif et on verra bien Wink
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 5473
Age : 64
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Panorabric (La version PC)   Ven 28 Nov 2014 - 8:17

Salut à tous,

Ce jeu fonctionne bien, bravo Jicehel cheers

Comme le dit Minibug, parfois il y a un blocage de la raquette Question Question Question

Une remarque: le jeu génère 3 images.bmp qui restent sur le bureau.

Bravo !

A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5923
Age : 45
Localisation : 77500
Date d'inscription : 18/04/2011

MessageSujet: Re: Panorabric (La version PC)   Ven 28 Nov 2014 - 9:53

Oui pour les images, c'est normal. En fait je les génère si elle n'existent pas. J'en fournirais de plus jolies avec l'article.
Pour cette version, je m'arréterais là et je ferais l'article, mais si besoin pour le moi prochain je pourrais sans doute faire un article avec un menu (pour régler les vitesses, activer le contrôle par boutons / clavier ou souris, activer ou désactiver les bruitage et la musique, afficher les scores, mettre en pause, recommencer une partie ou quitter), mettre bruitage et musique, gérer les highscores.
=> Il y aura donc des fichiers multimédia de fournis avec le fichier.

Je n'ai pas l'intention de gérer des niveaux différents au niveau du look, ça demanderais à faire des modifs et à prendre le temps de concevoir les niveaux et je n'aurais pas le temps.

Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Contenu sponsorisé




MessageSujet: Re: Panorabric (La version PC)   

Revenir en haut Aller en bas
 
Panorabric (La version PC)
Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» Offre promotionnelle : SnagIT 7.25 en version gratuite !
» Comment envoyer une détection chez avira avec Antivir 9 français - Version Classic
» Offre exceptionnelle : True Image 10 en version gratuite et complète
» [Résolu] Pb pour la désinstallation d'Antivir version Anglaise
» [Résolu] avira version 9.0

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Les jeux faits avec Panoramic-
Sauter vers: