FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» un nouveau editeur panobasic
par pascal10000 Hier à 21:52

» COMPILATEUR V 0.9 beta 7 du 10 aout 2017
par Jack Hier à 20:23

» Pb 16 (en analyse): ON_CLOSE plante à l'exécution
par Jack Hier à 20:00

» Pb 15 (en analyse): TIMER_ON plante à l'exécution
par Jack Hier à 19:58

» Compilateur FBPano
par jean_debord Hier à 8:49

» KGF_dll - nouvelles versions
par Yannick Dim 13 Aoû 2017 - 17:35

» probleme d'outil
par Yannick Dim 13 Aoû 2017 - 17:32

» Carte de France des régions
par Yannick Sam 12 Aoû 2017 - 21:33

» Pb 14 (en analyse): PRINT_LOCATE plante à l'exécution
par Jack Ven 11 Aoû 2017 - 22:37

» Petit avertissement [Mots réservés]
par papydall Ven 11 Aoû 2017 - 13:45

» Distances sur plan
par JL35 Jeu 10 Aoû 2017 - 21:29

» Tracé : Triangle, Carrée, Dents de scie, Sinusoïde redressée
par papydall Jeu 10 Aoû 2017 - 14:52

» Troncature dans une image
par JL35 Mer 9 Aoû 2017 - 13:45

» A chacun son point de vue
par papydall Mar 8 Aoû 2017 - 17:20

» Problème avec les chaines de caractères
par bignono Dim 6 Aoû 2017 - 9:33

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Août 2017
LunMarMerJeuVenSamDim
 123456
78910111213
14151617181920
21222324252627
28293031   
CalendrierCalendrier

Partagez | 
 

 Le martien est de retour

Voir le sujet précédent Voir le sujet suivant Aller en bas 
AuteurMessage
jjn4

avatar

Nombre de messages : 1594
Date d'inscription : 13/09/2009

MessageSujet: Le martien est de retour   Dim 19 Oct 2014 - 18:38

Bonjour à tous ( cheers  bounce  Basketball  king  sunny  Sleep  cherry  No  Suspect ...)
-----------------------------------------------
Me revoili, après de longues vacances sur la planète Mars.
L'aller n'a pas été trop long, car les dépanneuses martiennes vont très très vite !
Et pour le retour, on m'a donné, là-bas, un moyen de déplacement plus rapide.
(la soucoupe volante, là-bas, c'est déjà la préhistoire...!)
Je vous montre, dans ce programme, comment je suis revenu :
Code:
rem ' Retour du martien
   dim a , b , i , j : rem Variables provisoires numériques
   dim a$ : rem Varibles provisoires alphanumériques
   dim cr : rem Couleur Red
   dim cg : rem Couleur Green
   dim cb : rem Couleur Blue
   a$="Le retour du martien"
   label brasdb : rem Bras droit bas du martien
   label brasdh : rem Bras droit haut du martien
   label brasgb : rem Bras gauche bas du martien
   label brasgh : rem Bras gauche haut du martien
   label corps : rem Corps du martien
   label jambed : rem Jambe droite du martien
   label jambeg : rem Jambe gauche du martien
   label tete : rem Tête du martien
   label transfert : rem Transfert du martien
   label venue : rem Arrivée du martien
   label vie : rem Retour à la vie du martien
  
rem form0
   width 0,1300
   height 0,580

gosub venue

end

brasdb: : rem Ajout du bras droit bas du martien
   2d_poly_from 96,245
   2d_poly_to 35,280
   2d_poly_to 10,284
   2d_poly_to 33,286
   2d_poly_to 28,310
   2d_poly_to 38,290
   2d_poly_to 95,265
   2d_flood 90,255,0,255,0
return

brasdh: : rem Ajout du bras droit haut du martien
   2d_poly_from 116,195
   2d_poly_to 40,220
   2d_poly_to 25,210
   2d_poly_to 34,222
   2d_poly_to 20,232
   2d_poly_to 36,228
   2d_poly_to 34,245
   2d_poly_to 43,228
   2d_poly_to 106,215
   2d_flood 100,205,0,255,0
return

brasgb: : rem Ajout du bras gauche bas du martien
   2d_poly_from 184,245
   2d_poly_to 245,280
   2d_poly_to 270,284
   2d_poly_to 247,286
   2d_poly_to 252,310
   2d_poly_to 242,290
   2d_poly_to 185,265
   2d_flood 190,255,0,255,0
return

brasgh: : rem Ajout du bras gauche haut du martien
   2d_poly_from 164,195
   2d_poly_to 240,220
   2d_poly_to 255,210
   2d_poly_to 246,222
   2d_poly_to 260,232
   2d_poly_to 244,228
   2d_poly_to 246,245
   2d_poly_to 237,228
   2d_poly_to 174,215
   2d_flood 180,205,0,255,0
return

corps: : rem Affichage du corps du martien
   for i=1 to 360 step 0.2
      2d_point 140+45*cos(i),270+90*sin(i)
   next i
   2d_flood 140,270,0,255,0
   2d_fill_color 0,0,0
   2d_rectangle 100,300,181,310
   2d_rectangle 134,310,146,360
return

jambed: : rem Ajout de la jambe droite du martien
   2d_poly_from 146,359
   2d_poly_to 160,450
   2d_poly_to 175,447
   2d_poly_to 170,335
   2d_flood 150,370,0,255,0
   for i=1 to 360
      2d_point 185+35*cos(i),457+10*sin(i)
   next i
   2d_flood 185,457,255,0,0
return

jambeg: : rem Ajout de la jambe gauche du martien
   2d_poly_from 134,359
   2d_poly_to 120,450
   2d_poly_to 105,447
   2d_poly_to 110,335
   2d_flood 130,370,0,255,0
   for i=1 to 360
      2d_point 95+35*cos(i),457+10*sin(i)
   next i
   2d_flood 95,457,255,0,0
return

tete: : rem Affichage de la tête du martien
   2d_pen_width 1
   2d_fill_color 0,255,0
   2d_circle 140,142,40
   2d_pen_color 0,200,0
   2d_circle 135,150,2
   2d_circle 145,150,2
   2d_pen_width 3
   2d_line 112,112,85,70
   2d_line 168,112,195,70
   2d_circle 85,70,4
   2d_circle 195,70,4
   2d_pen_color 0,0,0
   2d_line 125,163,155,163
   2d_line 120,130,160,130
   2d_pen_width 1
return

transfert: : rem Transfert du martien
   caption 0,"Téléportation : phase 1"
   for i=60 to 470 step 2
      for j=10 to 275 step 2
         cr=color_pixel_red(100,j,i)
         cg=color_pixel_green(100,j,i)
         cb=color_pixel_blue(100,j,i)
         2d_target_is 200
         2d_pen_color cr,cg,cb
         2d_point j,i
      next j
      display
   next i
   caption 0,"Téléportation : phase 2"
   for i=61 to 470 step 2
      for j=11 to 275 step 2
         cr=color_pixel_red(100,j,i)
         cg=color_pixel_green(100,j,i)
         cb=color_pixel_blue(100,j,i)
         2d_target_is 200
         2d_pen_color cr,cg,cb
         2d_point j,i
      next j
      display
   next i
   caption 0,"Téléportation : phase 3"
   for i=61 to 470 step 2
      for j=10 to 275 step 2
         cr=color_pixel_red(100,j,i)
         cg=color_pixel_green(100,j,i)
         cb=color_pixel_blue(100,j,i)
         2d_target_is 200
         2d_pen_color cr,cg,cb
         2d_point j,i
      next j
      display
   next i
   caption 0,"Téléportation : phase 4"
   for i=60 to 470 step 2
      for j=11 to 275 step 2
         cr=color_pixel_red(100,j,i)
         cg=color_pixel_green(100,j,i)
         cb=color_pixel_blue(100,j,i)
         2d_target_is 200
         2d_pen_color cr,cg,cb
         2d_point j,i
      next j
      display
   next i
   beep
return

venue: : rem Arrivée du martien
   for i=300 to 1 step -1
      caption 0,string$(i," ")+a$+string$(601-i," ")
      wait 1
   next i
   caption 0,"Cabine de téléportation"
   for i=1300 to 340 step -1
      width 0,i
   next i
   picture 100
      hide 100
      left 100,20
      top 100,20
      width 100,285
      height 100,500
      2d_target_is 100
   picture 200
      left 200,20
      top 200,20
      width 200,285
      height 200,500
      gosub tete
      gosub corps
      gosub jambed
      gosub jambeg
      gosub brasdb
      gosub brasdh
      gosub brasgb
      gosub brasgh
      gosub transfert
      wait 1000
      caption 0,"Téléportation terminée"
      gosub vie
      wait 2000
      caption 0,"Bonjour les amis !"
return

vie: : rem Retour à la vie du martien
   2d_pen_color 0,255,0
   2d_pen_width 3
   2d_line 120,130,160,130
   2d_line 125,163,155,163
   2d_pen_color 0,0,0
   2d_pen_width 1
   for i=0 to 360
      2d_point 140+20*cos(i),130+10*sin(i)
   next i
   2d_flood 140,130,255,255,255
   2d_fill_color 0,200,255
   2d_circle 140,130,9
   2d_fill_color 0,0,0
   2d_circle 140,130,4
   2d_fill_color 0,220,0
   2d_pen_width 3
   2d_line 125,163,130,165
   2d_line 130,165,135,166
   2d_line 135,166,145,166
   2d_line 145,166,150,165
   2d_line 150,165,155,163
return
Dites donc, vous n'avez pas chômé, pendant mon absence !
Ouh, toutes les créations que je vais avoir à récapituler !!!
C'est pas possible, c'est un gag !
alien Laughing Laughing Laughing alien
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://jjn4.e-monsite.com
JL35



Nombre de messages : 5920
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Le martien est de retour   Dim 19 Oct 2014 - 19:00

Eh oui jjn4, fini les vacances exotiques, dis-donc tu en as bien profité, depuis le temps !
J'espère qu'au moins tu as eu du beau temps, tu as dû faire de la bronzette sur le sable, c'est pas ce qui manque là-bas.
D'accord, il n'y a pas la mer, que de la plage à perte de vue, mais on ne peut pas tout avoir non plus !

Et maintenant, au boulot, tu as du retard à rattraper ! Very Happy

Pas mal ton petit dessin, cela dit, mais bon, maintenant fini de jouer.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 4988
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Le martien est de retour   Dim 19 Oct 2014 - 19:09

Bon retour JJN4,

Je dois admettre que la téléportation c'est plus rapide que la soucoupe. Pourvu que que tu sois téléporté en une seul fois. alien

lol!

Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Laurent (Minibug)

avatar

Nombre de messages : 2353
Age : 50
Localisation : Vienne (86)
Date d'inscription : 10/02/2012

MessageSujet: Re: Le martien est de retour   Dim 19 Oct 2014 - 19:22

Bonjour jjn4 !

Content de te revoir parmi nous.
J'espère que tes vacances ont étés agréables.

Donc comme çà tu utilises le quadri-phasé !
Mais c'est pas trop long ? ! Laughing Laughing
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 7961
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Dim 19 Oct 2014 - 22:01

Bon retour parmis nous JJN4 !!!
Et surtout ne change rien, le port du string te va à merveille.....
lol! lol! lol! lol! lol! lol! lol! lol! lol! lol! lol! lol! lol! lol!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5501
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Le martien est de retour   Dim 19 Oct 2014 - 22:53



Je suis content de ton retour jjn4.

Ton si long séjour sur Mars t’as fait oublier qu’on a trouvé mieux que d’utiliser les LABEL / GOSUB.  Laughing  Laughing  Laughing  Laughing
Cette (mauvaise !?) remarque ne diminue en rien la valeur de ton code.

Pour changer les idées (les miennes je veux dire !  car je suis sur un article …) ….
Mauvais début de phrase, je l’admet :  je ne suis pas sur un article, mais je suis entrain d’écrire un article pour Le Mag sur …  (ne dévoilons pas le secret !) .
Alors, pour changer de registre, je me suis permis de passer ton excellent  code Martien à la machine Terrienne.
Je t’invite à apprécier l’optimisation de la SUB Transfert()  (à comparer avec la version Martienne !)  king  king  king



Code:

rem ============================================================================
rem            Retour du martien
rem             Par le Martien
rem           Revu par le Terrien
rem ============================================================================
init()
Venue()
end
rem ============================================================================
SUB Init()
    dim_local i,a$

    width 0,1300 : height 0,580
    a$="Le retour du martien"
    AnimateWindow()
    for i=300 to 1 step -1
        caption 0,string$(i," ")+a$+string$(601-i," ")
        pause 1 : ' Je prefère PAUSE à WAIT, devinez pourquoi ?
    next i
    caption 0,"Cabine de téléportation"
    for i=1300 to 340 step -2 : width 0,i : next i
    picture 100 : left 100,20 : top 100,20 :width 100,285 : height 100,500 : hide 100
       2d_target_is 100
    picture 200 : left 200,20 : top 200,20 : width 200,285 : height 200,500
END_SUB
rem ============================================================================
' Selon les paramètres, la fonction AnimateWindow masque (H10000) ou affiche (H2000)
' la fenêtre avec des effets spéciaux (par le centre H10, de haut en bas H4,
' de gauche à droite H2, de bas en haut H8, de droit à gauche  H1)

SUB AnimateWindow()
    dim_local ret%, hwnd%,tempo%
    color 0,0,255,255
    hwnd% = handle(0) : tempo% = 800 : ' Vous pouvez modifier la temporisation
    dll_on "user32.dll"

    ret% = dll_call3("AnimateWindow",hwnd%,tempo%, bin_or(hex("10"),hex("10000")))
    ret% = dll_call3("AnimateWindow",hwnd%,tempo%, bin_or(hex("10"),hex("20000")))

    ret% = dll_call3("AnimateWindow",hwnd%,tempo%, bin_or(hex("4"),hex("10000")))
    ret% = dll_call3("AnimateWindow",hwnd%,tempo%, bin_or(hex("2"),hex("20000")))

    ret% = dll_call3("AnimateWindow",hwnd%,tempo%, bin_or(hex("8"),hex("10000")))
    ret% = dll_call3("AnimateWindow",hwnd%,tempo%, bin_or(hex("1"),hex("20000")))

    ret% = dll_call3("AnimateWindow",hwnd%,tempo%, bin_or(hex("10"),hex("10000")))
    ret% = dll_call3("AnimateWindow",hwnd%,tempo%, bin_or(hex("10"),hex("20000")))

   dll_off
END_SUB
rem ============================================================================
' Arrivée du martien
SUB Venue()

    Tete() : Corps() : JambeD() : JambeG() : BrasDB() : BrasDH() : BrasGB() : BrasGH()
    Transfert()
    Pause 1000
    caption 0,"Téléportation terminée"
    Vie() : pause 2000
    caption 0,"Bonjour les amis !"

END_SUB
rem ============================================================================
' Affichage de la tête du martien
SUB Tete()

    2d_pen_width 1 :2d_fill_color 0,255,0 : 2d_circle 140,142,40
    2d_pen_color 0,200,0 : 2d_circle 135,150,2 : 2d_circle 145,150,2
    2d_pen_width 3 : 2d_line 112,112,85,70 : 2d_line 168,112,195,70
    2d_circle 85,70,4 : 2d_circle 195,70,4 : 2d_pen_color 0,0,0
    2d_line 125,163,155,163 : 2d_line 120,130,160,130 : 2d_pen_width 1

END_SUB
rem ============================================================================
' Affichage du corps du martien
SUB Corps()

    dim_local i
    for i=1 to 360 step 0.2 : 2d_point 140+45*cos(i),270+90*sin(i) : next i
    2d_flood 140,270,0,255,0 : 2d_fill_color 0,0,0
    2d_rectangle 100,300,181,310 : 2d_rectangle 134,310,146,360

END_SUB
rem ============================================================================
' Ajout de la jambe droite du martien
SUB JambeD()

    dim_local i
    2d_poly_from 146,359 : 2d_poly_to 160,450 : 2d_poly_to 175,447
    2d_poly_to 170,335 : 2d_flood 150,370,0,255,0
    for i=1 to 360 : 2d_point 185+35*cos(i),457+10*sin(i) : next i
    2d_flood 185,457,255,0,0
    
END_SUB
rem ============================================================================
' Ajout de la jambe gauche du martien
SUB JambeG()

    dim_local i
    2d_poly_from 134,359 : 2d_poly_to 120,450 : 2d_poly_to 105,447
    2d_poly_to 110,335 : 2d_flood 130,370,0,255,0
    for i=1 to 360 : 2d_point 95+35*cos(i),457+10*sin(i) : next i
    2d_flood 95,457,255,0,0
    
END_SUB
rem ============================================================================
' Ajout du bras droit bas du martien
SUB BrasDB()

    2d_poly_from 96,245 : 2d_poly_to 35,280 : 2d_poly_to 10,284
    2d_poly_to 33,286 : 2d_poly_to 28,310 : 2d_poly_to 38,290
    2d_poly_to 95,265 : 2d_flood 90,255,0,255,0
    
END_SUB
rem ============================================================================
'  Ajout du bras droit haut du martien
SUB BrasDH()

    2d_poly_from 116,195 : 2d_poly_to 40,220 :2d_poly_to 25,210
    2d_poly_to 34,222 : 2d_poly_to 20,232 : 2d_poly_to 36,228
    2d_poly_to 34,245 : 2d_poly_to 43,228 : 2d_poly_to 106,215
    2d_flood 100,205,0,255,0
    
END_SUB
rem ============================================================================
' Ajout du bras gauche bas du martien
SUB BrasGB()

    2d_poly_from 184,245 : 2d_poly_to 245,280 :2d_poly_to 270,284
    2d_poly_to 247,286 : 2d_poly_to 252,310 : 2d_poly_to 242,290
    2d_poly_to 185,265 : 2d_flood 190,255,0,255,0
END_SUB
rem ============================================================================
' Ajout du bras gauche haut du martien
SUB BrasGH()

    2d_poly_from 164,195 : 2d_poly_to 240,220 : 2d_poly_to 255,210
    2d_poly_to 246,222 : 2d_poly_to 260,232 : 2d_poly_to 244,228
    2d_poly_to 246,245 : 2d_poly_to 237,228 : 2d_poly_to 174,215
    2d_flood 180,205,0,255,0
END_SUB
rem ============================================================================
' Transfert du martien
SUB Transfert()
    dim_local i,j, phase, di
    dim cr : ' Couleur Red
    dim cg : ' Couleur Green
    dim cb : ' Couleur Blue

    for phase = 1 to 4
        if (phase = 1) or (phase = 4) then di = 0 : else : di = 1
        caption 0,"Téléportation : phase " + str$(phase)
        for i = 60 + di to 470 step 2
            '  La fonction EVEN(V) retourne 1 si V est pair, O sinon.
            for j = 10 + even(phase) to 275 step 2
                cr = color_pixel_red(100,j,i)
                cg = color_pixel_green(100,j,i)
                cb = color_pixel_blue(100,j,i)
                2d_target_is 200 : 2d_pen_color cr,cg,cb : 2d_point j,i
            next j
            display
         next i
    next phase
    beep

END_SUB
rem ============================================================================
' Retour à la vie du martien
SUB Vie()
    dim_local i
    2d_pen_color 0,255,0 : 2d_pen_width 3
    2d_line 120,130,160,130 : 2d_line 125,163,155,163
    2d_pen_color 0,0,0 : 2d_pen_width 1
    for i=0 to 360 : 2d_point 140+20*cos(i),130+10*sin(i) : next i
    2d_flood 140,130,255,255,255 : 2d_fill_color 0,200,255
    2d_circle 140,130,9 : 2d_fill_color 0,0,0
    2d_circle 140,130,4 : 2d_fill_color 0,220,0
    2d_pen_width 3
    2d_line 125,163,130,165 : 2d_line 130,165,135,166
    2d_line 135,166,145,166 : 2d_line 145,166,150,165
    2d_line 150,165,155,163
END_SUB
rem ============================================================================
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Invité
Invité



MessageSujet: Re: Le martien est de retour   Lun 20 Oct 2014 - 2:14

Bon retour JJN4. Ton programme est sympa.
Revenir en haut Aller en bas
Jicehel

avatar

Nombre de messages : 5849
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Le martien est de retour   Lun 20 Oct 2014 - 8:59

Bon retour sur terre et bonne lecture Smile
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
mindstorm

avatar

Nombre de messages : 530
Age : 48
Localisation : charente
Date d'inscription : 13/02/2013

MessageSujet: Re: Le martien est de retour   Mer 22 Oct 2014 - 0:00

bonjour JJN4
il n'est pas bien mur ton Martien
peut être faudrait il le laisser murir
Laughing
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
jjn4

avatar

Nombre de messages : 1594
Date d'inscription : 13/09/2009

MessageSujet: +++   Mer 22 Oct 2014 - 19:59

Eh oui, le port du string nous permet de mieux mettre en évidence notre belle couleur vert pomme !!!

Merci pour la transformation de mon programme, Papydall,
j'avais conscience que je pouvais faire mieux, dans le programme transfert
que de répéter quatre fois la séquence, mais j'ai eu la flemme d'améliorer cela !
(que veux-tu, le travail, quand, à la retraite, on rentre en plus de vacances...)
Et c'est vrai que c'est mieux de le mettre avec des sub.
Je ne le fais pas spontanément, car quand j'ai appris le basic, (en lointaine jeunesse)
les sub n'existaient pas dans ces basics-là.
Et l'habitude aidant... (moi, j'aime bien les gosub !)
Mais c'est sûr qu'il faudra que je m'y mette un jour
(au moins pour faire joli dans la Mag...) Laughing
Bon, mais je ne promets rien tout de suite...!
No alien No
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://jjn4.e-monsite.com
Jean Claude

avatar

Nombre de messages : 4988
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Le martien est de retour   Mer 22 Oct 2014 - 21:49

@JJN4,

Les SUB(s), je te les conseille, et tu verras une simplification de tes codes.

Ce qui m’interroge? :  as-tu voulu démontrer que: vous (les martiens) avez remplacé la soucoupe volante par la téléportation ???? Question  alien
Cela fait plusieurs jours que je dors mal, en me disant: "il sont trop fort ces martiens".

lol!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5501
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Le martien est de retour   Jeu 23 Oct 2014 - 2:20

JJn4 Alias Le Martien a écrit:

Et c'est vrai que c'est mieux de le mettre avec des sub.
Je ne le fais pas spontanément, car quand j'ai appris le basic, (en lointaine jeunesse)
les sub n'existaient pas dans ces basics-là.

Moi aussi je suis né avant les SUB ; Heu… je veux dire que j’ai appris le BASIC avec le super micro-ordinateur que voici



Et pourtant …. Laughing
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
jjn4

avatar

Nombre de messages : 1594
Date d'inscription : 13/09/2009

MessageSujet: +++   Jeu 23 Oct 2014 - 18:54

@Papydall
Et pourtant..., en effet, comme tu dis,
puisque mon premier ordinateur a été le laser 200
donc 1 ou 2 ans après toi...
Bon, j'essaierai de faire des sub, dans l'avenir !

@Jean-Claude
Bien sûr qu'ils sont super forts, ces martiens à peau verdâtre !
Mais que cela ne t'empêche pas de dormir !!!
Dommage que je ne puisse composer un programme de téléportation en panoramic...
Laughing alien Laughing
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://jjn4.e-monsite.com
Laurent (Minibug)

avatar

Nombre de messages : 2353
Age : 50
Localisation : Vienne (86)
Date d'inscription : 10/02/2012

MessageSujet: Re: Le martien est de retour   Jeu 23 Oct 2014 - 21:29

Citation :
Dommage que je ne puisse composer un programme de téléportation en panoramic...

Ah bon !! Bah pourquoi ?? !!! drunken drunken drunken
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
jjn4

avatar

Nombre de messages : 1594
Date d'inscription : 13/09/2009

MessageSujet: +++   Ven 24 Oct 2014 - 20:53

Il faudra demander à Jack de nous fabriquer quelques commandes à effet quantique...
Mais là, il risque de s'arracher les cheveux !!!
Laughing alien Laughing
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://jjn4.e-monsite.com
Laurent (Minibug)

avatar

Nombre de messages : 2353
Age : 50
Localisation : Vienne (86)
Date d'inscription : 10/02/2012

MessageSujet: Re: Le martien est de retour   Ven 24 Oct 2014 - 21:38

C'est peu être pour bientôt...

regardez ce lien : Ordinateur quantique

bomdrunkenrendeerkinggeekscratchLaughingLaughing
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
jjn4

avatar

Nombre de messages : 1594
Date d'inscription : 13/09/2009

MessageSujet: +++   Sam 25 Oct 2014 - 15:47

Tu as raison, c'est peut-être pour bientôt !
Dans ce cas, vaut mieux être les premiers.

Alors je suggère à Jack :
- atome_change (x,y,z),(x1,y1,z1)
- univers_change n,m
et surtout :
- chat_schrodinger n,x,y
(sinon, pas de téléportation possible)
lol! lol! lol! alien lol! lol! lol!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://jjn4.e-monsite.com
Contenu sponsorisé




MessageSujet: Re: Le martien est de retour   

Revenir en haut Aller en bas
 
Le martien est de retour
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» retour au travail....
» Le 23 mai Varadero me voilà/et c'est grâce à vous/retour à la réalité
» Est-ce que quelqu'un a vu le retour de Nounou McPhee
» Retour maison
» Retour 3D' S-Pagne...

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC 32 bits :: Les inutilitaires-
Sauter vers: