FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» StratégoV8 et V9
par Minibug Aujourd'hui à 1:10

» Rotation d'une image d'un angle quelconque
par JL35 Hier à 23:02

» GRID_LOAD
par Jean Claude Hier à 21:04

» HVIEWER
par Yannick Hier à 20:31

» KGF_dll - nouvelles versions
par Klaus Mar 16 Jan 2018 - 21:28

» Déformation d'image en trapèze
par mindstorm Mar 16 Jan 2018 - 21:06

» Mah-Jong américain
par Jean Claude Lun 15 Jan 2018 - 19:37

» Problème avec Deepl
par Klaus Lun 15 Jan 2018 - 0:34

» Quelques nouvelles ...
par Jean Claude Ven 12 Jan 2018 - 22:40

» Renommer les instructions ITEM_... ?
par Jicehel Ven 12 Jan 2018 - 18:56

» Ludothèque Panoramic
par jjn4 Ven 12 Jan 2018 - 18:11

» sous-programmes et fonctions
par Jack Ven 12 Jan 2018 - 17:51

» Mah-Jong français
par Jean Claude Jeu 11 Jan 2018 - 22:15

» panoramic 0.9.28
par gigi75 Ven 5 Jan 2018 - 14:06

» Un jeu qui va vous énerver!
par Jean Claude Jeu 4 Jan 2018 - 22:05

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Janvier 2018
LunMarMerJeuVenSamDim
1234567
891011121314
15161718192021
22232425262728
293031    
CalendrierCalendrier

Partagez | 
 

 J’ai dépoussiéré un code de jeu

Voir le sujet précédent Voir le sujet suivant Aller en bas 
AuteurMessage
papydall

avatar

Nombre de messages : 5623
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: J’ai dépoussiéré un code de jeu   Ven 8 Nov 2013 - 21:52

Salut tout le monde.

En me baladant sur ce Forum, je suis tombé nez à nez avec un jeu, mais pas n’importe lequel !
Un jeu codé par le géniteur officiel de PANORAMIC :  j’ai nommé Jack, et posté le 3/11/2008.

C’est ici

Comme je trouve qu’il s’agit d’un bon jeu et d’un bon exercice de Panoramic, je l’ai habillé  à la mode de la version actuelle ( avec des SUBs, des SELECTs, etc..).
Tout en espérant que je n’ai pas défiguré trop sa structure, je vous remets mon œuvre.

Est-il nécessaire de rappeler à certains qu’ils prennent la précaution de prévoir du Paracétamol !

Code:
rem ============================================================================
rem                              SYNAPSE.BAS
rem  Jeu initialement élaboré par JACK (créateur de PANORAMIC) le 03/12/2008
rem                 remis à jour par PAPYDALL le 08/11/2013
rem              en y intégrant les nouveautés du langage PANORAMIC
rem ============================================================================
Run()
end
rem ============================================================================
SUB Run()
    label jeu
    dim game%(20,11),c,i,j,k,k$,lev,m,nc,xs,ys,xp,yp
    width 0,800 : height 0,800
    scene3D 1 : full_space 1 : color 1,70,120,120
    caption 0,"SYNAPSE 3D : flèches pour bouger, <ESC> pour termimer"
    Rules()
    button 20 : top 20, 680 : left 20,300 : height 20,40 : width 20,100
    font_size 20,14 : caption 20,"CLIQUEZ" : on_click 20,jeu

END_SUB
rem ============================================================================
SUB Rules()
    3d_delete_all
    cam_x_position 6 : cam_y_position 6 : cam_z_position 8
    point_x_position 6 : point_y_position 6
    3d_box 1,0.95,0.95,0.2 : 3d_color 1,70,70,70
    3d_x_position 1,0 : 3d_y_position 1,11
    3d_text 2,"GRIS = 1 PASSAGE" : 3d_color 2,70,70,70
    3d_x_position 2,2 : 3d_y_position 2,11

    3d_box 3,0.95,0.95,0.2 : 3d_color 3,0,0,255
    3d_x_position 3,0 : 3d_y_position 3,9.6
    3d_text 4,"BLEU = 2 PASSAGES" : 3d_color 4,0,0,255
    3d_x_position 4,2 : 3d_y_position 4,9.6

    3d_box 5,0.95,0.95,0.2 : 3d_color 5,0,255,0
    3d_x_position 5,0 : 3d_y_position 5,8.2
    3d_text 6,"VERT = 3 PASSAGES" : 3d_color 6,0,255,0
    3d_x_position 6,2 : 3d_y_position 6,8.2

    3d_box 7,0.95,0.95,0.2 : 3d_color 7,255,0,0
    3d_x_position 7,0 : 3d_y_position 7,6.8
    3d_text 8,"ROUGE = 4 PASSAGES" : 3d_color 8,255,0,0
    3d_x_position 8,2 : 3d_y_position 8,6.8

    3d_box 9,0.95,0.95,0.2 : 3d_color 9,255,0,255
    3d_x_position 9,0 : 3d_y_position 9,5.4
    3d_text 10,"VIOLET = SAUT" : 3d_color 10,255,0,255
    3d_x_position 10,2 : 3d_y_position 10,5.4

    3d_box 11,0.95,0.95,0.2 : 3d_color 11,255,255,0
    3d_x_position 11,0 : 3d_y_position 11,4
    3d_text 12,"JAUNE = BUT" : 3d_color 12,255,255,0
    3d_x_position 12,2 : 3d_y_position 12,4

    3d_text 13,"Flèches pour se déplacer" : 3d_color 13,70,70,70
    3d_x_position 13,0 : 3d_y_position 13,2.5

    3d_text 14,"ESCAPE pour SORTIR" : 3d_color 14,70,70,70
    3d_x_position 14,0 : 3d_y_position 14,1
    
    3d_text 15,"PRET ?" : 3d_color 15,70,70,70
    3d_x_position 15,0 : 3d_y_position 15,-1
    
    3d_text 17,"***** S Y N A P S E  3 D *****" : 3d_x_position 17,01 : 3d_y_position 17,12.5
    3d_color 17,255,255,255
END_SUB
rem ============================================================================
jeu:
    hide 20
    3d_delete_all : lev = 1 : ' level
    start()
return
rem ============================================================================
SUB start()
    if lev = 9 then panoramic() : end : ' last level is 8
    level()
    restore
' clear the game 20x11
    for i = 1 to 20 : for j = 1 to 11 : game%(i,j)=0 : next j : next i
    if lev > 1
       for i = 1 to lev - 1 : ' jump the upper levels
           read nc
           for c = 1 to nc : read k : read k : read k : next c
       next i
    end_if
    3d_delete_all
' set the light
    cam_x_position 0:cam_y_position 0:cam_z_position 9
' read number of squares
    read nc
' put the character (red sphere) on the first square
    3d_sphere 1,0.3 : 3d_color 1,255,0,0
    read xs : read ys : ' read position of first square (character)
    3d_x_position 1,xs : 3d_y_position 1,ys
' memorize the colors in the table
    read c : ' read the code
    game%(xs,ys) = c
    for i = 2 to nc
        read xp : read yp : ' read the coordinates
        read c : ' read the code
        game%(xp,yp) = c
    next i
    draw_game()
    Main_Loop()
END_SUB
rem ============================================================================
' DISPLAY ADVERTISEMENT
rem ============================================================================
SUB panoramic()
    3d_delete_all
' set the camera for text
    cam_x_position 8 : cam_y_position 6 : cam_z_position 11
' aim the camera
    point_x_position 8 : point_y_position 6
' set the light
    light_x_position 8 : light_y_position 6 : light_z_position 10
    3d_text 2,"Ce jeu a été programmé"
    3d_color 2,70,70,70 : 3d_x_position 2,0 : 3d_y_position 2,10
    3d_text 3,"avec le langage PANORAMIC disponible sur :"
    3d_color 3,70,70,70 : 3d_x_position 3,0 : 3d_y_position 3,6
    3d_text 4,"www.panoramic-language.com"
    3d_color 4,15,15,255 : 3d_x_position 4,0 : 3d_y_position 4,2
    caption 0,"Cliquez sur la croix pour fermer. A bientôt sur le site !"
END_SUB
rem ============================================================================
' DISPLAY LEVEL
rem ============================================================================
SUB level()
    3d_delete_all
' set the camera for text
    cam_x_position 2 : cam_y_position 6 : cam_z_position 5
' aim the camera
    point_x_position 2 : point_y_position 6
    3d_text 2,"Niveau " + str$(lev) : 3d_color 2,70,70,70
    3d_x_position 2,0 : 3d_y_position 2,6
    wait 2000
END_SUB
rem ============================================================================
' DRAW THE BOARD
rem ============================================================================
SUB draw_game()
' set the camera to play
    cam_x_position 8 : cam_y_position 8 : cam_z_position 9
' aim the camera
    point_x_position 8 : point_y_position 8
' read the table, create the squares with their color
    k = 1
    for i = 1 to 20
        for j = 1 to 11
            select game%(i,j)
                case 1  : k = k + 1 : 3d_box k,0.95,0.95,0.2 : 3d_x_position k,i : 3d_y_position k,j : 3d_color k,70,70,70
                case 2  : k = k + 1 : 3d_box k,0.95,0.95,0.2 : 3d_x_position k,i : 3d_y_position k,j : 3d_color k,0,0,255
                case 3  : k = k + 1 : 3d_box k,0.95,0.95,0.2 : 3d_x_position k,i : 3d_y_position k,j : 3d_color k,0,255,0
                case 4  : k = k + 1 : 3d_box k,0.95,0.95,0.2 : 3d_x_position k,i : 3d_y_position k,j : 3d_color k,255,0,0
                case 9  : k = k + 1 : 3d_box k,0.95,0.95,0.2 : 3d_x_position k,i : 3d_y_position k,j : 3d_color k,255,0,255
                case -1 : k = k + 1 : 3d_box k,0.95,0.95,0.2 : 3d_x_position k,i : 3d_y_position k,j : 3d_color k,255,255,0
            end_select
       next j
    next i
END_SUB
rem ============================================================================
' MAIN LOOP : read the keyboard for the moves
rem ============================================================================
SUB Main_Loop()
    while "Jack" <> "Papydall" : ' hé une belle boucle infinie mais rassurez-vous, la sortie a été prévue !
        repeat
            m = 0
            select scancode
               case 37 : m = 37 : xp = xs : yp = ys : xs = xs - 1 :  move() : exit_repeat : ' left
               case 38 : m = 38 : xp = xs : yp = ys : ys = ys + 1 :  move() : exit_repeat : ' up
               case 39 : m = 39 : xp = xs : yp = ys : xs = xs + 1 :  move() : exit_repeat : ' right
               case 40 : m = 40 : xp = xs : yp = ys : ys = ys - 1 :  move() : exit_repeat : ' bottom
               case 32 : start() : ' SPACE
               case 13 : start() : ' ENTER
               case 27 : terminate
            end_select
            wait 50
        until "PANORAMIC" = "Panoramic" : ' une boucle sans fin, mais rassurez-vous, la sortie a été prévue !
    end_while
END_SUB
rem ============================================================================
SUB move()
    if game%(xp,yp) = 9 : ' JUMP = double move
       if m = 37 then xs = xs - 1
       if m = 38 then ys = ys + 1
       if m = 39 then xs = xs + 1
       if m = 40 then ys = ys - 1
    end_if
' move the character to (xs,ys)
    3d_x_position 1,xs : 3d_y_position 1,ys
' check if no square under character
    if game%(xs,ys) = 0 then wait 500 : ooops() : rules() : start() : ' fall !
    if game%(xp,yp) = 9 then game%(xp,yp) = 1 : ' case of jump
    game%(xp,yp) = game%(xp,yp) - 1           : ' changes the value
    if game%(xp,yp) = 0 then nc = nc - 1      : ' number of characters

    3d_delete_all
' recreate the character
    3d_sphere 1,0.3 : 3d_color 1,255,0,0
    3d_x_position 1,xs : 3d_y_position 1,ys
' draw the new game (the squares)
    draw_game()
    if game%(xs,ys) = -1
       wait 1000
       if nc = 1 then bravo() : lev = lev + 1 : start() : ' goal reached !
       ooops() : rules() : start()
    end_if
    wait 100
END_SUB
rem ============================================================================
' DISPLAY OOOPS
rem ============================================================================
SUB ooops()
    3d_delete_all
' set the camera for text
    cam_x_position 2:cam_y_position 6:cam_z_position 5
' aim the camera
    point_x_position 2:point_y_position 6
    3d_text 2,"OOOPS ...":3d_color 2,70,70,70
    3d_x_position 2,0:3d_y_position 2,6
    wait 2000
END_SUB
rem ============================================================================
' DISPLAY BRAVO
rem ============================================================================
SUB bravo()
    3d_delete_all
' set the camera for text
    cam_x_position 2:cam_y_position 6:cam_z_position 5
' aim the camera
    point_x_position 2:point_y_position 6
    3d_text 2,"BRAVO !":3d_color 2,70,70,70
    3d_x_position 2,0:3d_y_position 2,6
    wait 2000
END_SUB
rem ============================================================================
' level 1
data 15 : ' number of squares
data 5,8,1 : ' start
data 6,8,1
data 7,8,1
data 8,8,1
data 9,8,1
data 9,7,1
data 9,6,1
data 8,6,1
data 7,6,1
data 7,5,1
data 8,5,1
data 9,5,1
data 10,5,1
data 11,5,1
data 12,5,-1 : ' goal

' level 2
data 14
data 6,4,1
data 7,4,1
data 8,4,1
data 9,4,1
data 10,4,1
data 11,4,2
data 11,5,1
data 12,4,1
data 13,4,1
data 14,4,1
data 15,4,1
data 15,5,1
data 15,6,9
data 15,8,-1

' level 3
data 18
data 12,8,1
data 12,7,1
data 12,6,1
data 12,5,1
data 11,5,1
data 10,5,1
data 9,5,1
data 8,5,1
data 7,5,1
data 6,5,1
data 6,4,1
data 6,3,1
data 7,3,1
data 8,3,1
data 9,3,1
data 10,3,1
data 10,4,9
data 10,6,-1

' level 4
data 19
data 13,6,1
data 14,6,9
data 12,6,1
data 11,6,2
data 10,6,2
data 9,6,2
data 8,6,1
data 7,6,1
data 6,6,1
data 6,5,1
data 6,4,1
data 7,4,1
data 8,4,1
data 9,4,1
data 10,4,1
data 11,4,1
data 11,5,1
data 11,7,1
data 11,8,-1

' level 5
data 16
data 8,6,1
data 9,6,2
data 10,6,2
data 11,6,2
data 12,6,2
data 13,6,4
data 13,7,1
data 13,8,9
data 14,6,1
data 15,6,9
data 13,5,1
data 13,4,9
data 9,5,1
data 8,5,1
data 7,5,1
data 7,6,-1

' level 6
data 14
data 7,8,1
data 8,8,1
data 9,8,1
data 10,8,1
data 11,8,1
data 12,8,1
data 13,8,1
data 13,7,1
data 12,7,1
data 11,7,1
data 11,6,1
data 12,6,9
data 13,6,9
data 12,4,-1

' level 7
data 16
data 9,9,1
data 10,9,1
data 11,9,1
data 12,9,1
data 12,8,1
data 12,7,1
data 13,7,1
data 12,6,2
data 12,5,2
data 11,6,9
data 11,5,9
data 11,4,9
data 12,4,9
data 13,6,9
data 13,5,9
data 13,4,-1

' level 8
data 16
data 8,8,1
data 8,7,9
data 9,9,1
data 9,8,2
data 9,7,1
data 9,6,1
data 9,5,1
data 10,9,1
data 10,8,1
data 10,7,9
data 10,6,1
data 11,8,1
data 11,7,2
data 11,6,2
data 11,5,9
data 8,9,-1
rem ========================== FIN =============================================
PS : Je suis bloqué au level 7, mais je n’ai pas trop insisté (ce n’est pas faute  de stock de Paracétamol !) mais pour vous faire découvrir ou redécouvrir ce jeu sans plus tarder.
Alors amusez-vous bien !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Jean Claude

avatar

Nombre de messages : 5130
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: J’ai dépoussiéré un code de jeu   Ven 8 Nov 2013 - 22:31

Ce jeu est une torture mentale (çà devrait être interdit, c'est scandaleux, Jack a certainement des accords avec les pharmaciens). lol!   

Je suis arrivé au niveau 7 et je bloque ici:



Trêve de plaisanteries...
J'ai constaté quelques problèmes de réinitialisation en cas d'erreur, (difficile de les noter)

J'aimerais bien trouver le code original pour le tester.

PS: j'avais pas vu le lien (merci Papydall)
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 5130
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: J’ai dépoussiéré un code de jeu   Ven 8 Nov 2013 - 22:41

@Papydall,

Il faut que tu revois ta copie car le code de Jack réinitialise correctement en cas d'erreur.

bon j'ai mal à la tête drunken 

A+


Dernière édition par Jean Claude le Ven 8 Nov 2013 - 23:54, édité 1 fois
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Minibug

avatar

Nombre de messages : 2483
Age : 51
Localisation : Vienne (86)
Date d'inscription : 10/02/2012

MessageSujet: Re: J’ai dépoussiéré un code de jeu   Ven 8 Nov 2013 - 23:00

Bravo papydall cheers  et bravo aussi a Jack king !!

Dommage que ce soit si court !!! J'ai tout résolu en 10 minutes. drunken

Dis papydall fais nous des niveaux supplémentaires, s'il te plais ?? bounce bounce bounce 

Encore merci pour avoir ressorti ce jeu. Laughing
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://gpp.panoramic.free.fr
papydall

avatar

Nombre de messages : 5623
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: J’ai dépoussiéré un code de jeu   Sam 9 Nov 2013 - 0:13

Minibug a écrit:
Dis papydall fais nous des niveaux supplémentaires, s'il te plais ?? bouncebouncebounce
Tout d’abord c’est le code de Jack et non le mien :  je l’ai simplement recodé (à la va vite ) sans d’ailleurs en saisir le comment de son fonctionnement .
Jean Claude signale un dysfonctionnement de mon code. Je vais voir.
Vous pouvez tous (enfin ceux qui veulent bien) enrichir ce code en ajoutant d’autres niveaux( si vous avez compris le principe), et  ajouter  (pourquoi pas) une musiquette ou des effets sonores ou …

Quant à moi, je vais essayer d’y voir ce qui ne va pas suite à la remarque de JC

PS : S’il y a un bug dans mon code, utilisez l’original.
Je vous rappelle le lien :  C’est ici
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
papydall

avatar

Nombre de messages : 5623
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: J’ai dépoussiéré un code de jeu   Sam 9 Nov 2013 - 1:29

Je viens de réussir mon permis de SYNAPSE.
Il paraît que mes neurones peuvent encore rétablir des connexions entres elles !

Je suis arrivé à bout des 8 niveaux, certes après quelques (plutôt plusieurs !) chutes mais je n’ai pas rencontré le moindre dysfonctionnement du programme.

Jean Claude, est-ce que tu reconfirmes les problèmes de réinitialisation ?
Si oui, tu veux bien être un petit peu plus précis ?
Et vous, les autres vous confirmez ? Non ? He bien tant mieux !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Jicehel

avatar

Nombre de messages : 5876
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: J’ai dépoussiéré un code de jeu   Sam 9 Nov 2013 - 2:32

J'ai récupéré internet et j'ai testé et je confirme le bug qui se produit parfois quand on meurt.
Au lieu de réapparaitre sur la case de départ, on réapparait une case trop haut ou trop bas et au démarrage suivant, on est de nouveau bien positionné. Il doit rester une information d'avant qui fait monter ou descendre le personnage d'une case...
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5623
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: J’ai dépoussiéré un code de jeu   Sam 9 Nov 2013 - 2:50

Je n’ai pas pu localiser le bug car je ne l’ai pas encore rencontré !
Chez moi, tout semble correct.
Jicehel, tu as récupéré Internet, donc tu nous dois quelque chose : Very Happy 
Puisque tu disposes des deux codes (celui de Jack et le mien) tu veux bien chercher de ta part où ça pourrait clocher ?
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Jicehel

avatar

Nombre de messages : 5876
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: J’ai dépoussiéré un code de jeu   Sam 9 Nov 2013 - 11:24

Je ne te promets rien Papydall, j'ai 15 jours de retard sur certaines choses que je fais à côté et j'ai des codes à tester, mais après je regarde, promis..... Very Happy
(J'oubliais, j'ai aussi quelques corrections à apporter à mon article aussi et à les remettre sur le Webdav de notre absent breton)
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
treehouse

avatar

Nombre de messages : 28
Localisation : UK
Date d'inscription : 21/10/2013

MessageSujet: Re: J’ai dépoussiéré un code de jeu   Dim 24 Nov 2013 - 17:27

Il s'agit d'un grand jeu! Bravo!, Jack et papydall.

Je me demande si il serait difficile d'écrire un algorithme général pour créer les niveaux, afin que le programme lui-même peut concevoir de nombreux utilisant des variables aléatoires. Il débutera à la fin et travailler en arrière, je suppose. Si je m'ennuie ...affraid 
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5876
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: J’ai dépoussiéré un code de jeu   Dim 24 Nov 2013 - 19:23

Ce serait excellent Treehouse. J'espère que tu t’ennuieras assez pour t'y pencher, ça vaudrait le coup Wink
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
mindstorm

avatar

Nombre de messages : 545
Age : 48
Localisation : charente
Date d'inscription : 13/02/2013

MessageSujet: Re: J’ai dépoussiéré un code de jeu   Mar 26 Nov 2013 - 21:15

extra ce jeu jocolor 
avec des moyens aussi simple
chapeau bas
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Contenu sponsorisé




MessageSujet: Re: J’ai dépoussiéré un code de jeu   

Revenir en haut Aller en bas
 
J’ai dépoussiéré un code de jeu
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» code pour inséré les anime (Fond transparent)
» manuel de code e-anim
» J'ai 2 code pour avoir 6 razoirs Shick Induition DÉJÀ DONNÉ
» Vidéos - générateur de code pour vidéo et player
» [Nocturne] Demande d'aide pour code css complet s'il vous plait.

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Les jeux faits avec Panoramic-
Sauter vers: