FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» Pb 16 (en analyse): ON_CLOSE plante à l'exécution
par Jack Aujourd'hui à 20:00

» Pb 15 (en analyse): TIMER_ON plante à l'exécution
par Jack Aujourd'hui à 19:58

» Compilateur FBPano
par jean_debord Aujourd'hui à 8:49

» un nouveau editeur panobasic
par Jean Claude Hier à 20:05

» COMPILATEUR V 0.9 beta 7 du 10 aout 2017
par Pedro Alvarez Hier à 19:31

» KGF_dll - nouvelles versions
par Yannick Dim 13 Aoû 2017 - 17:35

» probleme d'outil
par Yannick Dim 13 Aoû 2017 - 17:32

» Carte de France des régions
par Yannick Sam 12 Aoû 2017 - 21:33

» Pb 14 (en analyse): PRINT_LOCATE plante à l'exécution
par Jack Ven 11 Aoû 2017 - 22:37

» Petit avertissement [Mots réservés]
par papydall Ven 11 Aoû 2017 - 13:45

» Distances sur plan
par JL35 Jeu 10 Aoû 2017 - 21:29

» Tracé : Triangle, Carrée, Dents de scie, Sinusoïde redressée
par papydall Jeu 10 Aoû 2017 - 14:52

» Troncature dans une image
par JL35 Mer 9 Aoû 2017 - 13:45

» A chacun son point de vue
par papydall Mar 8 Aoû 2017 - 17:20

» Problème avec les chaines de caractères
par bignono Dim 6 Aoû 2017 - 9:33

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Août 2017
LunMarMerJeuVenSamDim
 123456
78910111213
14151617181920
21222324252627
28293031   
CalendrierCalendrier

Partagez | 
 

 Planche-contact

Voir le sujet précédent Voir le sujet suivant Aller en bas 
AuteurMessage
JL35



Nombre de messages : 5920
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Planche-contact   Lun 9 Sep 2013 - 17:59

On dirait bien que les affaires reprennent, fini la dorure sur les plages !

Alors pour ajouter mon grain de sel, pour ceux qui ont des photos de vacances à classer, montrer, communiquer, une petite sub qui permet de rassembler en une seule image des imagettes de plusieurs photos.
Les paramètres donnés à la sub sont:
- le nombre de colonnes d'images dans la planche (le nombre de rangées sera déterminé par le nombre total d'images).
- la largeur en pixels de chaque imagette, les images verticales seront basculées à l'horizontale.
- le rapport de proportion largeur/hauteur des images (4:3 ou 3:2)
- l'écartement en pixels entre les colonnes.
- l'écartement en pixels entre les rangées
- un drapeau pour affichage ou non du nom du fichier image sous celle-ci.
- un titre général éventuel pour la planche.
- le chemin du fichier qui contient la liste (les chemins complets) des images.
- le chemin du fichier résultat.

Pour ceux qui sont allergiques à IrfanView, passez votre chemin, c'est lui qui fait le gros boulot (réduction et assemblage des images).
Il faut jouer sur les paramètres largeur d'imagettes/nombre de colonnes pour avoir une répartition harmonieuse par exemple dans les proportions d'une page A4, qu'on peut ensuite imprimer, pour classement, toujours avec IrfanView, éventuellement sur papier photo, le résultat est très bon si la définition choisie est correcte.
L'exécution est rapide, il est facile de modifier les paramètres pour voir le résultat, avant impression par exemple.

Avec un petit exemple d'utilisation en tête:
Code:
LABEL Chr, Chs, Sel, Seltout, Desel, Suptout, Exec, Caldpi
DIM nc%,wc%,ra,ec%,er%,nom%,titre$,fl$,fr$,a$
DIM wl%, i%, r$, f$, lt%, dpi%

fl$ = "C:\TEMP\Liste.txt"
fr$ = "C:\TEMP\Planche.jpg"

wl% = 220
HEIGHT 0,800: BORDER_SMALL 0: FONT_BOLD 0: COLOR 0,190,255,255
WIDTH 0,2*wl%+16: CAPTION 0,string$(45," ")+" -   PLANCHE   DE   PHOTOS   -"
EDIT 1: LEFT 1,0: WIDTH 1,2*wl%: TEXT 1,"Répertoire des images ...": ON_CLICK 1,Chr
ALPHA 2: TOP 2,25: CAPTION 2,"Total:"
BUTTON 3: TOP 3,20: LEFT 3,wl%-60: WIDTH 3,60: CAPTION 3,"Tout": ON_CLICK 3,Seltout
LIST 4: TOP 4,45: WIDTH 4,wl%: HEIGHT 4,HEIGHT(0)-96: ON_CLICK 4,Sel: COLOR 4,255,255,180
ALPHA 6: TOP 6,25: LEFT 6,wl%+5: CAPTION 6,"Sélect:"
BUTTON 7: TOP 7,20: LEFT 7,LEFT(6)+wl%-65: WIDTH 7,60: CAPTION 7,"Raz": ON_CLICK 7,Suptout
LIST 8: TOP 8,TOP(4): LEFT 8,wl%: WIDTH 8,wl%: HEIGHT 8,400: ON_CLICK 8,Desel
COLOR 8,255,255,164
CONTAINER 10: TOP 10,TOP(8)+HEIGHT(8)+2: LEFT 10,LEFT(8): WIDTH 10,wl%: HEIGHT 10,305
COLOR 10,255,190,190
ALPHA 11: PARENT 11,10: TOP 11,12: LEFT 11,10: CAPTION 11,"Colonnes:"
SPIN 12: PARENT 12,10:TOP 12,10: LEFT 12,65: WIDTH 12,40
MIN 12,1: MAX 12,20: POSITION 12,4
ALPHA 13: PARENT 13,10: TOP 13,12: LEFT 13,105: CAPTION 13,"-> xx rangées"
ALPHA 18: PARENT 18,10: TOP 18,38: LEFT 18,5
CAPTION 18,"Largeur des images:              pixels"
SPIN 19: PARENT 19,10: TOP 19,35: LEFT 19,120: WIDTH 19,50
MIN 19,10: MAX 19,1999: POSITION 19,300
CONTAINER_OPTION 30: PARENT 30,10: TOP 30,60: LEFT 30,5: HEIGHT 30,28: WIDTH 30,WIDTH(10)-10
CAPTION 30,"Proportions images :": COLOR 30,255,210,210
OPTION 31: PARENT 31,30: TOP 31,6: LEFT 31,120: CAPTION 31,"4:3": MARK_ON 31
OPTION 32: PARENT 32,30: TOP 32,TOP(31): LEFT 32,LEFT(31)+45: CAPTION 32,"3:2"

ALPHA 14: PARENT 14,10: TOP 14,93: LEFT 14,10: CAPTION 14,"Écartement entre colonnes:"
SPIN 15: PARENT 15,10: TOP 15,TOP(14)-3: LEFT 15,170: WIDTH 15,40
MIN 15,0: MAX 15,100: POSITION 15,2
ALPHA 16: PARENT 16,10: TOP 16,TOP(14)+20: LEFT 16,10: CAPTION 16,"Écartement entre rangées:"
SPIN 17: PARENT 17,10: TOP 17,TOP(16)-3: LEFT 17,LEFT(15): WIDTH 17,40
MIN 15,0: MAX 17,100: POSITION 17,30

ALPHA 25: PARENT 25,10: LEFT 25,15: TOP 25,TOP(17)+30: CAPTION 25,"->dpi à l'impression A4:"
COLOR 25,255,210,210
EDIT 26: PARENT 26,10: TOP 26,TOP(25)-3: LEFT 26,150: WIDTH 26,50

CHECK 20: PARENT 20,10: TOP 20,165: LEFT 20,10: WIDTH 20,180
CAPTION 20,"Légendes (nom du fichier)"
CHECK 21: PARENT 21,10: TOP 21,TOP(20)+20: LEFT 21,10: WIDTH 21,180
CAPTION 21,"Titre général de la page :"
EDIT 22: PARENT 22,10: TOP 22,TOP(21)+17: LEFT 22,5: WIDTH 22,WIDTH(10)-10
CHECK 23: PARENT 23,10: TOP 23,TOP(22)+28: LEFT 23,10: WIDTH 23,180
CAPTION 23,"Fichier de sortie :"
EDIT 24: PARENT 24,10: TOP 24,TOP(23)+15: LEFT 24,5: WIDTH 24,WIDTH(10)-10
TEXT 24,fr$: ON_CLICK 24,Chs

BUTTON 40: PARENT 40,10: TOP 40,275: LEFT 40,80: CAPTION 40,"Exec": ON_CLICK 40,Exec
GOSUB Caldpi
ON_CHANGE 12,Caldpi: ON_CHANGE 15,Caldpi: ON_CHANGE 19,Caldpi
OPEN_DIALOG 98
SAVE_DIALOG 99
END
' ==============================================================================
Chr:
r$ = FILE_NAME$(98)
IF LEN(r$) < 4 THEN RETURN
FOR i% = LEN(r$) TO 1 STEP -1
    IF MID$(r$, i%, 1) = "\" THEN EXIT_FOR
NEXT i%
r$ = LEFT$(r$, i%-1)
DIR_CHANGE r$
f$ = FILE_FIND_FIRST$
IF f$ = "_" THEN RETURN
IF LEFT$(f$,1) <> "." THEN ITEM_ADD 4, f$
f$ = FILE_FIND_NEXT$
WHILE f$<>"_"
    IF LEFT$(f$,1) <> "." THEN ITEM_ADD 4, f$
    f$ = FILE_FIND_NEXT$
END_WHILE
CAPTION 2,"Total:  "+STR$(COUNT(4))+" images."
RETURN
' ==============================================================================
Chs:
r$ = FILE_NAME$(99)
IF LEN(r$) < 4 THEN RETURN
fr$ = r$: TEXT 24, fr$
RETURN
' ==============================================================================
Sel:
ITEM_ADD 8,ITEM_INDEX$(4)
CAPTION 6,"Sélect:  "+STR$(COUNT(8))
RETURN
' ==============================================================================
Seltout:
FOR i% = 1 TO COUNT(4)
    ITEM_ADD 8,ITEM_READ$(4,i%)
NEXT i%
CAPTION 6,"Sélect:  "+STR$(COUNT(8))
RETURN
' ==============================================================================
Desel:
ITEM_DELETE 8,ITEM_INDEX(8)
CAPTION 6,"Sélect:  "+STR$(COUNT(8))
RETURN
' ==============================================================================
Suptout:
CLEAR 8
CAPTION 6,"Sélect:  "+STR$(COUNT(8))
RETURN
' ==============================================================================
Exec:
IF COUNT(8) = 0 THEN RETURN
FILE_OPEN_WRITE 1, fl$
FOR i% = 1 TO COUNT(8)
    FILE_WRITELN 1,r$ + "\" + ITEM_READ$(8, i%)
NEXT i%
FILE_CLOSE 1
nc% = POSITION(12)
wc% = POSITION(19)
ec% = POSITION(15)
er% = POSITION(17)
ra = 4/3: IF CHECKED(32) = 1 THEN ra = 3/2
nom% = 0: IF CHECKED(20) = 1 THEN nom% = 1
titre$ = "": IF CHECKED(21) = 1 THEN titre$ = TEXT$(22)
fr$ = "": IF CHECKED(23) = 1 THEN fr$ = TEXT$(24)
ImgContact(nc%,wc%,ra,ec%,er%,nom%,titre$,fl$,fr$)
' Voir le résultat, et impression éventuelle sous IrfanView:
EXECUTE_WAIT "C:\Progra~2\Irfanv~1\i_view32.exe /clippaste"
RETURN
' ==============================================================================
Caldpi:
nc% = POSITION(12)
wc% = POSITION(19)
ec% = POSITION(15)
lt% = nc%*wc% + (nc%-1)*ec%: ' largeur totale du résultat en pixels
dpi% = (25.4*lt%)/200: ' dpi à l'impression, sur une largeur de 200 mm (A4)
TEXT 26,STR$(dpi%)
RETURN
' ==============================================================================
SUB ImgContact(nc%,wc%,ra,ec%,er%,nom%,titre$,fl$,fr$)
' Création d'une planche contact d'images, nc% colonnes de largeur wc%
' espacement colonnes ec%, rangées er%.
' ra = rapport de proportion des images (4/3 ou 3/2)
' Si nom% = 1: légende des images, titre$ = titre général de la planche (ou "")
' Liste des images (chemins) dans le fichier fl$, résultat dans fr$ (ou dans le
' clipboard si fr$ = "")
DIM_LOCAL i_imv$, i_imf$, i_np%, i_nd%, i_ni%, ii%, ij%, ik%, iw%, ih%, ia$, xco%, yco%
i_imv$ = "C:\Progra~2\Irfanv~1\i_view32.exe ": ' <=== chemin de IrfanView ======
i_imf$ = "C:\TEMP\iitmp.bmp"
i_np% = 1000: WHILE OBJECT_EXISTS(i_np%)=1: i_np%=i_np%+1: END_WHILE
PICTURE i_np%: LEFT i_np%,-5000: WIDTH i_np%,wc%*nc%+(nc%-1)*ec%: HIDE i_np%
2D_TARGET_IS i_np%: PRINT_TARGET_IS i_np%: FONT_NAME i_np%,"Arial"
FONT_SIZE i_np%,10: IF wc%>200 THEN FONT_SIZE i_np%,INT(wc%/20)
i_nd% = i_np%+1: WHILE OBJECT_EXISTS(i_nd%)=1: i_nd%=i_nd%+1: END_WHILE
DLIST i_nd%: FILE_LOAD i_nd%,fl$: ' liste des images
i_ni%=i_nd%+1: WHILE OBJECT_EXISTS(i_ni%)=1: i_ni%=i_ni%+1: END_WHILE
IMAGE i_ni%
ii% = INT(COUNT(i_nd%)/nc%): IF ii%<COUNT(i_nd%)/nc% THEN ii% = ii%+1
HEIGHT i_np%, ii%*(3*wc%/4 + er%)
IF titre$ <> "" THEN HEIGHT i_np%,HEIGHT(i_np%)+TEXT_HEIGHT(titre$,i_np%)+5
yco% = 0
IF titre$<>""
    PRINT_LOCATE (WIDTH(i_np%)-TEXT_WIDTH(titre$,i_np%))/2,2: PRINT titre$
    yco% = yco% + TEXT_HEIGHT(titre$,i_np%)+5
END_IF
FOR ii% = 1 TO COUNT(i_nd%) STEP nc%
    xco% = 0
    FOR ij% = ii% TO ii%+nc%-1
        IF ij% > COUNT(i_nd%) THEN EXIT_FOR
        EXECUTE_WAIT i_imv$+ITEM_READ$(i_nd%,ij%)+" /clipcopy /killmesoftly"
        CLIPBOARD_PASTE i_ni%: FILE_SAVE i_ni%,i_imf$
        FILEBIN_OPEN_READ 9,i_imf$: ' dimensions de l'image
            FILEBIN_POSITION 9,18: iw%=FILEBIN_READ(9)+256*FILEBIN_READ(9)
            FILEBIN_POSITION 9,22: ih%=FILEBIN_READ(9)+256*FILEBIN_READ(9)
        FILEBIN_CLOSE 9
        IF iw% > ih%
            ia$ = ITEM_READ$(i_nd%,ij%)+" /resize=("+STR$(wc%)+",0) /aspectratio"
            EXECUTE_WAIT i_imv$+ia$+"/resample /clipcopy /killmesoftly"
        ELSE
            ia$ = ITEM_READ$(i_nd%,ij%)+" /resize=(0,"+STR$(wc%)+") /aspectratio"
            EXECUTE_WAIT i_imv$+ia$+" /rotate_l /resample /clipcopy /killmesoftly"
        END_IF
        CLIPBOARD_PASTE i_ni%
        2D_IMAGE_PASTE i_ni%,xco%,yco%
        IF nom% = 1
            ia$ = ITEM_READ$(i_nd%,ij%): ' légende = nom du fichier (sans son chemin)
            FOR ik% = LEN(ia$) TO 1 STEP -1
                IF MID$(ia$, ik%, 1) = "\" THEN EXIT_FOR
            NEXT ik%
            PRINT_LOCATE xco%,yco%+wc%/ra
            PRINT MID$(ia$,ik%+1,50)
        END_IF
        xco% = xco%+wc%+ec%
    NEXT ij%
    yco% = yco% + wc%/ra + er%
NEXT ii%
CLIPBOARD_COPY i_np%: ' résultat dans le clipboard
IF fr$ <> ""
    EXECUTE_WAIT i_imv$+"/clippaste /convert="+fr$: ' fichier planche d'images résultat
END_IF
2D_TARGET_IS 0: PRINT_TARGET_IS 0
DELETE i_np%: DELETE i_nd%: DELETE i_ni%
FILE_DELETE i_imf$
END_SUB
' ==============================================================================
Edit 11/9 programme d'utilisation de la sub un peu étoffé...


Dernière édition par JL35 le Jeu 12 Sep 2013 - 15:54, édité 1 fois
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
JL35



Nombre de messages : 5920
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Planche-contact   Mer 11 Sep 2013 - 23:45

Comme je vois que ma petite sub a soulevé l'enthousiasme général et unanime (Very Happy ), du coup j'ai développé le programme d'appel pour en faire un générateur de planches-contact à part entière.

Utilisation:
- définir le répertoire d'origine des images (-> affichage du contenu)
- sélectionner les images à incorporer (bouton 'Tout' pour toutes), elles s'affichent à droite. On peut désélectionner une ou des images en cliquant sur leur nom à droite (ou tout: bouton 'Raz')
- choisir le nombre de colonnes d'images de la planche
- choisir la largeur en pixels des images dans la planche, ce qui conditionnera leur définition (le dpi indiqué est calculé pour affichage dans une feuille A4)
- choisir la proportion largeur/hauteur des images: en général 4:3 ou 3:2 pour un APN.
- choisir l'écartement en pixels entre colonnes et entre rangées. Pour les rangées, tenir compte de la légende éventuelle.
- Si 'Légendes' est coché: affichage du nom de fichier sous les images correspondantes.
- On peut afficher un titre général de la page.
- On peut ou non définir un fichier de sortie. C'est nécessaire pour archivage ou envoi par mail éventuel, et inutile si c'est seulement pour impression immédiate (le résultat est passé à IrfanView dans le clipboard).

Il faudra en général plusieurs essais pour définir une répartition harmonieuse des images, en changeant un ou des paramètres à chaque fois, avant exploitation. Surtout si c'est pour impression.

Pour l'impression, une fois dans IrfanView, il faut utiliser la fonction d'impression et fixer les paramètres d'impression: respecter les proportions de l'image, fixer ou non des marge, puis fixer les paramètres dans l'imprimante: format et type de papier (photo par exemple), qualité, etc.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5849
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Planche-contact   Jeu 12 Sep 2013 - 11:19

Désolé JL35, je ne crois pas avoir réinstallé Infraview et je n'ai pas pris le temps de tester.

Je suis suis sûr que ce programme est intéressant et je pense que je pourrais regarder ce weekend. Je manque trop de temps en ce moment pour faire du Panoramic sérieusement...
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
JL35



Nombre de messages : 5920
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Planche-contact   Jeu 12 Sep 2013 - 13:02

Y'a pas le feu Jicehel, je joue sur le long terme !
L'embêtant, c'est vrai, c'est qu'il faut avoir irfanview installé, mais toutes ces tâches sont impossibles à faire en panoramic pur, et le grand intérêt de irfanview c'est de pouvoir justement faire tout un tas d'opérations sur images de manière transparente depuis un programme en panoramic.

Maintenant je dépose le programme ici comme ça, sans arrière-pensée, et sans attendre des clameurs d'enthousiasme, c'est simplement que je pense que ça peut intéresser certains, et que ceux qui sont intéressés, justement, ne se manifestent pas forcément, c'est pas grave !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5849
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Planche-contact   Jeu 12 Sep 2013 - 14:49

^^ JL35. Tu fais preuve de beaucoup de sagesse. Merci pour ce partage
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 7961
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Jeu 12 Sep 2013 - 14:54



@JL35,

cela n' est il pas possible avec la dll de Klaus ?...
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
JL35



Nombre de messages : 5920
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Planche-contact   Jeu 12 Sep 2013 - 15:47

Bonjour ygeronimi,
certes, la dll de Klaus permet de faire beaucoup de choses, mais je ne pense pas qu'on puisse tout faire avec sur les images, notamment les impressions ne sont pas simples à mettre en oeuvre.
Et puis c'est toujours un programme externe à panoramic, mais j'avoue que pour cette application-là je n'ai pas étudié le problème sous l'aspect KGF.dll, par paresse en partie, parce que j'ai l'habitude de faire appel à irfanview depuis bien longtemps pour toutes les manipulations d'images, du fait qu'il est très simple à utiliser en ligne de commande (donc avec un execute_wait), avec en particulier le passage d'images par le clipboard.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 7961
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Jeu 12 Sep 2013 - 16:13

Je n' ai pas ré-installé irfanview et je ne maîtrise pas la bête en ligne de commande
ou plutôt je ne maîtrise pas les lignes de commande Embarassed
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
JL35



Nombre de messages : 5920
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Planche-contact   Jeu 12 Sep 2013 - 16:40

Alors là, mon ami ygeronimi, tu te prives de beaucoup de possibilités, à mon avis, tout un tas de choses que tu peux faire avec un simple Execute sous panoramic.
Pour commencer de toutes les fonctions ms-dos.

Si tu as 5 minutes, pas plus, fais simplement l'expérience suivante:
Tape [touche Windows]/R (pour Run), et dans la fenêtre qui apparaît, tape cmd (pour command)
Tu te retrouves avec une fenêtre noire, qui accepte justement toutes les commandes (équivalent à ligne de commande).
Dans cette fenêtre, tape simplement help , ça te donne la liste de toutes les commandes ms-dos avec une explication succincte.
Toutes ces commandes peuvent être appelées depuis panoramic avec un simple execute_wait, avec des paramètres éventuels.
(si tu veux des détails sur une de ces commandes en particulier, paramètres, etc., tu tapes help [nomdelacommande]
Pour quitter cette fenêtre noire (sortir du mode commande), tu tapes simplement exit

Ce n'est qu'un exemple, mais tu peux également appeler de cette façon tout un tas de logiciels externes (ceux qui sont prévus pour ça).
Je reprends l'exemple de IrfanView: dans l'aide de irfanview il y a un paragraphe qui contient toutes les fonctions appelables en ligne de commande, avec leurs paramètres.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 7961
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Jeu 12 Sep 2013 - 17:00

Ben, j' en ai appris beaucoup en lisant tes quelques lignes. 

cheers Merci JL35 !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
JL35



Nombre de messages : 5920
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Planche-contact   Jeu 12 Sep 2013 - 17:25

Pas de quoi, c'est un plaisir !

Pour compléter (partiellement) ton éducation, si tu veux par exemple utiliser une fonctions ms-dos qui renvoie des résultat (comme la plupart), il faut récupérer ces résultats quelque part.

Un exemple tout simple, la fonction DIR, qui donne la liste des éléments contenus dans un répertoire (avec tout un tas de paramètres possibles, voir ci-dessus pour la liste), deux possibilités (répertoire Monrep):
rep$ = "C:\Monrep"
1)
Code:
EXECUTE_WAIT "CMD.exe /C DIR " + rep$ + " >Monfich.txt"
-> la liste résultat sera dans le fichier texte Monfich.txt
2)
Code:

EXECUTE_WAIT "CMD.exe /C DIR " + rep$ + " | clip"
-> la liste résultat sera dans le clipboard (pour 'coller' dans un Memo, par exemple)

Je dois quand même signaler un petit inconvénient, dans le cas de l'appel de fonctions ms-dos: pendant le temps de l'exécution de la fonction, il y a brève apparition d'une fenêtre noire d'exécution. Mais il y a moyen d'inhiber cette apparition (j'ai fait une sub pour ça).
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 4988
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Planche-contact   Ven 13 Sep 2013 - 19:23

Bon ben sur ce coup là je suis comme tous le monde. il faut que je réinstalle IrfanView.

Je te promet que je vais faire un essai la semaine prochaine car pour le moment je ne peux accéder à mon ordi que quelques minutes par jour. J'ai du monde plein la cabane.

A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
JL35



Nombre de messages : 5920
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Planche-contact   Sam 14 Sep 2013 - 10:23

Merci Jean Claude,

Pour le traitement des images, IrfanView est le plus simple à utiliser en ligne de commande, mais il y en a d'autres, bien plus puissants avec plein d'autres possibilités et tout aussi gratuits: nconvert, imagemagick..., mais là ça devient compliqué.

Je ne vais pas être trop disponible dans les jours qui viennent (une bonne dizaine de jours, minimum, une grande balade dans le midi avec des copains Very Happy ), alors pour les réactions éventuelles il faudra attendre un peu, mais bon, vous pouvez aussi bricoler le programme vous-mêmes, c'est ouvert !

Bonne journée à tous, pour moi ça va être un peu chargé (un anniversaire de mariage...).

La ligne de commande mériterait sûrement un petit article dans le mag, on verra ça plus tard.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 4988
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Planche-contact   Sam 14 Sep 2013 - 12:12

Pour ta ballade dans le midi si c'est dans le var tu as soleil garanti.
sunny sunny sunny sunny sunny sunny sunny sunny 
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Contenu sponsorisé




MessageSujet: Re: Planche-contact   

Revenir en haut Aller en bas
 
Planche-contact
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 1 sur 1

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC 32 bits :: Vos sources, vos utilitaires à partager-
Sauter vers: