FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» I Love You
par JL35 Jeu 19 Oct 2017 - 16:25

» MARK_ON déclenche un événement ON_CLICK à la place de ...
par Jean Claude Mer 18 Oct 2017 - 18:08

» mise a jour calculatrice
par joeeee2017 Mer 18 Oct 2017 - 15:57

» [solved] 3D_LINE How to ?
par Jicehel Mer 18 Oct 2017 - 11:01

» Convertisseur de base 10 de 2 à 36
par gigi75 Mar 17 Oct 2017 - 18:49

» calculatrice avec touches movibles
par joeeee2017 Dim 15 Oct 2017 - 1:11

» CORTANA
par gigi75 Sam 14 Oct 2017 - 16:32

» Calculatrice
par Jean Claude Sam 14 Oct 2017 - 12:30

» Compilateur FBPano
par jean_debord Jeu 12 Oct 2017 - 9:53

» KGF_dll - nouvelles versions
par Klaus Mar 10 Oct 2017 - 18:49

» à propos de Panoramic_Editor [Résolu]
par Klaus Mar 10 Oct 2017 - 3:19

» Un petit "coucou" à tous les Panoramiciens !
par Jack Ven 6 Oct 2017 - 10:24

» Pourquoi le compilateur stagne
par mindstorm Mer 4 Oct 2017 - 20:38

» Panoramic ?
par Marc37 Mer 4 Oct 2017 - 0:39

» Premiers pas avec Arduino
par Marc37 Mer 4 Oct 2017 - 0:29

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Octobre 2017
LunMarMerJeuVenSamDim
      1
2345678
9101112131415
16171819202122
23242526272829
3031     
CalendrierCalendrier

Partagez | 
 

 Démo dédicacé à Papydall

Voir le sujet précédent Voir le sujet suivant Aller en bas 
Aller à la page : 1, 2  Suivant
AuteurMessage
Jicehel

avatar

Nombre de messages : 5858
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Démo dédicacé à Papydall   Dim 24 Fév 2013 - 22:47

Code:
' Démo ecrite par Jicehel sur une idée de Papydall
' pour tester le 2D_point...
'
Dim PosX , PosY ,Pos2X , Pos2Y , angle, couleur, sens
2d_pen_width 20 : ' ne fonctionne pas avec 2D_POINT
caption 0,"<CLICK> pour arrêter"
repeat
  PosX = 0 : PosY = 0 : couleur = 0 : sens = 0.5
  for angle = 0 to 360 step 0.3141
    PosX = PosX + Cos(angle / (360 / 50)) * 10 : PosY = PosY + Sin(angle / (360 / 150)) * 20
    2d_pen_color abs(Posx/3)+50,angle/ 3, 255 - couleur
    2d_poly_from  PosX + 280, PosY + 20 : 2d_poly_to PosX + 280, PosY + 20
    couleur = couleur + 1 * sens : if (couleur >= 255 or couleur <= 0) then  sens = 0 - sens
    if scancode <>0 then exit_for
    wait 3
  next angle
until scancode <> 0
terminate
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
JL35



Nombre de messages : 5953
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: Démo dédicacé à Papydall   Dim 24 Fév 2013 - 23:42

Et ça change de couleur en plus ! joli Jicehel (pas toi, la figure... enfin, je sais pas finalement Very Happy )
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5546
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Démo dédicacé à Papydall   Lun 25 Fév 2013 - 2:12

Merci Jicehel.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
papydall

avatar

Nombre de messages : 5546
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Démo dédicacé à Papydall   Mer 27 Fév 2013 - 3:35

@Jicehel
Voici un papillon (coloré à ma façon) que tu peux le rendre plus joli en le colorant à ta guise.

Code:
' papillon.bas par Papydall
dim x,y,rho,theta,pi,xc,yc
full_space 0 : xc = width(0)/2 : yc = height(0)/2
caption 0,"<CLICK> pour arrêter ce joli Papillon"
pi = 4*atn(1) : theta = 0-10*pi : color 0,0,0,0 : cls : 2d_pen_color 0,0,0
rho = exp(sin(theta))-2*cos(4*theta)+power(sin(theta/12),5)
x = cos(theta)+0.5*cos(7*theta)+0.333*cos(pi/2 -17*theta)
y = sin(theta)+0.5*sin(7*theta)+0.333*sin(pi/2 -17*theta)
x =rho*cos(theta) : y = rho*sin(theta) : 2d_poly_from xc+100*x,yc-100*y
repeat
  2d_pen_color rnd(255),rnd(255),rnd(255)
  for theta = 0-10*pi to 10*pi step pi/180
      rho = exp(sin(theta))-2*cos(4*theta)+power(sin(theta/12),5)
      x = cos(theta)+0.5*cos(7*theta)+0.333*cos(pi/2 -17*theta)
      y = sin(theta)+0.5*sin(7*theta)+0.333*sin(pi/2 -17*theta)
      x =rho*cos(theta) : y = rho*sin(theta) : 2d_poly_to xc+100*x,yc-100*y
  next theta
until scancode <> 0
terminate
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Yannick

avatar

Nombre de messages : 7994
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: RE   Mer 27 Fév 2013 - 4:29

Qu' il est joli ce papillon !!!....

Bravo Papydall !!!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5858
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Démo dédicacé à Papydall   Mer 27 Fév 2013 - 4:33

Bon il est temps que j'aile me coucher.
Ma colorisation avant:
Code:
' papillon.bas par Papydall
dim x,y,rho,theta,pi,xc,yc, m
full_space 0 : xc = width(0)/2 : yc = height(0)/2
caption 0,"<CLICK> pour arrêter ce joli Papillon"
2d_pen_width 10
pi = 4*atn(1) : theta = 0-10*pi : color 0,0,0,0 : cls : 2d_pen_color 0,0,0
rho = exp(sin(theta))-2*cos(4*theta)+power(sin(theta/12),5)
x = cos(theta)+0.5*cos(7*theta)+0.333*cos(pi/2 -17*theta)
y = sin(theta)+0.5*sin(7*theta)+0.333*sin(pi/2 -17*theta)
x =rho*cos(theta) : y = rho*sin(theta) : 2d_poly_from xc+100*x,yc-100*y
m =100
repeat
  for theta = 0-2*pi to 2*pi step pi/180
      rho = exp(sin(theta))-2*cos(4*theta)+power(sin(theta/12),5)
      x = cos(theta)+0.5*cos(7*theta)+0.333*cos(pi/2 -17*theta)
      y = sin(theta)+0.5*sin(7*theta)+0.333*sin(pi/2 -17*theta)
      x =rho*cos(theta) : y = rho*sin(theta)
      2d_pen_color abs(x)*75,abs(y)*75,50
      2d_poly_to xc+m*x,yc-m*y
  next theta
  m = m - 2
until scancode <> 0 or m < 35
end
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5546
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Démo dédicacé à Papydall   Jeu 28 Fév 2013 - 4:00

Encore un fractal !

Code:
' **********************    Fractal.bas par Papydall    ***********************
Run()
terminate
' ******************************************************************************
SUB Run()
    DIM  xmax,ymax,tcmax,cx,cy,sa,sav,sb,sc
    full_space 0 : color 0,0,0,0
    caption 0,"<CLICK> pour arrêter"
    xmax = width(0)-20 : ymax = height(0)-20
    cx = INT(.5 + xmax / 2) :  cy = INT(.5 + ymax / 2) : tcmax = 15
    repeat
      sa = RND(100) - 50 : sb = RND(100) - 50 : sc = RND(100) - 50
      sav = (ABS(sa) + ABS(sb) + ABS(sc)) / 3
      Fractal(sa,sb,sc,6 - ABS(sav / 10))
    UNTIL scancode <> 0
end_sub
' ******************************************************************************
SUB Fractal(a,b,c,s)
    DIM_local xold, yold, xnew, ynew,t,tc
    xold = 0 : yold = 0 : t = 0 : tc = 0
    repeat
      2d_pen_color rnd(255),rnd(255),rnd(255)
      2d_point INT(.5 + xold) + cx, INT(.5 + yold) + cy
      xnew = yold - sgn(xold) * SQR(ABS(b * xold - c))
      ynew = a - xold : xold = xnew : yold = ynew
      t = t + 1 : IF t > 1000 then tc = tc + 1 : t = 0
    UNTIL scancode <> 0 OR ((tc > (tcmax - 1)) AND (tcmax > 0))
    cls
END_SUB
' ******************************************************************************
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
papydall

avatar

Nombre de messages : 5546
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Démo dédicacé à Papydall   Jeu 28 Fév 2013 - 5:55

Et .... un graphique sans nom !

Vous pouvez proposer un nom pour ce graphique.
L'auteur de la meilleure trouvaille recevra le prix Papydall.

Code:
' ------------------------------------------------------------------------------
' ***************  Sans_Nom.bas par Papydall  ********************************
' ------------------------------------------------------------------------------
dim size : size = 25
DIM x(size),y(size),xx(size),yy(size),nx(size),ny(size),r(size),t(size),v(size),u(size)
DIM winx,winy,accel,maxsp,minsp,maxX,maxy,xp,yp,i
full_space 0 : color 0,0,0,0
caption 0,"<CLICK> pour arrêter"
winX = 160 : winY = 240 : accel = .8 : maxsp = size / 1.5 : minsp = 0-maxsp
maxX = width(0)-winX : maxY = height(0)-winY : xp = maxX : yp = maxY
' -----------------------------------------------------------------------------
FOR i = 1 TO size
    xx(i) = minsp : yy(i) = minsp
    xp = xp - 400 / size : yp = yp - 400 / size
    x(i) = xp : y(i) = yp : r(i) = i
NEXT i
' -----------------------------------------------------------------------------
repeat
  FOR i = 1 TO size
      2d_pen_color 255,255,0 : 2d_CIRCLE t(i), v(i), u(i)
      2d_pen_color rnd(10)*i,rnd(10)*i,rnd(10)*i : 2d_CIRCLE x(i), y(i), r(i)
      IF i < size
          2d_pen_color 255,0,0 : 2d_LINE x(i), y(i),x(i + 1), y(i + 1)
      end_if
      t(i) = x(i): v(i) = y(i): u(i) = r(i)
  NEXT i
  FOR i = 1 TO size
      IF i = size
          xx(i) = xx(i) + nx(i) : yy(i) = yy(i) + ny(i)
          IF xx(i) > maxsp THEN xx(i) = maxsp
          IF xx(i) < minsp THEN xx(i) = minsp
          IF yy(i) > maxsp THEN yy(i) = maxsp
          IF yy(i) < minsp THEN yy(i) = minsp
          x(i) = x(i) + xx(i) : y(i) = y(i) + yy(i)
          IF x(i) > maxX THEN nx(i) = 0-RND(accel) - accel
          IF x(i) < winX THEN nx(i) = RND(accel) + accel
          IF y(i) > maxY THEN ny(i) = 0-RND(accel) - accel
          IF y(i) < winY THEN ny(i) = RND(accel) + accel
      END_IF
      IF i < size THEN : x(i) = x(i + 1) : y(i) = y(i + 1)
  NEXT i
until scancode <> 0
' ******************************************************************************
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Jean Claude

avatar

Nombre de messages : 5040
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Démo dédicacé à Papydall   Jeu 28 Fév 2013 - 9:47

Je propose La nappe de Grand-mère Very Happy

Une version colorisée:
Code:
' ------------------------------------------------------------------------------
' ***************  Sans_Nom.bas par Papydall  ********************************
' --------------------------------------------------- colorisation Jean Claude
dim cr,cg,cb
dim size : size = 25
DIM x(size),y(size),xx(size),yy(size),nx(size),ny(size),r(size),t(size),v(size),u(size)
DIM winx,winy,accel,maxsp,minsp,maxX,maxy,xp,yp,i
full_space 0 : color 0,0,0,0
caption 0,"<CLICK> pour arrêter"
winX = 160 : winY = 240 : accel = .8 : maxsp = size / 1.5 : minsp = 0-maxsp
maxX = width(0)-winX : maxY = height(0)-winY : xp = maxX : yp = maxY
' -----------------------------------------------------------------------------
FOR i = 1 TO size
    xx(i) = minsp : yy(i) = minsp
    xp = xp - 400 / size : yp = yp - 400 / size
    x(i) = xp : y(i) = yp : r(i) = i
NEXT i
' -----------------------------------------------------------------------------
repeat
  FOR i = 1 TO size
      cr=rnd(254)+1:cg=rnd(254)+1:cb=rnd(254)+1
      2d_pen_color cr,cg,cb : 2d_CIRCLE t(i), v(i), u(i)
      2d_pen_color rnd(10)*i,rnd(10)*i,rnd(10)*i : 2d_CIRCLE x(i), y(i), r(i)
      IF i < size
          cr=rnd(254)+1:cg=rnd(254)+1:cb=rnd(254)+1
          2d_pen_color cr,cg,cb : 2d_LINE x(i), y(i),x(i + 1), y(i + 1)
      end_if
      t(i) = x(i): v(i) = y(i): u(i) = r(i)
  NEXT i
  FOR i = 1 TO size
      IF i = size
          xx(i) = xx(i) + nx(i) : yy(i) = yy(i) + ny(i)
          IF xx(i) > maxsp THEN xx(i) = maxsp
          IF xx(i) < minsp THEN xx(i) = minsp
          IF yy(i) > maxsp THEN yy(i) = maxsp
          IF yy(i) < minsp THEN yy(i) = minsp
          x(i) = x(i) + xx(i) : y(i) = y(i) + yy(i)
          IF x(i) > maxX THEN nx(i) = 0-RND(accel) - accel
          IF x(i) < winX THEN nx(i) = RND(accel) + accel
          IF y(i) > maxY THEN ny(i) = 0-RND(accel) - accel
          IF y(i) < winY THEN ny(i) = RND(accel) + accel
      END_IF
      IF i < size THEN : x(i) = x(i + 1) : y(i) = y(i + 1)
  NEXT i
until scancode <> 0
' ******************************************************************************

Bon faut que j'y aille (travail oblige)

A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5546
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Démo dédicacé à Papydall   Jeu 28 Fév 2013 - 15:01

Salut Jean Claude.

Pas mal, la nappe de Grand-mère et la colorisation est jolie !
Tu es sur la liste des prétendants au prix.
Mais je crains que quelqu’un d'autre te devancera dans l’ordre de mérite.
Pour l’instant tu es tête de liste.

Wait and see ! Cool
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Yannick

avatar

Nombre de messages : 7994
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Jeu 28 Fév 2013 - 16:18

Je vous propose : le vers tricoteur

Laughing
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5546
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Démo dédicacé à Papydall   Jeu 28 Fév 2013 - 16:28

Ça c’est une trouvaille !
Et du coup tu surclasses J.C
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
mindstorm

avatar

Nombre de messages : 534
Age : 48
Localisation : charente
Date d'inscription : 13/02/2013

MessageSujet: Re: Démo dédicacé à Papydall   Jeu 28 Fév 2013 - 20:31

bonjour a tous
si je peux participé et ne pas paraitre trop beauf
allez ....je me lance....mais je suis serieux

le soutien gorge

vraiment je suis serieux
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 5040
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Démo dédicacé à Papydall   Jeu 28 Fév 2013 - 20:58

Heu Mindstorm, t'aurais pas des problèmes de vue cyclops

lol!

@Ygeronimi si c'est un ver alors je l'ai fait se tordre:
Code:
' ------------------------------------------------------------------------------
' ***************  Sans_Nom.bas par Papydall  ********************************
' --------------------------------------------------- Version (serpent) Jean Claude
dim cr,cg,cb,csp
dim size : size = 25
DIM x(size),y(size),xx(size),yy(size),nx(size),ny(size),r(size),t(size),v(size),u(size)
DIM winx,winy,accel,maxsp,minsp,maxX,maxy,xp,yp,i
full_space 0 : color 0,0,0,0
caption 0,"<CLICK> pour arrêter"
winX = 160 : winY = 240 : accel = .8 : maxsp = size / 1.5 : minsp = 0-maxsp
maxX = width(0)-winX : maxY = height(0)-winY : xp = maxX : yp = maxY
' -----------------------------------------------------------------------------
FOR i = 1 TO size
    xx(i) = minsp : yy(i) = minsp
    xp = xp - 400 / size : yp = yp - 400 / size
    x(i) = xp : y(i) = yp : r(i) = i
NEXT i
' -----------------------------------------------------------------------------
repeat
  FOR i = 1 TO size
      cr=rnd(254)+1:cg=rnd(254)+1:cb=rnd(254)+1
      2d_pen_color cr,cg,cb : 2d_CIRCLE t(i), v(i), u(i)
      2d_pen_color rnd(10)*i,rnd(10)*i,rnd(10)*i : 2d_CIRCLE x(i), y(i), r(i)
      IF i < size
          cr=rnd(254)+1:cg=rnd(254)+1:cb=rnd(254)+1
          2d_pen_color cr,cg,cb : 2d_LINE x(i), y(i),x(i + 1), y(i + 1)
      end_if
      t(i) = x(i): v(i) = y(i): u(i) = r(i)
  NEXT i
  FOR i = 1 TO size
  csp=rnd(24)+11
      IF i = size
          xx(i) = xx(i) + nx(i) : yy(i) = yy(i) + ny(i)
          IF xx(i) > maxsp THEN xx(i) = maxsp -csp
          IF xx(i) < minsp THEN xx(i) = minsp
          IF yy(i) > maxsp THEN yy(i) = maxsp -csp
          IF yy(i) < minsp THEN yy(i) = minsp
          x(i) = x(i) + xx(i) : y(i) = y(i) + yy(i)
          IF x(i) > maxX THEN nx(i) = 0-RND(accel) - accel
          IF x(i) < winX THEN nx(i) = RND(accel) + accel
          IF y(i) > maxY THEN ny(i) = 0-RND(accel) - accel
          IF y(i) < winY THEN ny(i) = RND(accel) + accel
      END_IF
      IF i < size THEN : x(i) = x(i + 1) : y(i) = y(i + 1)
  NEXT i
until scancode <> 0
' ******************************************************************************

Bon je vais prendre un verre c'est l'heure lol!

A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 7994
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Jeu 28 Fév 2013 - 21:04

@ Mindstorm,

Il est temps que tu résilies ton abonnement à canal+ ...

lol! lol! lol!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
mindstorm

avatar

Nombre de messages : 534
Age : 48
Localisation : charente
Date d'inscription : 13/02/2013

MessageSujet: Re: Démo dédicacé à Papydall   Jeu 28 Fév 2013 - 23:16

pour me faire pardonner avec mes modestes moyens




Code:
' Démo ecrite par Jicehel sur une idée de Papydall
' pour tester le 2D_point...
' forme coeurmodif mindstorm
Dim PosX , PosY ,Pos2X , Pos2Y , angle, couleur, sens
2d_pen_width 10 : ' ne fonctionne pas avec 2D_POINT
caption 0,"<CLICK> pour arrêter"
repeat
  PosX = 0 : PosY = 0 : couleur = 0 : sens = 0.5
  for angle = 0 to 360 step 0.3141
    PosX = 40 *((sin(angle))*(1+(cos(angle)))) : PosY =200+( 50*((cos(angle)*(1+cos(angle)))))
    2d_pen_color abs(Posx/3)+50,angle/ 3, 255 - couleur
    2d_poly_from  PosX + 280, PosY + 20 : 2d_poly_to PosX + 280, PosY + 20
    couleur = couleur + 1 * sens : if (couleur >= 255 or couleur <= 0) then  sens = 0 - sens
    if scancode <>0 then exit_for
    wait 3
  next angle
until scancode <> 0
terminate
avec du retard pour la saint valentin
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5858
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Démo dédicacé à Papydall   Ven 1 Mar 2013 - 0:19

Oh ben dites donc, j'ai de la lecture bon alors ma version pour les 3 programmes pour défendre ma réputation ^^
Code:
' ------------------------------------------------------------------------------
' ***************  Sans_Nom.bas par Papydall  ********************************
' ------------------------------------------------------------------------------
dim size : size = 25
DIM x(size),y(size),xx(size),yy(size),nx(size),ny(size),r(size),t(size),v(size),u(size)
DIM winx,winy,accel,maxsp,minsp,maxX,maxy,xp,yp,i, cpt, sens
full_space 0 : color 0,0,0,0
caption 0,"<CLICK> pour arrêter"
winX = 160 : winY = 240 : accel = .8 : maxsp = size / 1.5 : minsp = 0-maxsp
maxX = width(0)-winX : maxY = height(0)-winY : xp = maxX : yp = maxY
' -----------------------------------------------------------------------------
FOR i = 1 TO size
    xx(i) = minsp : yy(i) = minsp
    xp = xp - 400 / size : yp = yp - 400 / size
    x(i) = xp : y(i) = yp : r(i) = i
NEXT i
' -----------------------------------------------------------------------------
cpt = 1 : sens = 1
repeat
  FOR i = 1 TO size
      2d_pen_color i*cpt,255-i*10,0 : 2d_CIRCLE t(i), v(i), u(i)
      2d_pen_color rnd(cpt)*i,255 - rnd(cpt)*i,rnd(cpt)*i : 2d_CIRCLE x(i), y(i), r(i)
      IF i < size
          2d_pen_color 255,0,0 : 2d_LINE x(i), y(i),x(i + 1), y(i + 1)
      end_if
      t(i) = x(i): v(i) = y(i): u(i) = r(i)
      cpt = cpt+1*sens : if cpt = 10 : sens = 0 - sens : else: if cpt = 1 then sens = 0 - sens : end_if
  NEXT i
  FOR i = 1 TO size
      IF i = size
          xx(i) = xx(i) + nx(i) : yy(i) = yy(i) + ny(i)
          IF xx(i) > maxsp THEN xx(i) = maxsp
          IF xx(i) < minsp THEN xx(i) = minsp
          IF yy(i) > maxsp THEN yy(i) = maxsp
          IF yy(i) < minsp THEN yy(i) = minsp
          x(i) = x(i) + xx(i) : y(i) = y(i) + yy(i)
          IF x(i) > maxX THEN nx(i) = 0-RND(4*accel) - accel
          IF x(i) < winX THEN nx(i) = RND(4*accel) + accel
          IF y(i) > maxY THEN ny(i) = 0-RND(accel) - accel
          IF y(i) < winY THEN ny(i) = RND(accel) + accel
      END_IF
      IF i < size THEN : x(i) = x(i + 1) : y(i) = y(i + 1)
  NEXT i
until scancode <> 0
' ******************************************************************************


le 2 ème

Code:
' ------------------------------------------------------------------------------
' ***************  Sans_Nom.bas par Papydall  ********************************
' --------------------------------------------------- Version (serpent) Jean Claude
dim cr,cg,cb,csp
dim size : size = 25
DIM x(size),y(size),xx(size),yy(size),nx(size),ny(size),r(size),t(size),v(size),u(size)
DIM winx,winy,accel,maxsp,minsp,maxX,maxy,xp,yp,i,cpt, sens
full_space 0 : color 0,0,0,0
caption 0,"<CLICK> pour arrêter"
winX = 160 : winY = 240 : accel = .8 : maxsp = size / 1.5 : minsp = 0-maxsp
maxX = width(0)-winX : maxY = height(0)-winY : xp = maxX : yp = maxY
' -----------------------------------------------------------------------------
FOR i = 1 TO size
    xx(i) = minsp : yy(i) = minsp
    xp = xp - 400 / size : yp = yp - 400 / size
    x(i) = xp : y(i) = yp : r(i) = i
NEXT i
' -----------------------------------------------------------------------------
cpt = 1 : sens = 1
repeat
  FOR i = 1 TO size
      cr=i*cpt:cg=255-i*cpt:cb=0
      2d_pen_color cr,cg,cb : 2d_CIRCLE t(i), v(i), u(i)
      2d_pen_color rnd(cpt)*i,255-rnd(cpt)*i,rnd(cpt)*i : 2d_CIRCLE x(i), y(i), r(i)
      IF i < size
          cr=rnd(254)+1:cg=rnd(254)+1:cb=rnd(254)+1
          2d_pen_color cr,cg,cb : 2d_LINE x(i), y(i),x(i + 1), y(i + 1)
      end_if
      t(i) = x(i): v(i) = y(i): u(i) = r(i)
      cpt = cpt+1*sens : if cpt = 10 : sens = 0 - sens : else: if cpt = 1 then sens = 0 - sens : end_if
  NEXT i
  FOR i = 1 TO size
  csp=rnd(24)+11
      IF i = size
          xx(i) = xx(i) + nx(i) : yy(i) = yy(i) + ny(i)
          IF xx(i) > maxsp THEN xx(i) = maxsp -csp
          IF xx(i) < minsp THEN xx(i) = minsp
          IF yy(i) > maxsp THEN yy(i) = maxsp -csp
          IF yy(i) < minsp THEN yy(i) = minsp
          x(i) = x(i) + xx(i) : y(i) = y(i) + yy(i)
          IF x(i) > maxX THEN nx(i) = 0-RND(accel) - accel
          IF x(i) < winX THEN nx(i) = RND(accel) + accel
          IF y(i) > maxY THEN ny(i) = 0-RND(accel) - accel
          IF y(i) < winY THEN ny(i) = RND(accel) + accel
      END_IF
      IF i < size THEN : x(i) = x(i + 1) : y(i) = y(i + 1)
  NEXT i
until scancode <> 0
' ******************************************************************************

et la St Valentin revue

Code:
' Démo ecrite par Jicehel sur une idée de Papydall
' pour tester le 2D_point...
' forme coeurmodif mindstorm
Dim PosX , PosY ,Pos2X , Pos2Y , angle, couleur, sens
2d_pen_width 20 : ' ne fonctionne pas avec 2D_POINT
caption 0,"<CLICK> pour arrêter"
repeat
  PosX = 0 : PosY = 0 : couleur = 0 : sens = 0.5
  for angle = 0 to 360 step 0.5
    PosX = 120 *((sin(angle))*(1+(cos(angle)))) : PosY =100 +( 150*((cos(angle)*(1+cos(angle)))))
    2d_pen_color angle /2 + 50,rnd(50), couleur + rnd (100)
    2d_poly_from  PosX + 280, PosY + 20 : 2d_poly_to PosX + 280, PosY + 20
    couleur = couleur + 1 * sens : if (couleur >= 100 or couleur <= 0) then  sens = 0 - sens
    if scancode <>0 then exit_for
    wait 3
  next angle
until scancode <> 0
terminate
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5858
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Démo dédicacé à Papydall   Ven 1 Mar 2013 - 0:29

Mince, j'avais oublié le beau programme de fractales alors que c'est mon préféré en plus.
Don voici sa version colorisée
Code:
' **********************    Fractal.bas par Papydall    ***********************
Run()
terminate
' ******************************************************************************
SUB Run()
    DIM  xmax,ymax,tcmax,cx,cy,sa,sav,sb,sc
    full_space 0 : color 0,0,0,0
    caption 0,"<CLICK> pour arrêter"
    xmax = width(0)-20 : ymax = height(0)-20
    cx = INT(.5 + xmax / 2) :  cy = INT(.5 + ymax / 2) : tcmax = 15
    repeat
      sa = RND(100) - 50 : sb = RND(100) - 50 : sc = RND(100) - 50
      sav = (ABS(sa) + ABS(sb) + ABS(sc)) / 3
      Fractal(sa,sb,sc,6 - ABS(sav / 10))
    UNTIL scancode <> 0
end_sub
' ******************************************************************************
SUB Fractal(a,b,c,s)
    DIM_local xold, yold, xnew, ynew,t,tc
    DIM_local C1,C2,C3
    xold = 0 : yold = 0 : t = 0 : tc = 0
    repeat
      caption 0,abs(c)
      C1 = abs(xold)*(rnd(1)+0.5) : IF C1 < 10 : C1 = 10 : ELSE :IF C1 > 255 THEN C1 = 255 : END_IF
      C2 = abs(b)*(rnd(4)+1) : IF C2 < 10 : C2 = 10: ELSE :IF C2 > 255 THEN C2 = 255 : END_IF
      C3 = abs(c)*(rnd(2)+0.5) : IF C3 < 10 : C3 = 10 : ELSE : IF C3 > 255 THEN C3 = 255 : END_IF
      2d_pen_color C1,C2,C3
      2d_point INT(.5 + xold) + cx, INT(.5 + yold) + cy
      xnew = yold - sgn(xold) * SQR(ABS(b * xold - c))
      ynew = a - xold : xold = xnew : yold = ynew
      t = t + 1 : IF t > 1000 then tc = tc + 1 : t = 0
    UNTIL scancode <> 0 OR ((tc > (tcmax - 1)) AND (tcmax > 0))
    cls
END_SUB
' ******************************************************************************
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5546
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Démo dédicacé à Papydall   Ven 1 Mar 2013 - 2:46

Salut tout le monde.
Je me suis absenté quelques heures et que de belles choses !
Merci à vous tous.

@minderstorm
Ta participation me fait plaisir. J’ai beau chercher le soutien-gorge mais je ne l’ai pas vu ou plutôt j’ai vu mieux qu’un vulgaire soutien-gorge : j’ai cru voir ce qu’il devrait cacher ! Mais, bon chacun peut voir ce qu’il veut voir.

@Jicehel
Merci pour les couleurs.

@Tous : Jean Claude, Ygeronimi, mindstorm, Jicehel

Je vous déclare tous gagnants du prix Papydall !


Voici un autre sans nom.
Code:
' ******************************************************************************
'                  un autre sans nom par Papydall
' ******************************************************************************
dim pi,demi_Pi,X,Y,Angle,debut,fin ,p
pi = 4*atn(1) : Demi_pi = pi/2 : debut = 0-20*pi : fin = 20*pi : p = .9
caption 0,"<CLICK> pour arrêter" : color 0,0,0,0 : cls
repeat
  FOR Angle = debut TO fin STEP p
    X = 320 + 150 * COS(Angle) : Y = 200 + 75 * SIN(Angle)
    2d_pen_color rnd(255),rnd(255),rnd(255): 2d_circle X + 90 * COS(Angle), Y + 20 * SIN(Angle),26
    2d_pen_color 255,255,255 : 2d_circle X + 80 * COS(Angle), Y + 20 * SIN(Angle),24
    2d_pen_color 255,255,0  : 2d_circle X + 70 * COS(Angle), Y + 18 * SIN(Angle),21
    2d_pen_color 255,0,255  : 2d_circle X + 60 * COS(Angle), Y + 16 * SIN(Angle),18
    2d_pen_color 255,0,0    : 2d_circle X + 50 * COS(Angle), Y + 14 * SIN(Angle),15
    2d_pen_color 0,255,255  : 2d_circle X + 40 * COS(Angle), Y + 12 * SIN(Angle),12
    2d_pen_color 0,255,0    : 2d_circle X + 30 * COS(Angle), Y + 10 * SIN(Angle),09
    2d_pen_color 0,0, 255    : 2d_circle X + 20 * COS(Angle), Y + 08 * SIN(Angle),06
    2d_pen_color rnd(255),rnd(255),rnd(255) : 2d_circle X + 10 * COS(Angle), Y + 06 * SIN(Angle),03
' ------------------------------------------------------------------------------
    2d_pen_color rnd(255),rnd(255),rnd(255): 2d_circle X - 80 * COS(Angle + Demi_Pi), Y - 20 * SIN(Angle + Demi_Pi),26
    2d_pen_color 255,255,255 : 2d_circle X - 80 * COS(Angle + Demi_Pi), Y - 20 * SIN(Angle + Demi_Pi),24
    2d_pen_color 255,255,0  : 2d_circle X - 70 * COS(Angle + Demi_Pi), Y - 18 * SIN(Angle + Demi_Pi),21
    2d_pen_color 255,0,255  : 2d_circle X - 60 * COS(Angle + Demi_Pi), Y - 16 * SIN(Angle + Demi_Pi),18
    2d_pen_color 255,0,0    : 2d_circle X - 50 * COS(Angle + Demi_Pi), Y - 14 * SIN(Angle + Demi_Pi),15
    2d_pen_color 0,255,255  : 2d_circle X - 40 * COS(Angle + Demi_Pi), Y - 12 * SIN(Angle + Demi_Pi),12
    2d_pen_color 0,255,0    : 2d_circle X - 30 * COS(Angle + Demi_Pi), Y - 10 * SIN(Angle + Demi_Pi),09
    2d_pen_color 0,0, 255    : 2d_circle X - 20 * COS(Angle + Demi_Pi), Y - 08 * SIN(Angle + Demi_Pi),06
    2d_pen_color rnd(255),rnd(255),rnd(255) : 2d_circle X - 10 * COS(Angle + Demi_Pi), Y - 06 * SIN(Angle + Demi_Pi),03
  NEXT Angle
'  debut = 0-debut : fin = 0-fin : p = 0-p
until scancode <> 0

Les plus courts sont les meilleurs!

Code:
' ******************************************************************************
' Les plus courts sont les meilleurs !  par Papydall
' ******************************************************************************
dim angle,r,pi,xc,yc,p
pi = 4*atn(1) : p = pi/1440 : caption 0,"<CLICK> pour arrêter"
full_space 0 : xc = width(0)/2 : yc = height(0)/2 : color 0,0,0,0
repeat
  angle = angle + p : if angle > 2*pi then angle = 0
  r = r + 1.07 : if r > 390 then r = 0
  2d_pen_color rnd(255),rnd(255),rnd(255) : 2d_point xc + r*COS(angle),yc + r*SIN(angle)
  2d_pen_color mod(r,255),255,40*angle : 2d_point xc + r*COS(angle + p * 9), yc + r*SIN(angle + p * 9)
until scancode <> 0
' ******************************************************************************
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Jean Claude

avatar

Nombre de messages : 5040
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Démo dédicacé à Papydall   Ven 1 Mar 2013 - 9:44

J'aime bien le dernier de Papydall, très joli avec l'éclairage au centre.

@Jicehel
Le premier que tu as présenté me plait beaucoup, on a une impression de 3D.

Pour la coupe, comme on est plusieurs gagnant, je propose que Papydall la garde bien au chaud chez lui pour éviter des frais d'envoi trop coûteux.

lol!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 7994
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Ven 1 Mar 2013 - 16:50

Pour : "un autre sans nom" , je te propose : "La valse des crayons"... Laughing
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5546
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Démo dédicacé à Papydall   Sam 2 Mar 2013 - 6:54

Voici un énième tracé de la fractale de Julia.

Code:
' ******************************************************************************
'                  Julia.bas par Papydall
' ******************************************************************************
Run()
end
' ******************************************************************************
SUB Run()
    label fin
    dim ec,x0,y0,xp0,yp0,Nxp,Nyp
    caption 0,"Tracé de la fractale de Julia en cours ... Veuillez patienter ... <CLICK> pour arrêter"
    ec = 400 : width 0, 2*ec+20 : color 0,0,0,0
' Essayez ces differents paramètres pour d'autres ensembles de Julia
    x0 = 0 : y0 = 0 : xp0 = .3 : yp0 = .5
'    x0 = 0-.5 : y0 = 0 : xp0 = .285 : yp0 = .013
'    x0 = 0-.5 : y0 = 0 : xp0 = .3 : yp0 = 0 -.49
'    x0 = 0-.5 : y0 = 0 : xp0 = .285 : yp0 = .01
'    x0 = .5 : y0 = .123 : xp0 = .3777 : yp0 = .123456
'    x0 = 0-.5 : y0 = .0123 : xp0 = .3456789 : yp0 = 0-.423456789

 
    Nxp = (xp0 - x0) * ec  / 4 + ec / 2 : Nyp = (y0 - yp0) * ec  / 4 + ec / 2
    alpha 1 : top 1,420 :left 1,100 : font_color 1,255,255,0 : font_bold 1
    color 1,255,0,0 : font_size 1,10 : caption 1," Fractale en Couleur "
    alpha 2 : top 2,420 :left 2,600 : font_color 2,255,255,0 : font_bold 2
    color 2,255,0,0 : font_size 2,10 : caption 2," Fractale en Noir "
    display : Julia(Nxp,Nyp) : caption 0,"Terminé"
END_SUB
' *****************************************************************************
' Tracé de la fractale ; optimisation du tracé par la symétrie
SUB Julia(Nxp, Nyp)
    dim_local cx,cy,x,y,xn,yn,modul ,nx,ny,Nb_iter
    cx = x0 + 4 / ec * (Nxp - ec / 2) : cy = y0 - 4 / ec * (Nyp - ec / 2)
    FOR Nx = 1 TO ec
        FOR Ny = 1 TO Nx
            X = 3 / ec * (Nx - ec / 2) : Y =  -3 / ec * (Ny - ec / 2)
' Diminuer le nombre d'itérations accélère le tracé mais on perd en netteté !
            FOR Nb_iter = 1 TO 50
                xn = X*X - Y*Y + cx : yn = 2*X*Y + cy
                modul = SQR((x-xn)*(x-xn) + (y-yn)*(y-yn)) : X = xn : Y = yn
                IF SQR(xn * xn + yn * yn) > 2
                  2d_pen_color 50,150,150
                  2d_point Nx, Ny : 2d_point ec - Nx + 1, ec - Ny + 1
                  2d_point ec + nx, Ny : 2d_point 2*ec - Nx +1, ec -Ny + 1
                  GOTO fin
                END_IF
            NEXT Nb_iter
            IF modul >= 2  THEN 2d_pen_color 0,0,0
            IF modul < 2    THEN 2d_pen_color 255,0,255
            IF modul < 1.75  THEN 2d_pen_color 255,255,0
            IF modul < 1.5  THEN 2d_pen_color 255,255,255
            IF modul < 1.25 THEN 2d_pen_color 0,255,0
            IF modul < 1    THEN 2d_pen_color 0,255,255
            IF modul < .7  THEN 2d_pen_color 0,0,255
            IF modul < .5  THEN 2d_pen_color 127,127,127
            IF modul < .4  THEN 2d_pen_color 127,127,0
            IF modul < .3  THEN 2d_pen_color 127,0,127
            IF modul < .2  THEN 2d_pen_color 127,0,0
            IF modul < .1  THEN 2d_pen_color 255,0,0
            2d_point Nx, Ny : 2d_point ec - Nx + 1, ec - Ny + 1
fin:
            if scancode <> 0 then caption 0,"Arrêté par l'utilisateur ! Dommage !!!" :end
        NEXT Ny
    NEXT Nx
END_SUB
' ******************************************************************************

J’aimerais bien voir comment ça se passerait avec le futur compilateur !


Dernière édition par papydall le Sam 2 Mar 2013 - 18:50, édité 3 fois (Raison : Ajout d'autres ensembles de Julia)
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Jicehel

avatar

Nombre de messages : 5858
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Démo dédicacé à Papydall   Sam 2 Mar 2013 - 11:58

Joli Wink
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 7994
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Sam 2 Mar 2013 - 15:42

Très jolie, un peu bizarre ta copines mais jolie...
lol!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5546
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Démo dédicacé à Papydall   Sam 2 Mar 2013 - 17:17

ygeronimi a écrit:
Très jolie, un peu bizarre ta copines mais jolie...
lol!

Heu, de quelle copines tu parles ?!
Julia n’est pas une femme !!!
Gaston Maurice Julia (né le 3 février 1893 en Algérie , décédé le 19 mars 1978 à Paris) était un mathématicien , spécialiste des fonctions d'une variable complexe.
Ses résultats de 1917-1918 sur l'itération des fractions rationnelles ont été remis à la mode dans les années 1970 par le mathématicien français d'origine polonaise, Benoît Mandelbrot.
Les ensembles de Julia offrent de nombreux exemples d'ensembles fractals.

EDIT : J'ai édité Julia.bas. Raison : ajout d'autres ensembles de Julia.


Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Contenu sponsorisé




MessageSujet: Re: Démo dédicacé à Papydall   

Revenir en haut Aller en bas
 
Démo dédicacé à Papydall
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 1 sur 2Aller à la page : 1, 2  Suivant
 Sujets similaires
-
» Démo dédicacé à Papydall
» Welcome Papydall
» Rachel Bilson (PF & PFS)
» Les articles de Papydall

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Vos sources, vos utilitaires à partager-
Sauter vers: