FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» Synedit Parameters
par Yannick Aujourd'hui à 0:27

» Code à vérifier SVP (Oups ! résolu)
par Jean Claude Hier à 21:16

» Compilateur FBPano
par jean_debord Hier à 9:56

» Bienvenue à Virtualalan !
par UltraVox Hier à 9:18

» Concours de Morpions
par jjn4 Hier à 0:04

» ShortName$(F) [Cloturé]
par papydall Mer 21 Juin 2017 - 16:19

» Remplacer espace par tiret dans noms des dossiers / fichiers
par papydall Mer 21 Juin 2017 - 15:27

» Menu personalisé avec icones et menu contextuel
par Laurent (Minibug) Mer 21 Juin 2017 - 12:44

» La liste des choses à faire ...
par Jack Mar 20 Juin 2017 - 22:49

» Quoi de neuf à propos de Goric 3D ? (@Jack)
par UltraVox Mar 20 Juin 2017 - 21:06

» Nom court et anti fenetre dos
par silverman Mar 20 Juin 2017 - 18:31

» Ludothèque Panoramic
par jjn4 Mar 20 Juin 2017 - 18:09

» Proposition à la communauté
par Yannick Mar 20 Juin 2017 - 15:02

» >199
par maelilou Mar 20 Juin 2017 - 14:13

» NUMBER_FOCUS
par Yannick Lun 19 Juin 2017 - 15:25

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Juin 2017
LunMarMerJeuVenSamDim
   1234
567891011
12131415161718
19202122232425
2627282930  
CalendrierCalendrier

Partagez | 
 

 Un petit outil pour les sprites

Voir le sujet précédent Voir le sujet suivant Aller en bas 
AuteurMessage
Jicehel

avatar

Nombre de messages : 5837
Age : 44
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Un petit outil pour les sprites   Jeu 28 Mar 2013 - 11:58

Je vous donne un petit outil que j'ai fait pour pouvoir avoir des sprites pour Panoramic à partir d'une image.
J'avais déjà fait un petit utilitaire comme ça il y a quelques mois mais je l'ai un peu relooké.
Les images sont disponibles dans le répertoire tools de cette archive: barbarian.zip

Le reste du répertoire sert pour le jeu que je viens de commencer pour lequel j'ai créé l'outil (un remake de barbarian, un vieux jeux d'il y a 25 ans ...), mais bon pour le moment, ce n'est qu'un début avec un perso qui fait quelques mouvements tout seul.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5384
Age : 66
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Un petit outil pour les sprites   Jeu 28 Mar 2013 - 20:17

Ce Barbarian "fait quelques mouvements tout seul", j’espère que dans un proche avenir il en fera avec d’autres ; car comme début c’est PROMETTEUR !
Merci Jicehel
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
pascal10000

avatar

Nombre de messages : 494
Localisation : Troyes
Date d'inscription : 05/02/2011

MessageSujet: Re: Un petit outil pour les sprites   Jeu 28 Mar 2013 - 22:21

Jicehel
il est bizarre ton lien pour télécharger il ouvre un nouvel onglet

et on click alors qu'il faut une petite manœuvre pour faire le
lien direct

moi personnellement je ça

1 je fait fait le téléchargement du fichier souhaité et ensuite je fait une pause et là

2 je repère le fichier en cliquant dessus avec le bouton droit de la sourie
3 tu copie l'adresse complète

et ensuite je le colle a l'option de lurl de panoramique et le tour est joué

barbabian.zip

bonne soiré
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5837
Age : 44
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Un petit outil pour les sprites   Jeu 28 Mar 2013 - 22:26

Merci pascal1000, j'avais directement utilisé le lien généré par Microsoft, c'est la première fois que je l'utilisais. L'avantage c'est que vous n'avez pas à vous connecter pour récupérer le fichier contrairement au webdav. C'est plus pratique, je pense pour les versions temporaires comme celle là, je pense. J'essayerais ta méthode pour la prochaine fois en attendant les autres peuvent utiliser ton lien pour récupérer le zip en direct Wink
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
pascal10000

avatar

Nombre de messages : 494
Localisation : Troyes
Date d'inscription : 05/02/2011

MessageSujet: Re: Un petit outil pour les sprites   Jeu 28 Mar 2013 - 22:34

de rien! j'arrive tjr a trouvé des petites magouilles comme celle là
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5837
Age : 44
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Un petit outil pour les sprites   Lun 29 Avr 2013 - 1:20

J'ai remanié un peu le code pour offrir plus de possibilités.
Je ne suis pas satisfait de la fonction pipette si quelqu'un peu trouver une astuce pour que l'on voit mieux l'endroit où l'on prend la couleur, je suis preneur.
Dans quelques jours, je voudrais avoir ajouté: le remplacement d'une couleur par une autre comme le faisait le programme initial (pas compliqué, j'ai juste à rajouter ce que j'avais fait, mais je n'ai pas eu le temps ce soir)
Après, je voudrais pouvoir récupérer une liste de couleur dans un carré, afficher les couleurs trouvées sous forme de codes hexas et de prévisu avec possibilité de remplacer ou non la couleur
Après je voudrais rajouter le traitement par lot comme avait fait JL35 pour le traitement d'images d'un répertoire pour pouvoir appliquer une modif à un ensemble de fichiers.
Bon en attendant, voici le début du nouveau code de l'utilitaire (il n'est pas finalisé, on peut charger et appliquer une série de fonctions que je pense pratique pour les sprites).
Code:
REM -------------------------------------------------------------
REM ---                                                      ---
REM ---            Sprites tool en Panoramic v1.0            ---
REM ---                                                      ---
REM -------------------------------------------------------------
REM
REM Permet de:
REM      - Remplacer les couleurs 0;0;0 des images par des 0;0;1
REM      - Remplacer une couleur de fond par des 0;0;0
REM      - Ajuster et déplacer un sprite en hauteur ou largeur
REM

LABEL Charger,Quitter,Sauver,Couleur,aff_palette,aff_loupe
LABEL AfficherZoom,Pipette,Selectionne_couleur,Mire,Rotation90G,Rotation90D
LABEL MirroirH,MirroirV
' ,Remplace,Echange
' LABEL CopieCouleurARemplacer,CopieCouleurDeRemplacement
' LABEL R_NOIR,R_ROSE,R2_FAUXNOIR,R2_NOIR

DIM D$ : D$ = "C:\Panoramic-Init\sources\Barbarian-jc\"
DIM Ligne,Col,C1%,C2%,C3%,S1$,S2$,S3$,Modif%,hnd_edit%
DIM Charger%,Sauver%
DIM wco%,hco%,wct%,hct%,ech%,ecv%,ra%,ga%,ba%,i%,j%,k%,l%,x%,y%
DIM affich_palette%,affich_zoom%
DIM Menu%,no%,no2%,bpalette%,bzoom%,res%,hnd_button%

DLL_ON D$+"KGF.dll"
HEIGHT 0,300:WIDTH 0,400:LEFT 0,(screen_x-211)/2
CAPTION 0,"SPRITES TOOLS"

IMAGE 2
BUTTON 3: LEFT 3,-1000 : CAPTION 3,"SOURIS SUR LE SPRITE"
hnd_button% = HANDLE(3): ON_ClICK 3,AfficherZoom

' Trace la palette de couleurs html, de &000000 à &FFFFFF, pas de &33
' &000000, &000033, &000066, &000099, &0000CC, &0000FF, &003300, &003333, etc.
wco% = 15: hco% = 15: ech% = 0: ecv% = 0
wct% = 6*(wco%+ech%): hct% = 36*(hco%+ecv%)
affich_palette%=0:affich_zoom%=0

FORM 400: HIDE 400 : TOP 400,400 : LEFT 400,400 : BORDER_SMALL 400
HEIGHT 400,135 : WIDTH 400,118 : CAPTION 400, "ZOOM"
PICTURE 401 : PARENT 401,400 : WIDTH 401,100 : HEIGHT 401,100

FORM 300: HIDE 300 : TOP 300, 0: LEFT 300, 0: BORDER_SMALL 300
CAPTION 300, " - PALETTE -"
WIDTH 300, wct%+16: HEIGHT 300, hct%+34
PICTURE 301: PARENT 301, 300: WIDTH 301, wct%: HEIGHT 301,hct%
2D_TARGET_IS 301
ra% = 0: ga% = 0: ba% = 0
FOR j% = 0 TO 35
    y% = j%*(hco%+ecv%)
    FOR i% = 0 TO 5
        x% = i%*(wco%+ech%)
        2D_FILL_COLOR ra%,ga%,ba%
        2D_RECTANGLE x%,y%,x%+wco%-1,y%+hco%-1
        ba% = ba% + HEX("33")
        IF ba% > 255
            ba% = 0: ga% = ga% + HEX("33")
            IF ga% > 255
                ga% = 0: ra% = ra% + HEX("33")
            END_IF
        END_IF
    NEXT i%
NEXT j%
ON_CLICK 301, Couleur
CONTAINER 310 : HIDE 310 : PARENT 310,300 :WIDTH 310,200 : HEIGHT 310, 80
TOP 310,5 : LEFT 310,6*(wco%+ech%)+5
ALPHA 311 : PARENT 311,310 : WIDTH 311, 200 : TOP 311, 7: LEFT 311,3
FONT_BOLD 311 : FONT_COLOR 311,50,50,200 : CAPTION 311,"  COULEUR SELECTIONNEE"
ALPHA 316 : PARENT 316,310 : WIDTH 316,58 : TOP 316,27 : LEFT 316,6
FONT_COLOR 316,255,0,0 : CAPTION 316,"ROUGE"
ALPHA 317 : PARENT 317,310 : WIDTH 317,58 : TOP 317,27 : LEFT 317,70
FONT_COLOR 317,0,200,0 : CAPTION 317,"VERT"
ALPHA 318 : PARENT 318,310 : WIDTH 318,58 : TOP 318,27 : LEFT 318,134
FONT_COLOR 318,0,0,255 : CAPTION 318,"BLEU"
EDIT 319 : PARENT 319,310 : WIDTH 319,58 : TOP 319,47 : LEFT 319,6 : TEXT 319,"0"
EDIT 320 : PARENT 320,310 : WIDTH 320,58 : TOP 320,47 : LEFT 320,70 : TEXT 320,"0"
EDIT 321 : PARENT 321,310 : WIDTH 321,58 : TOP 321,47 : LEFT 321,134 : TEXT 321,"0"
ALPHA 302 : PARENT 302,300 : HIDE 302 : WIDTH 302,58 : TOP 302,92 : LEFT 302,6*(wco%+ech%)+10
FONT_BOLD 302 : CAPTION 302,"APPERCU"
PICTURE 303 : HIDE 303 : PARENT 303,300 : WIDTH 303,60 : TOP 303,90 : LEFT 303,6*(wco%+ech%)+74
HEIGHT 303,18

' Menu principal
no%=100 : main_menu no% : Menu% = no%
' Sous menu fichier
no% = no% + 1 : sub_menu no% : parent no%,Menu% : no2% = no% : caption no%,"Fichier"
no% = no% + 1 : sub_menu no% : parent no%,no2% : Charger% = no%
caption no%,"Charger": on_click no%,charger
no% = no% + 1 : sub_menu no% : parent no%,no2% : caption no%,"Enregistrer"
inactive no% : Sauver% = no% : on_click no%,sauver
no% = no% + 1 : sub_menu no% : parent no%,no2% : caption no%,"-"
no% = no% + 1 : sub_menu no% : parent no%,no2% : caption no%,"Quitter": on_click no%,quitter
' Sous menu outils
no% = no% + 1 : sub_menu no% : parent no%,Menu% : no2% = no% : caption no%,"Outils"
no% = no% + 1 : sub_menu no% : parent no%,no2% : caption no%,"Pipette": on_click no%,pipette
no% = no% + 1 : sub_menu no% : parent no%,no2% : caption no%,"Mire de test": on_click no%,mire
no% = no% + 1 : sub_menu no% : parent no%,no2% : caption no%,"Rotation à gauche de 90°": on_click no%,rotation90G
no% = no% + 1 : sub_menu no% : parent no%,no2% : caption no%,"Rotation à droite de 90°": on_click no%,rotation90D
no% = no% + 1 : sub_menu no% : parent no%,no2% : caption no%,"Miroir Horizontal": on_click no%,MirroirH
no% = no% + 1 : sub_menu no% : parent no%,no2% : caption no%,"Miroir Vertical": on_click no%,MirroirV

' Sous menu affichage
no% = no% + 1 : sub_menu no% : parent no%,Menu% : no2% = no% : caption no%,"  Afficher"
no% = no% + 1 : sub_menu no% : parent no%,no2% : bpalette% = no%
caption no%,"  Afficher Palette": on_click no%,aff_palette
no% = no% + 1 : sub_menu no% : parent no%,no2% : bzoom% = no%
caption no%,"  Afficher Zoom": on_click no%,aff_loupe

PICTURE 4: LEFT 4,70 : EDIT 1234 : HIDE 1234 : hnd_edit% = HANDLE(1234)
res% = dll_call5("ClickDefineRect",1,70,0,WIDTH(4),HEIGHT(4))
PICTURE 5 : HIDE 5
END

aff_palette:
  affich_palette%=1-affich_palette%
  IF affich_palette%=1
    CAPTION bpalette%,"X Afficher Palette"
    SHOW 300 : ON_CLOSE 300,aff_palette
  ELSE
    CAPTION bpalette%,"  Afficher Palette"
    HIDE 300 : OFF_CLOSE 300
  END_IF
RETURN

Pipette:
CURSOR_CROSS 4
ON_CLICK 4,Selectionne_couleur
RETURN

Rotation90G:
CLIPBOARD_COPY 4
res% = dll_call0("LoadPicture")
res% = dll_call0("RotateM90")
res% = dll_call0("SavePicture")
i%=HEIGHT(4):HEIGHT 4,WIDTH(4) : WIDTH 4,i%
CLIPBOARD_PASTE 4
RETURN

Rotation90D:
CLIPBOARD_COPY 4
res% = dll_call0("LoadPicture")
res% = dll_call0("Rotate90")
res% = dll_call0("SavePicture")
i%=HEIGHT(4):HEIGHT 4,WIDTH(4) : WIDTH 4,i%
CLIPBOARD_PASTE 4
RETURN

MirroirH:
WIDTH 5,WIDTH(4):HEIGHT 5,HEIGHT(4)
2D_TARGET_IS 5
FOR i%=1 TO WIDTH(4)
  FOR j%=1 TO HEIGHT(4)
      ra% = COLOR_PIXEL_RED(4,i%,j%)
      ga% = COLOR_PIXEL_GREEN(4,i%,j%)
      ba% = COLOR_PIXEL_BLUE(4,i%,j%)
      2D_PEN_COLOR ra%,ga%,ba% : 2D_POINT WIDTH(4)-(i%-1),j%
  NEXT j%
NEXT i%
2D_IMAGE_COPY 2,0,0,WIDTH(4),HEIGHT(4)
2D_TARGET_IS 4: 2D_IMAGE_PASTE 2,0,0
RETURN

MirroirV:
WIDTH 5,WIDTH(4):HEIGHT 5,HEIGHT(4)
2D_TARGET_IS 5
FOR i%=1 TO WIDTH(4)
  FOR j%=1 TO HEIGHT(4)
      ra% = COLOR_PIXEL_RED(4,i%,j%)
      ga% = COLOR_PIXEL_GREEN(4,i%,j%)
      ba% = COLOR_PIXEL_BLUE(4,i%,j%)
      2D_PEN_COLOR ra%,ga%,ba% : 2D_POINT i%,HEIGHT(4)-(j%-1)
  NEXT j%
NEXT i%
2D_IMAGE_COPY 2,0,0,WIDTH(4),HEIGHT(4)
2D_TARGET_IS 4: 2D_IMAGE_PASTE 2,0,0
RETURN

Selectionne_couleur:
CURSOR_DEFAULT 4
OFF_CLICK 4
col = MOUSE_X_POSITION(4) : ligne = MOUSE_Y_POSITION(4)
TEXT 319,COLOR_PIXEL_RED(4,ligne,col)
TEXT 320,COLOR_PIXEL_GREEN(4,ligne,col)
TEXT 321,COLOR_PIXEL_BLUE(4,ligne,col)
COLOR 303,VAL(TEXT$(319)),VAL(TEXT$(320)),VAL(TEXT$(321))
RETURN

AfficherZoom:
OFF_CLICK 3
' CAPTION 0,"Souris en : " + STR$(MOUSE_X_POSITION(4)) + ";" +STR$(MOUSE_Y_POSITION(4))
IF affich_zoom%=1
  X% = MOUSE_X_POSITION(4): IF X% > (WIDTH(4)-10)  THEN X% = WIDTH(4)  - 10
  Y% = MOUSE_Y_POSITION(4): IF Y% > (HEIGHT(4)-10) THEN Y% = HEIGHT(4) - 10
  2D_TARGET_IS 401
  FOR i% = 9 TO 0 STEP -1
    FOR j% = 9 TO 0 STEP -1
      ra% = COLOR_PIXEL_RED(4,x%+j%,y%+i%)
      ga% = COLOR_PIXEL_GREEN(4,x%+j%,y%+i%)
      ba% = COLOR_PIXEL_BLUE(4,x%+j%,y%+i%)
      2D_FILL_COLOR ra%,ga%,ba% : 2D_PEN_COLOR ra%,ga%,ba%
      2D_RECTANGLE j%*10,i%*10,j%*10+9,i%*10+9
    NEXT j%
  NEXT i%
END_IF
ON_CLICK 3,AfficherZoom
RETURN

aff_loupe:
' définir un rectangle de numéro num% (de 1 à 200)
res% = dll_call2("ClickSetHook",handle(0),hnd_edit%)
res% = dll_call3("ClickSetLinkRect",hnd_button%,0-7,1)
affich_zoom%=1-affich_zoom%
  IF affich_zoom%=1
    CAPTION bzoom%,"X Afficher Zoom"
    SHOW 400 : ON_CLOSE 400,aff_loupe
  ELSE
    CAPTION bzoom%,"  Afficher Zoom"
    HIDE 400 : OFF_CLOSE 400
  END_IF
RETURN

Charger:
  OpenImg()
  WIDTH 4,res_x%:HEIGHT 4,res_y%: TOP 4,10
  2D_TARGET_IS 4 : 2D_IMAGE_PASTE 2,0,0
  CAPTION 0,"Edition du sprite : " + R_OpenImg$
  C1% = WIDTH(4)  : IF C1% <  60 THEN C1%= 60
  C2% = HEIGHT(4) : IF C2% < 100 THEN C2%=100
  HEIGHT 0,C2%+160 : WIDTH 0,C1%+306
  res% = dll_call5("ClickDefineRect",1,left(4),top(4),WIDTH(4),HEIGHT(4))
  Modif% = 0 : INACTIVE Sauver%
RETURN

Sauver:
  SaveImg()
  Modif%=0 : inactive Sauver%
RETURN

SUB SaveImg()
  FILE_SAVE 4,Img_File$
RETURN

Mire:
  2D_TARGET_IS 4
  k%=255/WIDTH(4) : l%=255/HEIGHT(4)
  FOR i%=1 TO WIDTH(4)
    FOR j%=1 TO HEIGHT(4)
      IF ODD(j%)=1
        C1%=j%*l%
      ELSE
        C1%=255-(j%*l%)
      END_IF
      IF ODD(i%)=1
        C2%=i%*k%
      ELSE
        C2%=255-(k%*i%)
      END_IF
      2D_PEN_COLOR C1%,C2%,RND(255) : 2D_POINT i%,j%
    NEXT j%
  NEXT i%
RETURN

SUB OpenImg()
  IF VARIABLE("R_OpenImg$") = 0 THEN DIM R_OpenImg$
  IF VARIABLE("Img_File$") = 0 THEN DIM Img_File$
  DIM_LOCAL OpenImg_res%,OpenImg_filter$:OpenImg_filter$="*.JPG;*.BMP;*.GIF;*.PNG;*.EMF;*.ICO;*.WMF"
  OPEN_DIALOG 1
  FILTER 1,"Fichiers images|"+OpenImg_filter$+"|Tous|*.*"
  Img_File$ = FILE_NAME$(1) : DELETE 1
  IF Img_File$ <> "_"
    IF INSTR(OpenImg_filter$,UPPER$(RIGHT$(Img_File$,4)))=0
      MESSAGE "Désolé mais ce format ("+LOWER$(RIGHT$(Img_type$,3))+")"+chr$(10)+"n'est pas pris en compte !"
    ELSE
      OpenImg_res%=DLL_CALL1("LoadAnyImageFile",adr(Img_File$))
      DimImg(): WIDTH 2,res_x% : HEIGHT 2,res_y%: CLIPBOARD_PASTE 2
      Rinstr(Img_File$,"\")
      R_OpenImg$ = RIGHT$(Img_File$,LEN(Img_File$)-rs_k%)
    END_IF
  END_IF
END_SUB

SUB Rinstr(ch$,sq$)
' recherche de sq$ dans ch$ à partir de la fin (~Instr inversé) -> rs_k%
IF VARIABLE("rs_k%") = 0 THEN DIM rs_k%
FOR rs_k% = LEN(ch$)-LEN(sq$)+1 TO 1 STEP -1
    IF MID$(ch$, rs_k%, LEN(sq$)) = sq$ THEN EXIT_FOR
NEXT rs_k%
END_SUB

SUB DimImg()
  IF VARIABLE("res_x%") = 0 THEN DIM res_x%,res_y%
  res_x% = DLL_CALL0("GetClipboardPictureWidth")
  res_y% = DLL_CALL0("GetClipboardPictureHeight")
END_SUB

Couleur:
  x% = MOUSE_X_POSITION(301): y% = MOUSE_Y_POSITION(301)
  ra% = COLOR_PIXEL_RED(301,x%,y%)
  ga% = COLOR_PIXEL_GREEN(301,x%,y%)
  ba% = COLOR_PIXEL_BLUE(301,x%,y%)
  wct% = 6*(wco%+ech%)+210 : WIDTH 300, wct%+16 : SHOW 310 : SHOW 302
  TEXT 319,STR$(ra%) :  TEXT 320,STR$(ga%):  TEXT 321,STR$(ba%)
  COLOR 303,ra%,ga%,ba% : SHOW 303
RETURN

Quitter:
  TIMER_OFF_ALL
  res% = dll_call1("ClickClearHook",handle(4))
  DLL_OFF
Terminate
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 7809
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Lun 29 Avr 2013 - 1:35

Je crois qu'il ne te reste plus qu'à faire une demande à Jack...

Cursor_Pipette .... Laughing


Edit : trêve de plaisanterie, tu peux mettre un petit picture qui prend la couleur de la position de la souris.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5837
Age : 44
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Un petit outil pour les sprites   Lun 29 Avr 2013 - 1:42

oui, tu as raison, ça serait simple et efficace. Quand je suis sur l'icone (merci Klaus pour la fonction), je l'affiche à gauche dans un rectangle et je met à jour en cas de déplacement. Je vais faire ça.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5384
Age : 66
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Un petit outil pour les sprites   Lun 29 Avr 2013 - 2:29

Quand je clique sur Quitter, j’obtiens un message d’erreur en ligne 310

Dans le menu ‘Outils’, il serait utile d’ajouter un sous-menu Annuler pour annuler la dernière modification.
Qu’en penses-tu ?
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Jicehel

avatar

Nombre de messages : 5837
Age : 44
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Un petit outil pour les sprites   Lun 29 Avr 2013 - 9:00

oui, tu as raison, je l'ajouterais. En fait pour le moment, j'applique normalement qu'une ou deux modifications sur mes sprites donc si je fais une betise, je rechargeais juste le sprite initial. Mais je le rajouterais
Pour l'erreur c'est corrigé, merci, le code à modifier est le suivant:
Code:
Quitter: 
  TIMER_OFF_ALL
  res% = dll_call1("ClickClearHook",handle(0))
  DLL_OFF
  TERMINER

Par contre quand je quitte, j'ai le message comme quoi Panoramic a cessé de fonctionner, mais je pense que le problème ne vien pas dû programme (j'ai bien dis je crois et si je me trompe, je prends l'explication voir la correction Wink )
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 7809
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Lun 29 Avr 2013 - 15:03

@ Jicehel,

Comme toi j' ai utilisé la fonction "clicksetrect" qui nécessite "clicksethook".
Comme toi j'ai eu ce message disgracieux.
Le problème venait du fait que je n'avais pas arrêter "clicksethook" par "clickclearhook" avant de fermer l'application.
De plus, si tu as plusieur "form" qui l'utilise tu dois faire pour chaque "form" avant le Dll_off

if object_exists(num_form%)=1
res% = dll_call1("ClickClearHook",hnd%)
end_if

car sinon, windows essaye de fermer un dll qui est encore en travail

Edit : Regardes la fonction quitter de "Mon Ecurie" et mets un "clickclearhook" en rem ou du moins la sub s'y rapportant et tu verras
que le phénomène se reproduit.
Et si ma mémmoire est bonne c'est toi qui m'avais fait remarqué ce bug... Laughing
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5837
Age : 44
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Un petit outil pour les sprites   Lun 29 Avr 2013 - 16:21

Oui Ygernomi, mais le problème là c'est que je le fais (dans le premier listing, il y avait une erreur mais j'ai corrigé avec un res% = dll_call1("ClickClearHook",handle(0)), mais j'ai toujours ce message non bloquant mais disgracieux comme tu les dis si bien Wink

Klaus, on oublie un truc ou on fait une erreur de manipulation ?
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 7809
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Lun 29 Avr 2013 - 19:23

@ Jicehel,

J'ai corrigé le "clickclearhook" du code posté au dessus et je n'ai plus ce message disgracieux.
Mais ce code n'est peut-être qu'une partie d'un autre...
Parfois, et je ne sais pourquoi, il faut fermer l'éditeur et le ré-ouvrir, recharger le source pour voir certains
message disparaître...
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5837
Age : 44
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Un petit outil pour les sprites   Lun 29 Avr 2013 - 19:31

Tu as raison ygeronimi, je m'en rappelle maintenant !! Quand on a eu le problème une fois, il faut fermer complètement. Je fais le test ce soir, mais je crois que tu as raison, ça me revient maintenant ... Merci.
Je teste ce soit et je te confirme.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 7809
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Lun 29 Avr 2013 - 19:43

Cela fait partie des mystères de l' éditeur... Laughing

Lorsque tu m'avais signalé ce message, cela faisait un moment que je n'avais pas fermer l'éditeur.
Lorsque les Panoramiciens chargeait le source, ils avaient le message et pas moi.
J'ai fermé l'éditeur pour dormir quelques heures et à la ré-ouverture affraid j'avais moi aussi ce message.
Et c'est à ce moment que j'ai pu voir d'où cela venait... Laughing
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5837
Age : 44
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Un petit outil pour les sprites   Lun 29 Avr 2013 - 22:20

Toujours le message après avoir relancé l'éditeur ...
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 7809
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Lun 29 Avr 2013 - 22:24

Il est récalcitrant celui là !!!
lol!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Laurent (Minibug)

avatar

Nombre de messages : 2340
Age : 50
Localisation : Vienne (86)
Date d'inscription : 10/02/2012

MessageSujet: Re: Un petit outil pour les sprites   Lun 29 Avr 2013 - 22:38

Bravo Jicehel pour ces petits programmes.

Moi aussi j'ai eu des problemes avec la dll KGF dans ton programme.
J'avais des erreurs a chaque ligne ou il y avait un appel a KGF.
Je l'ai rechargée directement sur le WEBDEV de klaus et tout est rentré dans l'ordre.

Peut être ta DLL a été altérée...


Rectification : toujours le message lorsqu'on quitte le programme mais en appliquant ta procedure ça fonctionne parfaitement chez moi.

Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5837
Age : 44
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Un petit outil pour les sprites   Lun 29 Avr 2013 - 23:02

C'était une bonne idée, mais malgrè tout j'ai toujours le message en fermant Panoramic ...
Bon tant pis, je verrais ça plus tard, ce n'est pas bloquant.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Contenu sponsorisé




MessageSujet: Re: Un petit outil pour les sprites   

Revenir en haut Aller en bas
 
Un petit outil pour les sprites
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» petit probleme pour afficher un image sur mon forum...
» Petit soucis pour une map monde des inscrit
» Petit soucis pour le nom de mon " nouveau " Forum
» [Logiciel]Outil pour minecraft
» Un cadre pour les avatars

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC 32 bits :: Vos sources, vos utilitaires à partager-
Sauter vers: