FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» StratégoV8 et V9
par Minibug Aujourd'hui à 21:47

» KGF_dll - nouvelles versions
par Klaus Aujourd'hui à 21:28

» Déformation d'image en trapèze
par mindstorm Aujourd'hui à 21:06

» Mah-Jong américain
par Jean Claude Hier à 19:37

» Problème avec Deepl
par Klaus Hier à 0:34

» Quelques nouvelles ...
par Jean Claude Ven 12 Jan 2018 - 22:40

» Renommer les instructions ITEM_... ?
par Jicehel Ven 12 Jan 2018 - 18:56

» Ludothèque Panoramic
par jjn4 Ven 12 Jan 2018 - 18:11

» sous-programmes et fonctions
par Jack Ven 12 Jan 2018 - 17:51

» Mah-Jong français
par Jean Claude Jeu 11 Jan 2018 - 22:15

» HVIEWER
par Klaus Mer 10 Jan 2018 - 2:06

» panoramic 0.9.28
par gigi75 Ven 5 Jan 2018 - 14:06

» Un jeu qui va vous énerver!
par Jean Claude Jeu 4 Jan 2018 - 22:05

» Bonne fêtes de fin d'année ! Meilleurs Vœux 2018 !
par Jicehel Jeu 4 Jan 2018 - 17:28

» Mah-Jong international
par jjn4 Jeu 4 Jan 2018 - 16:55

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Janvier 2018
LunMarMerJeuVenSamDim
1234567
891011121314
15161718192021
22232425262728
293031    
CalendrierCalendrier

Partagez | 
 

 passez à la loupe ses polices de caratères

Voir le sujet précédent Voir le sujet suivant Aller en bas 
Aller à la page : 1, 2, 3  Suivant
AuteurMessage
bignono

avatar

Nombre de messages : 1109
Age : 60
Localisation : Val de Marne
Date d'inscription : 13/11/2011

MessageSujet: passez à la loupe ses polices de caratères   Sam 5 Jan 2013 - 18:16

Bonjour à tous Smile
J'ai réalisé il y a déjà pas mal de temps, bien avant les sub, un petit bout de code qui me permet de voir à quoi ressemble les polices de caractères affichées dans un memo avec leurs attributs graphiques. J'en ai limité la taille à 20, mais vous pouvez changer le programme si vous désirez pousser les capacités plus loin. J'y ai inséré 5 phrases sensées contenir toutes les lettres de l'alphabet. Ce genre de phrase porte un nom, mais il ne me vient pas à l'esprit. Il y en a des possibilités infinis et certaines phrases sont plus loufoques que d'autres.
Le programme est des plus simple et pas très long non plus et devrait être facile à comprendre pour un débutant.
Code:
dim fr%,fv%,fb%,j,cr%,cv%,cb%
label fond,font,taille,police,gras,raye,ital,soul

left 0,(screen_x-width(0))/2:top 0,(screen_y-height(0))/2

combo 30:left 30,395:width 30,40:for j=6 to 20:item_add 30,str$(j):next j:text 30,"10":on_change 30,taille
alpha 35:left 35,320:top 35,5:font_bold 35:caption 35,"Taille police"
combo 40:left 40,438:font_names_load 40:text 40,"Arial":on_change 40,police

check 45:left 45,340:top 45,60:font_bold 45:caption 45,"GRAS":on_click 45,gras
check 46:left 46,340:top 46,40:font_bold 46:caption 46,"RAYÉ":on_click 46,raye
check 47:left 47,420:top 47,60:font_bold 47:caption 47,"ITALIQUE":on_click 47,ital
check 48:left 48,420:top 48,40:font_bold 48:caption 48,"SOULIGNÉ":on_click 48,soul

memo 50:left 50,2:top 50,80:width 50,580:height 50,310:color 50,0,0,0:font_name 50,"Arial"
item_add 50,"Télégraphiez c'week-end vos fous joyaux iambiques"
item_add 50,"Objectivez magnifique whisky paradoxal !"
item_add 50,"Eh, fi ! Rempaquetez vos jeux ce week-end. Balayage !"
item_add 50,"Voyez le brick géant que j'examine près du wharf."
item_add 50,"Évêqe, hébergez fées le week-end, je m'excepte !"

alpha 60:left 60,70:top 60,5:font_bold 60:caption 60,"Couleur de fond du mémo"
scroll_bar 61:left 61,5:top 61,020:width 61,256:min 61,0:max 61,255:on_change 61,fond
scroll_bar 62:left 62,5:top 62,040:width 62,256:min 62,0:max 62,255:on_change 62,fond
scroll_bar 63:left 63,5:top 63,060:width 63,256:min 63,0:max 63,255:on_change 63,fond
alpha 081:left 081,265:top 081,020:font_name 081,"Consolas":font_color 081,255,0,0:font_bold 081
alpha 082:left 082,265:top 082,040:font_name 082,"Consolas":font_color 082,0,155,0:font_bold 082
alpha 083:left 083,265:top 083,060:font_name 083,"Consolas":font_color 083,0,0,255:font_bold 083
gosub fond

alpha 90:left 90,190:top 90,390:font_bold 90:caption 90,"Couleur de la police de caractères"
scroll_bar 91:left 91,005:top 91,420:width 91,180:min 91,0:max 91,255:on_change 91,font
scroll_bar 92:left 92,200:top 92,420:width 92,180:min 92,0:max 92,255:on_change 92,font
scroll_bar 93:left 93,395:top 93,420:width 93,180:min 93,0:max 93,255:on_change 93,font
alpha 101:left 101,100:top 101,405:font_name 101,"Consolas":font_color 101,255,0,0:font_bold 101
alpha 102:left 102,300:top 102,405:font_name 102,"Consolas":font_color 102,0,155,0:font_bold 102
alpha 103:left 103,500:top 103,405:font_name 103,"Consolas":font_color 103,0,0,255:font_bold 103
gosub font
end

fond:
fr%=position(61):fv%=position(62):fb%=position(63):color 50,fr%,fv%,fb%
caption 81,"ROUGE => "+str$(fr%):caption 82,"VERT ==> "+str$(fv%):caption 83,"BLEU ==> "+str$(fb%)
return

font:
cr%=position(91):cv%=position(92):cb%=position(93):font_color 50,cr%,cv%,cb%
caption 101,str$(cr%):caption 102,str$(cv%):caption 103,str$(cb%)
return

taille:
if item_index(30)=0 then return
j=val(item_read$(30,item_index(30)))
font_size 50,j
return

gras:
font_bold_off 50:if checked(45)=1 then font_bold 50
return

raye:
font_strike_off 50:if checked(46)=1 then font_strike 50
return

ital:
font_italic_off 50:if checked(47)=1 then font_italic 50
return

soul:
font_underline_off 50:if checked(48)=1 then font_underline 50
return

police:
if item_index(40)=0 then return
font_name 50,item_index$(40)
return
A+ Wink Wink Wink
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
JL35



Nombre de messages : 6069
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: passez à la loupe ses polices de caratères   Sam 5 Jan 2013 - 20:03

Portez ce vieux whisky au juge blond qui fume.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 5121
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: passez à la loupe ses polices de caratères   Sam 5 Jan 2013 - 20:40

Ce programme est bien pratique pour faire son choix de police et de couleur.

A ce propos j'utilise très souvent un programme fait par JL35 qui nous donne les codes caractères pour toutes les polices. il s'appelle 204FONTES (en tout cas c'est que je lis dans le bandeau). très pratique pour rechercher des symboles (en particulier pour les fontes Wingding)

Je verrais bien une association des 2 car celui de Bignono ne donne pas les codes mais permet aisément de choisir couleur,taille,police, ... et de visionner le résultat.

Qu'en penses-tu JL35

A+

PS: j'ai ajouter à la place du texte ces 3 lignes au code de Bignono, mais il faudrait revoir la taille du memo et j'ai pas trop le temps. Very Happy
Code:
for i%=1 to 9:item_add 50,"  "+str$(i%)+"  "+chr$(i%):next i%
for i%=10 to 99:item_add 50," "+str$(i%)+"  "+chr$(i%):next i%
for i%=100 to 255:item_add 50,str$(i%)+"  "+chr$(i%):next i%
Revenir en haut Aller en bas
Voir le profil de l'utilisateur En ligne
bignono

avatar

Nombre de messages : 1109
Age : 60
Localisation : Val de Marne
Date d'inscription : 13/11/2011

MessageSujet: Re: passez à la loupe ses polices de caratères   Sam 5 Jan 2013 - 22:53

Bonsoir Jean Claude, Very Happy
Moi aussi j'utilise le programme de JL35 qui affiche les polices de caractères chr$. Il est très pratique surtout sa première version avec le décodage hexadécimal du chr$ choisi. Je pense que ce serait une bonne idée de le combiner avec le mien. Je suis trop pris et occupé en ce moment pour le faire, mais peut-être que JL35 ...?
A+ Wink Wink Wink
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
JL35



Nombre de messages : 6069
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 1:52

Vous gênez pas les gars pour me donner du boulot !

Bon j'ai repris rapidement mon programme de polices et j'ai ajouté quelques trucs en m'inspirant de bignono (couleurs et enrichissements), mais je n'ai pas prévu de changer la taille (pas trop d'intérêt ?, à voir...):
Code:
Rem Liste des polices système
dim i%, j%, k%, a$, Police$, np, we, he, xh, yh, eh, xv, yv, ev, tx$, x%, y%, xlp, ylp
DIM rf%, gf%, bf%, rc%, gc%, bc%, enr$, c$
label Debut, Afpol, Cfond, Ccar, Reaff
tx$ = "Voyez Le Brick Géant Que J'Examine Près Du Wharf 0123456789"
we = 780: he = 810: width 0, we: height 0, he
Font_Name 0, "Courier New": Font_Size 0,14
Color 0,255,255,190

Rem affichage de la liste des polices
list 1: left 1,5 : top 1, 4 : width 1, 220 : height 1, 630: ' liste des polices dispo
Font_Name 1, "Arial": Font_Size 1,10: Color 1,196,255,196
on_click 1, Debut

xh = 260 : yh = 38: eh = 30
xv = 240: yv = 60: ev = 36
Rem affichage des échelles horizontale et verticale
List 2: top 2, yh: left 2, xh: width 2, 490: height 2, 20
Font_Name 2, "Courier New": Font_Size 2, 12: Font_Color 2, 0, 0, 255
Font_Bold 2
List 3: top 3, yv: left 3, xv: width 3, 20: height 3, 570
Font_Name 3, "Courier New": Font_Size 3, 12: Font_Color 3, 0, 0, 255
Font_Bold 3
Print_Target_Is 2: Print " 0  1  2  3  4  5  6  7  8  9  A  B  C  D  E  F"
For i% = 0 To 15: Item_Add 3, Hex$(i%): Item_Add 3, "": Next i%
xlp = xh+13: ylp = yv
Rem exemple de texte
List 4: Top 4, 640: Left 4, 5: Width 4, we-30: Height 4,40: ' Texte exemple
List 5: Top 5, 5: Left 5, xh: Height 5, 28: Width 5, 300: ' Nom de police
Font_Name 5, "Arial Black": Font_Size 5, 12: Font_Color 5, 0, 0, 255
DLIST 6: FONT_NAMES_LOAD 6
np = COUNT(6): CAPTION 0, " " + STR$(np) + " polices de caractères"
Picture 9: top 9,-800
FOR i% = 1 TO np
    Police$ = ITEM_READ$(6, i%): FONT_NAME 9,Police$
    j% = TEXT_WIDTH("iiiiiiiiii",9): k% = TEXT_WIDTH("mmmmmmmmmm",9)
    IF j% = k%
        a$ = "F " + Police$: ' police à pas fixe
    ELSE
        a$ = "  " + Police$: ' police proportionnelle
    END_IF
    ITEM_ADD 1, a$
NEXT i%
DELETE 9
ALPHA 10: TOP 10,TOP(4)+HEIGHT(4)+10: LEFT 10,10: CAPTION 10, "Fond:"
SCROLL_BAR 11:TOP 11,TOP(10)+3:LEFT 11,70: WIDTH 11,190
MIN 11,0: MAX 11,255: POSITION 11,255: ON_CHANGE 11,Cfond
ALPHA 12:TOP 12,TOP(10):LEFT 12,LEFT(11)+WIDTH(11):CAPTION 12,POSITION(11)
FONT_COLOR 12,255,0,0: FONT_BOLD 12
SCROLL_BAR 13:TOP 13,TOP(11):LEFT 13,300: WIDTH 13,190
MIN 13,0: MAX 13,255: POSITION 13,255: ON_CHANGE 13,Cfond
ALPHA 14:TOP 14,TOP(10):LEFT 14,LEFT(13)+WIDTH(13):CAPTION 14,POSITION(13)
FONT_COLOR 14,0,255,0: FONT_BOLD 14
SCROLL_BAR 15:TOP 15,TOP(11):LEFT 15,530: WIDTH 15,190
MIN 15,0: MAX 15,255: POSITION 15,255: ON_CHANGE 15,Cfond
ALPHA 16:TOP 16,TOP(10):LEFT 16,LEFT(15)+WIDTH(15):CAPTION 16,POSITION(15)
FONT_COLOR 16,0,0,255: FONT_BOLD 16
ALPHA 20: TOP 20,TOP(10)+25: LEFT 20,5: CAPTION 20, "Carac:"
SCROLL_BAR 21:TOP 21,TOP(20)+3: LEFT 21,70: WIDTH 21,190
MIN 21,0: MAX 21,255: POSITION 21,0: ON_CHANGE 21, Ccar
ALPHA 22:TOP 22,TOP(20):LEFT 22,LEFT(21)+WIDTH(21):CAPTION 22,POSITION(21)
FONT_COLOR 22,255,0,0: FONT_BOLD 22
SCROLL_BAR 23:TOP 23,TOP(21):LEFT 23,300: WIDTH 23,190
MIN 23,0: MAX 23,255: POSITION 23,0: ON_CHANGE 23, Ccar
ALPHA 24:TOP 24,TOP(20):LEFT 24,LEFT(23)+WIDTH(23):CAPTION 24,POSITION(23)
FONT_COLOR 24,0,255,0: FONT_BOLD 24
SCROLL_BAR 25:TOP 25,TOP(21):LEFT 25,530: WIDTH 25,190
MIN 25,0: MAX 25,255: POSITION 25,0: ON_CHANGE 25, Ccar
ALPHA 26:TOP 26,TOP(20):LEFT 26,LEFT(25)+WIDTH(25):CAPTION 26,POSITION(25)
FONT_COLOR 26,0,0,255: FONT_BOLD 26

CHECK 30: TOP 30,TOP(20)+30: LEFT 30,150: CAPTION 30, "Gras"
CHECK 31: TOP 31,TOP(30): LEFT 31,280: CAPTION 31, "Italique"
CHECK 32: TOP 32,TOP(30): LEFT 32,410: CAPTION 32, "Souligné"
CHECK 33: TOP 33,TOP(30): LEFT 33,540: CAPTION 33, "Barré"
gra% = 0: ita% = 0: sou% = 0: str% = 0
enr$ = "0000"

TIMER 100: TIMER_INTERVAL 100,200: ON_TIMER 100,Reaff

Police$ = "Arial": Gosub Afpol
End

Debut:
Police$= LTRIM$(MID$(Item_Index$(1),2,100)): ' choix d'une police dans la liste
Afpol:
Font_Name 0, Police$
Font_Size 0, 14
Print_Target_is 0
Display
Rem affichage des 256 caractères de la police
For j% = 0 To 255 Step 16
    y% = ylp + ev*j%/16
    For i% = j% to j% + 15
        x% = xlp + eh * (i%-j%)
        Print_Locate x%, y%: Print Chr$(i%)
    Next i%
Next j%
Font_Name 4, Police$: Font_Size 4, 18: Print_Target_Is 4
Clear 4: Print_Locate 5, 5: Print tx$
Clear 5: Print_Target_Is 5: Print " " + Police$
Return

Cfond:
rf% = POSITION(11): gf% = POSITION(13): bf% = POSITION(15)
CAPTION 12, STR$(rf%): CAPTION 14, STR$(gf%): CAPTION 16, STR$(bf%)
COLOR 4, rf%, gf%, bf%
RETURN

Ccar:
rc% = POSITION(21): gc% = POSITION(23): bc% = POSITION(25)
CAPTION 22, STR$(rc%): CAPTION 24, STR$(gc%): CAPTION 26, STR$(bc%)
FONT_COLOR 4, rc%, gc%, bc%
RETURN

Reaff:
a$ = "0": IF CHECKED(30) = 1 THEN a$ = "1"
c$ = "0": IF CHECKED(31) = 1 THEN c$ = "1"
a$ = a$ + c$
c$ = "0": IF CHECKED(32) = 1 THEN c$ = "1"
a$ = a$ + c$
c$ = "0": IF CHECKED(33) = 1 THEN c$ = "1"
a$ = a$ + c$
IF a$ <> enr$
    FONT_BOLD_OFF 4: FONT_ITALIC_OFF 4: FONT_UNDERLINE_OFF 4: FONT_STRIKE_OFF 4
    IF CHECKED(30) = 1 THEN FONT_BOLD 4
    IF CHECKED(31) = 1 THEN FONT_ITALIC 4
    IF CHECKED(32) = 1 THEN FONT_UNDERLINE 4
    IF CHECKED(33) = 1 THEN FONT_STRIKE 4
    enr$ = a$
END_IF
RETURN
(Je rappelle que le 'F' à gauche du nom de la police désigne une police à pas fixe).

Là-dessus... Sleep
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5623
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 2:05

Hello JL35.

Rassure-toi : on ne se gêne pas pour te donner du boulot !

J’ai dû supprimer cette ligne (ligne 76) qui ne sert à rien si ce n'est à provoquer une erreur puisque les variables n'ont pas été déclarées par DIM ! Et puis tu n'as pas jugé bon de les utiliser par la suite !
Code:
 gra% = 0: ita% = 0: sou% = 0: str% = 0

Sinon, c'est Hmmm !

Autrement, c'est Bnnn !
Finalement, c'est
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
bignono

avatar

Nombre de messages : 1109
Age : 60
Localisation : Val de Marne
Date d'inscription : 13/11/2011

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 12:50

Salut JL35,
J'ai vu ton dernier code qui est très bien, mais j'ai finalement trouvé le temps ce matin de bricoler ton code et le mien afin de les scinder dans un unique programme. J'ai pas peaufiné, mais ça marche!
Code:
' Liste des polices système
dim a,i%,j%,k%,a$,Police$,np,we,he,xh,yh,eh,xv,yv,ev,tx$,x%,y%,xlp,ylp,fr%,fv%,fb%,cr%,cv%,cb%,chx$
label Debut,Afpol,taille,gras,raye,ital,soul,fond,font,effet,objet,texte
tx$="Voyez Le Brick Géant Que J'Examine Près Du Wharf 0123456789"
we=783:he=860:width 0,we:height 0,he:font_name 0,"Courier New":Font_Size 0,14:Color 0,255,255,190

' affichage de la liste des polices
list 1:left 1,5:top 1,38:width 1,220:height 1,540:Font_Name 1,"Arial":Font_Size 1,10:Color 1,196,255,196:on_click 1,Debut
xh=260:yh=38:eh=30:xv=240:yv=60:ev=36
' affichage des échelles horizontale et verticale
List 2:top 2,yh:left 2,xh:width 2,490:height 2,20:Font_Name 2,"Courier New":Font_Size 2,12:Font_Color 2,0,0,255:Font_Bold 2
List 3:top 3,yv:left 3,xv:width 3,20:height 3,570:Font_Name 3,"Courier New":Font_Size 3,12:Font_Color 3,0,0,255:Font_Bold 3
Print_Target_Is 2: Print " 0  1  2  3  4  5  6  7  8  9  A  B  C  D  E  F"
For i%=0 To 15:Item_Add 3,Hex$(i%):Item_Add 3,"":Next i%
xlp=xh+13:ylp=yv
' exemple de texte
edit 4:Top 4,635:Left 4,5:Width 4,we-40:Height 4,100:text 4,tx$
DLIST 6:FONT_NAMES_LOAD 6:np=COUNT(6):CAPTION 0," "+STR$(np)+" polices de caractères"
Picture 9:top 9,-800
FOR i%=1 TO np
    Police$=ITEM_READ$(6,i%):FONT_NAME 9,Police$:j%=TEXT_WIDTH("iiiiiiiiii",9):k%=TEXT_WIDTH("mmmmmmmmmm",9)
    IF j%=k%:a$="F "+Police$:ELSE:a$="  " +Police$:END_IF
    ITEM_ADD 1,a$
NEXT i%
DELETE 9:Police$="Arial":Gosub Afpol

edit 10:left 10,5:top 10,4:width 10,220:font_name 10,"Consolas":font_size 10,10:text 10,tx$:on_change 10,texte

button 12:left 12,15:top 12,580:font_name 12,"Consolas":caption 12,"EDIT":on_click 12,objet
button 14:left 14,15:top 14,605:font_name 14,"Consolas":caption 14,"LIST":on_click 14,objet
button 16:left 16,width(12)+50:top 16,580:font_name 16,"Consolas":caption 16,"MEMO":on_click 16,objet
button 18:left 18,width(14)+50:top 18,605:font_name 18,"Consolas":caption 18,"ALPHA":on_click 18,objet

combo 30:left 30,230:width 30,40:font_size 30,10:for a=6 to 50:item_add 30,str$(a):next a:text 30,"10":on_change 30,taille
check 45:left 45,280:top 45,10:font_size 45,9:font_bold 45:caption 45,"GRAS":on_click 45,gras
check 46:left 46,340:top 46,10:font_size 46,9:font_bold 46:caption 46,"RAYÉ":on_click 46,raye
check 47:left 47,400:top 47,10:font_size 47,9:font_bold 47:caption 47,"ITALIQUE":on_click 47,ital
check 48:left 48,480:top 48,10:font_size 48,9:font_bold 48:caption 48,"SOULIGNÉ":on_click 48,soul

alpha 60:left 60,50:top 60,735:font_bold 60:caption 60,"Couleur de fond"
scroll_bar 61:left 61,5:top 61,760:width 61,256:min 61,0:max 61,255:position 61,255:on_change 61,fond
scroll_bar 62:left 62,5:top 62,780:width 62,256:min 62,0:max 62,255:position 62,255:on_change 62,fond
scroll_bar 63:left 63,5:top 63,800:width 63,256:min 63,0:max 63,255:position 63,255:on_change 63,fond
alpha 081:left 081,265:top 081,760:font_name 081,"Consolas":font_color 081,255,0,0:font_bold 081
alpha 082:left 082,265:top 082,780:font_name 082,"Consolas":font_color 082,0,155,0:font_bold 082
alpha 083:left 083,265:top 083,800:font_name 083,"Consolas":font_color 083,0,0,255:font_bold 083
gosub fond

alpha 90:left 90,435:top 90,735:font_bold 90:caption 90,"Couleur police"
scroll_bar 91:left 91,390:top 91,760:width 91,245:min 91,0:max 91,255:on_change 91,font
scroll_bar 92:left 92,390:top 92,780:width 92,245:min 92,0:max 92,255:on_change 92,font
scroll_bar 93:left 93,390:top 93,800:width 93,245:min 93,0:max 93,255:on_change 93,font
alpha 101:left 101,640:top 101,760:font_name 101,"Consolas":font_color 101,255,0,0:font_bold 101
alpha 102:left 102,640:top 102,780:font_name 102,"Consolas":font_color 102,0,155,0:font_bold 102
alpha 103:left 103,640:top 103,800:font_name 103,"Consolas":font_color 103,0,0,255:font_bold 103
gosub font

edit 104:top 104,1:left 104,570:width 104,40:font_size 104,11:text 104,chx$
edit 105:top 105,1:left 105,700:width 105,40:font_size 105,11
button 106:top 106,1:left 106,615:width 106,80:caption 106,"HEX/DEC"
For i% =104 to 106:font_name i%,"Consolas":next i%
on_click 106,effet

End

texte:
tx$=text$(10):' text 10,tx$
if object_type(4)=3 then text 4,tx$
if object_type(4)=8 then print_target_is 0:delete 4:list 4:Top 4,635:Left 4,5:Width 4,we-40:Height 4,100:print_target_is 4:print "1-";tx$:print "2-";tx$:print "3-";tx$
if object_type(4)=4 then print_target_is 0:delete 4:memo 4:Top 4,635:Left 4,5:Width 4,we-40:Height 4,100:print_target_is 4:print tx$:print tx$
if object_type(4)=6 then caption 4,tx$
return

objet:
print_target_is 0:delete 4
if clicked(12)=1 then edit 4:Top 4,635:Left 4,5:Width 4,we-40:Height 4,100:text 4,tx$
if clicked(14)=1 then list 4:Top 4,635:Left 4,5:Width 4,we-40:Height 4,100:print_target_is 4:print "1-";tx$:print "2-";tx$:print "3-";tx$
if clicked(16)=1 then memo 4:Top 4,635:Left 4,5:Width 4,we-40:Height 4,100:print_target_is 4:print tx$:print tx$
if clicked(18)=1 then alpha 4:top 4,635:left 4,5:caption 4,tx$
gosub fond:gosub font:gosub taille:gosub gras:gosub raye:gosub ital:gosub soul
return

effet:
chx$=text$(104)
for i%=1 to len(chx$):a$=mid$(chx$,i%,1):a$=upper$(a$)
if a$<>"0" and a$<>"1" and a$<>"2" and a$<>"3" and a$<>"4" and a$<>"5" and a$<>"6" and a$<>"7" and a$<>"8" and a$<>"9" and a$<>"A" and a$<>"B" and a$<>"C" and a$<>"D" and a$<>"E" and a$<>"F" then return
next i%
text 105,hex(chx$):Return

font:
cr%=position(91):cv%=position(92):cb%=position(93):font_color 4,cr%,cv%,cb%:caption 101,"ROUGE => "+str$(cr%):caption 102,"VERT ==> "+str$(cv%):caption 103,"BLEU ==> "+str$(cb%):return

fond:
fr%=position(61):fv%=position(62):fb%=position(63):color 4,fr%,fv%,fb%:caption 81,"ROUGE => "+str$(fr%):caption 82,"VERT ==> "+str$(fv%):caption 83,"BLEU ==> "+str$(fb%):return

gras:
font_bold_off 4:if checked(45)=1 then font_bold 4
return

raye:
font_strike_off 4:if checked(46)=1 then font_strike 4
return

ital:
font_italic_off 4:if checked(47)=1 then font_italic 4
return

soul:
font_underline_off 4:if checked(48)=1 then font_underline 4
return

taille:
if item_index(30)=0 then return
a=val(item_read$(30,item_index(30))):font_size 4,a:return

Debut:
Police$=LTRIM$(MID$(Item_Index$(1),2,100))
Afpol:
Font_Name 0,Police$:Font_Size 0,14:Print_Target_is 0:Display
' affichage des 256 caractères de la police
For j%=0 To 255 Step 16
    y%=ylp+ev*j%/16
    For i%=j% to j%+15:x%=xlp+eh*(i%-j%):Print_Locate x%,y%:Print Chr$(i%):Next i%
Next j%
Font_Name 4,Police$:Return
A+ Wink Wink Wink
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5623
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 13:32

Salut Bignono.


Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
bignono

avatar

Nombre de messages : 1109
Age : 60
Localisation : Val de Marne
Date d'inscription : 13/11/2011

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 14:20

je suis
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 5121
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 15:39

J'ai testé vos 2 programmes et je suis pas content Evil or Very Mad

Quand je vous donne du boulot j'aimerais qu'il ne soit pas baclé. lol!


Bon, je déconne, et si je suis pas content, je n'ai qu'a me le faire moi-même (le prog)


En fait il manque la valeur décimale d'un caractère (ce que faisait le prog initiale de JL35).
J'ai vu que Bignono a prévu un bouton HEX/DEC mais il semble qu'il ne fonctionne pas.

En tout cas Merci à vous deux de suivre mes caprices. Very Happy
Revenir en haut Aller en bas
Voir le profil de l'utilisateur En ligne
papydall

avatar

Nombre de messages : 5623
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 16:06

Salut Jean Claude.

Tes caprices peuvent être des ordres : pas de problème! king

J’au cru moi-même un instant que le bouton HEX/DEC ne fonctionnait pas. Embarassed
Mais, il fonctionne ! Idea

Clique à gauche du bouton HEX et introduit par exemple la valeur 32, puis clique sur HEX/DEC, il s’affiche à droite la valeur 50.
Donc 32 HEX = 50 DEC.
Et c’est CORRECT ! sunny


Dernière édition par papydall le Dim 6 Jan 2013 - 16:24, édité 1 fois
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Jean Claude

avatar

Nombre de messages : 5121
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 16:20

Bien vu Papydall,

J'adopte le programme qui rendra bien des services.

A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur En ligne
JL35



Nombre de messages : 6069
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 16:31

T'avais raison Papydall pour les variables qui ne servaient à rien, je les avais supprimées dans le dim mais j'avais oublié une ligne...

Bon, je regarde la dernière mouture de bignono.

Edit
Oui, pas mal bignono, belle synthèse des deux !
J'adopte, après quelques petites modifs mineures pour mon goût personnel.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
bignono

avatar

Nombre de messages : 1109
Age : 60
Localisation : Val de Marne
Date d'inscription : 13/11/2011

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 17:01

Ça, le goût personnel et les couleurs, ça ne se discute pas! Laughing Laughing Laughing
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
JL35



Nombre de messages : 6069
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 17:28

Je me suis ajouté le clic sur un caractère dans la table qui donne directement son code hex et dec.
Et j'ai remis l'affichage initial de la police Arial (qui apparaissait fugitivement avant d'être effacé).
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5623
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 17:42

JL35 a écrit:
Je me suis ajouté le clic sur un caractère dans la table qui donne directement son code hex et dec.
Et j'ai remis l'affichage initial de la police Arial (qui apparaissait fugitivement avant d'être effacé).

Tu t'es ajouté le clic.... Et tu le garde pour toi ?! Laughing
N'avons-nous pas le droit (ou le gauche !) pour en profiter? Crying or Very sad

Vas-y, un petit effort pour publier ton oeuvre!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
JL35



Nombre de messages : 6069
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 18:02

Oui, mais je suis reparti de mon programme qui n'est pas aussi beau que celui de bignono.
Bon, puisque tu insistes, en fait il suffit de cliquer sur un caractère du tableau pour avoir son code en haut à droite:
Code:
Rem Liste des polices système
dim i%, j%, k%, a$, Police$, np, we, he, xh, yh, eh, xv, yv, ev, tx$, x%, y%, xlp, ylp
DIM rf%, gf%, bf%, rc%, gc%, bc%, enr$, c$, sz%
label Debut, Afpol, Cfond, Ccar, Clicar, Reaff
tx$ = "Voyez Le Brick Géant Que J'Examine Près Du Wharf 0123456789"
we = 780: he = 810: width 0, we: height 0, he
Font_Name 0, "Courier New": Font_Size 0,14
Color 0,255,255,190: ON_CLICK 0, Clicar

Rem affichage de la liste des polices
list 1: left 1,5 : top 1, 4 : width 1, 220 : height 1, 630: ' liste des polices dispo
Font_Name 1, "Arial": Font_Size 1,10: Color 1,196,255,196
on_click 1, Debut

xh = 260 : yh = 38: eh = 30
xv = 240: yv = 60: ev = 36
Rem affichage des échelles horizontale et verticale
List 2: top 2, yh: left 2, xh: width 2, 490: height 2, 20
Font_Name 2, "Courier New": Font_Size 2, 12: Font_Color 2, 0, 0, 255
Font_Bold 2
List 3: top 3, yv: left 3, xv: width 3, 20: height 3, 570
Font_Name 3, "Courier New": Font_Size 3, 12: Font_Color 3, 0, 0, 255
Font_Bold 3
Print_Target_Is 2: Print " 0  1  2  3  4  5  6  7  8  9  A  B  C  D  E  F"
For i% = 0 To 15: Item_Add 3, Hex$(i%): Item_Add 3, "": Next i%
xlp = xh+13: ylp = yv
Rem exemple de texte
List 4: Top 4, 640: Left 4, 5: Width 4, we-30: Height 4,45: ' Texte exemple
List 5: Top 5, 5: Left 5, xh: Height 5, 28: Width 5, 300: ' Nom de police
Font_Name 5, "Arial Black": Font_Size 5, 12: Font_Color 5, 0, 0, 255
DLIST 6: FONT_NAMES_LOAD 6
np = COUNT(6): CAPTION 0, " " + STR$(np) + " polices de caractères"
Picture 9: top 9,-800
FOR i% = 1 TO np
    Police$ = ITEM_READ$(6, i%): FONT_NAME 9,Police$
    j% = TEXT_WIDTH("iiiiiiiiii",9): k% = TEXT_WIDTH("mmmmmmmmmm",9)
    IF j% = k%
        a$ = "F " + Police$: ' police à pas fixe
    ELSE
        a$ = "  " + Police$: ' police proportionnelle
    END_IF
    ITEM_ADD 1, a$
NEXT i%
DELETE 9
CONTAINER 9: TOP 9, TOP(4)+HEIGHT(4): LEFT 9,5: WIDTH 9,WIDTH(0)-22: HEIGHT 9,85
COLOR 9,255,192,192
ALPHA 10: PARENT 10,9: TOP 10,15: LEFT 10,5: CAPTION 10, "Fond:"
SCROLL_BAR 11: PARENT 11,9: TOP 11,TOP(10)+3: LEFT 11,60: WIDTH 11,190: height 11,14
MIN 11,0: MAX 11,255: POSITION 11,255: ON_CHANGE 11,Cfond
ALPHA 12: PARENT 12,9: TOP 12,TOP(10): LEFT 12,LEFT(11)+WIDTH(11):CAPTION 12,POSITION(11)
FONT_COLOR 12,192,0,0: FONT_BOLD 12
SCROLL_BAR 13:PARENT 13,9: TOP 13,TOP(11):LEFT 13,300: WIDTH 13,WIDTH(11): height 13,14
MIN 13,0: MAX 13,255: POSITION 13,255: ON_CHANGE 13,Cfond
ALPHA 14: PARENT 14,9: TOP 14,TOP(10):LEFT 14,LEFT(13)+WIDTH(13):CAPTION 14,POSITION(13)
FONT_COLOR 14,0,192,0: FONT_BOLD 14
SCROLL_BAR 15: PARENT 15,9: TOP 15,TOP(11):LEFT 15,530: WIDTH 15,WIDTH(11): height 15,14
MIN 15,0: MAX 15,255: POSITION 15,255: ON_CHANGE 15,Cfond
ALPHA 16: PARENT 16,9: TOP 16,TOP(10):LEFT 16,LEFT(15)+WIDTH(15):CAPTION 16,POSITION(15)
FONT_COLOR 16,0,0,255: FONT_BOLD 16

ALPHA 20: PARENT 20,9: TOP 20,TOP(10)+20: LEFT 20,5: CAPTION 20, "Carac:"
SCROLL_BAR 21: PARENT 21,9: TOP 21,TOP(20)+3: LEFT 21,LEFT(11): WIDTH 21,WIDTH(11): height 21,14
MIN 21,0: MAX 21,255: POSITION 21,0: ON_CHANGE 21, Ccar
ALPHA 22: PARENT 22,9: TOP 22,TOP(20):LEFT 22,LEFT(12):CAPTION 22,POSITION(21)
FONT_COLOR 22,192,0,0: FONT_BOLD 22
SCROLL_BAR 23: PARENT 23,9: TOP 23,TOP(21):LEFT 23,LEFT(13): WIDTH 23,WIDTH(13): height 23,14
MIN 23,0: MAX 23,255: POSITION 23,0: ON_CHANGE 23, Ccar
ALPHA 24: PARENT 24,9: TOP 24,TOP(20):LEFT 24,LEFT(14):CAPTION 24,POSITION(23)
FONT_COLOR 24,0,192,0: FONT_BOLD 24
SCROLL_BAR 25: PARENT 25,9: TOP 25,TOP(21):LEFT 25,LEFT(15): WIDTH 25,WIDTH(15): height 25,14
MIN 25,0: MAX 25,255: POSITION 25,0: ON_CHANGE 25, Ccar
ALPHA 26: PARENT 26,9: TOP 26,TOP(20):LEFT 26,LEFT(16):CAPTION 26,POSITION(25)
FONT_COLOR 26,0,0,255: FONT_BOLD 26

ALPHA 27: PARENT 27,9: TOP 27,TOP(20)+20: LEFT 27,5: CAPTION 27,"Taille:"
font_name 27,"Verdana": font_size 27,12
SPIN 28: PARENT 28,9: TOP 28,TOP(27): LEFT 28,LEFT(11): WIDTH 28,50: HEIGHT 28, 168
MIN 28,6: MAX 28,30: sz% = 18: POSITION 28, sz%: ON_CHANGE 28, Reaff

CHECK 30: PARENT 30,9: TOP 30,TOP(20)+25: LEFT 30,150: CAPTION 30, "Gras"
CHECK 31: PARENT 31,9: TOP 31,TOP(30): LEFT 31,280: CAPTION 31, "Italique"
CHECK 32: PARENT 32,9: TOP 32,TOP(30): LEFT 32,410: CAPTION 32, "Souligné"
CHECK 33: PARENT 33,9: TOP 33,TOP(30): LEFT 33,540: CAPTION 33, "Barré"
FOR i% = 30 TO 33: ON_CLICK i%, Reaff: NEXT i%
enr$ = "0000"
for i% = 10 to 16 step 2: font_name i%, "Verdana": font_size i%,12: next i%
for i% = 20 to 28 step 2: font_name i%, "Verdana": font_size i%,12: next i%
for i% = 30 to 33: font_name i%, "Verdana": font_size i%,12: next i%

ALPHA 40: TOP 40,-2: LEFT 40,xh+405: FONT_SIZE 40,8:CAPTION 40,"Hex    Dec"
LIST 41: TOP 41,2: LEFT 41,xh+350: WIDTH 41,45: HEIGHT 41,30
FONT_COLOR 41,192,0,0: FONT_SIZE 41,18
LIST 42: TOP 42,10: LEFT 42,LEFT(41)+45: WIDTH 42,45: HEIGHT 42,23
LIST 43: TOP 43,10: LEFT 43,LEFT(42)+50: WIDTH 43,45: HEIGHT 43,23
FONT_NAME 42,"Lucida Console": FONT_NAME 43,"Lucida Console"

Police$ = "Arial": Gosub Afpol
End

Debut:
Police$= LTRIM$(MID$(Item_Index$(1),2,100)): ' choix d'une police dans la liste
Afpol:
Font_Name 0, Police$
Font_Size 0, 14
Print_Target_is 0
Display
Rem affichage des 256 caractères de la police
For j% = 0 To 255 Step 16
    y% = ylp + ev*j%/16
    For i% = j% to j% + 15
        x% = xlp + eh * (i%-j%)
        Print_Locate x%, y%: Print Chr$(i%)
    Next i%
Next j%
sz% = POSITION(28)
Font_Name 4, Police$: Font_Size 4, sz%: Print_Target_Is 4
Clear 4: Print_Locate 5, 5: Print tx$
Clear 5: Print_Target_Is 5: Print " " + Police$
Return

Cfond:
rf% = POSITION(11): gf% = POSITION(13): bf% = POSITION(15)
CAPTION 12, STR$(rf%): CAPTION 14, STR$(gf%): CAPTION 16, STR$(bf%)
COLOR 4, rf%, gf%, bf%
RETURN

Ccar:
rc% = POSITION(21): gc% = POSITION(23): bc% = POSITION(25)
CAPTION 22, STR$(rc%): CAPTION 24, STR$(gc%): CAPTION 26, STR$(bc%)
FONT_COLOR 4, rc%, gc%, bc%
RETURN

Clicar:
x% = MOUSE_X_POSITION(0): y% = MOUSE_Y_POSITION(0)
IF x%<xlp OR x%>(xlp+eh*16) OR y%<ylp OR y%>(ylp+ev*16) THEN RETURN
CLEAR 41: CLEAR 42: CLEAR 43
x% = x%-6: y% = y%-10
x% = x%-xlp: x% = x%/eh: IF x% > 15 THEN x% = 15: ' colonne
y% = y%-ylp: y% = y%/ev: IF y% > 15 THEN y% = 15: ' rangée
i% = x% + 16*y%: ITEM_ADD 42," "+RIGHT$("0"+HEX$(i%),2): ' caractère, hexa
ITEM_ADD 43, STR$(i%): ' décimal
FONT_NAME 41,Police$: ITEM_ADD 41," "+CHR$(i%)
RETURN

Reaff:
IF POSITION(28) <> sz% THEN sz% = POSITION(28): FONT_SIZE 4, sz%
a$ = "0": IF CHECKED(30) = 1 THEN a$ = "1"
c$ = "0": IF CHECKED(31) = 1 THEN c$ = "1"
a$ = a$ + c$
c$ = "0": IF CHECKED(32) = 1 THEN c$ = "1"
a$ = a$ + c$
c$ = "0": IF CHECKED(33) = 1 THEN c$ = "1"
a$ = a$ + c$
IF a$ <> enr$
    FONT_BOLD_OFF 4: FONT_ITALIC_OFF 4: FONT_UNDERLINE_OFF 4: FONT_STRIKE_OFF 4
    IF CHECKED(30) = 1 THEN FONT_BOLD 4
    IF CHECKED(31) = 1 THEN FONT_ITALIC 4
    IF CHECKED(32) = 1 THEN FONT_UNDERLINE 4
    IF CHECKED(33) = 1 THEN FONT_STRIKE 4
    enr$ = a$
END_IF
RETURN

Edit, déjà une petite modif.
... encore une...

Màj 20h00 pour les polices des enrichissements qui fluctuaient...
23h20: ajout de la possibilité de choisir la taille des caractères du texte exemple (le brick géant)


Dernière édition par JL35 le Lun 7 Jan 2013 - 1:19, édité 3 fois
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5623
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 18:08

Ben ! Voila!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
JL35



Nombre de messages : 6069
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 18:13

Encore une petite modif, mais c'est juste esthétique (chiffres des codes plus lisibles)
sous les applaudissements de Papydall... Embarassed
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5623
Age : 67
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 19:24

Tu penses aux Panoramiciens à lunettes. MERCI.
J’en connais au moins un qui sera content. Laughing
Est-ce que tu en fais partie, toi ? Very Happy
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
JL35



Nombre de messages : 6069
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 19:40

Bien sûr ! et j'aime bien que ce soit bien lisible, j'ai tendance à tout mettre en 'bold', et en plus j'ai la chance d'avoir un grand écran.
Il y a encore quelques petits trucs: par exemple j'avais mis un Timer sur les Check des enrichissements, c'est idiot, il faut mettre un On_Click comme a fait bignono.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
bignono

avatar

Nombre de messages : 1109
Age : 60
Localisation : Val de Marne
Date d'inscription : 13/11/2011

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 20:39

Bon j'ai pris la manière de JL35 pour l'affichage hex/dec et je l'ai tout de suite intégré à mon programme! Mais ton programme est très bien aussi JL35.
Code:
' Liste des polices système
dim a,i%,j%,k%,a$,Police$,np,we,he,xh,yh,eh,xv,yv,ev,tx$,x%,y%,xlp,ylp,fr%,fv%,fb%,cr%,cv%,cb%,chx$
label Debut,Afpol,taille,gras,raye,ital,soul,fond,font,objet,texte,clicar
tx$="Portez ce vieux whisky au juge blond qui fume"
' tx$="Voyez Le Brick Géant Que J'Examine Près Du Wharf 0123456789"
we=783:he=860:width 0,we:height 0,he:font_name 0,"Courier New":Font_Size 0,14:Color 0,255,255,190:on_click 0,clicar

' affichage de la liste des polices
list 1:left 1,5:top 1,38:width 1,220:height 1,540:Font_Name 1,"Arial":Font_Size 1,10:Color 1,196,255,196:on_click 1,Debut
xh=260:yh=38:eh=30:xv=240:yv=60:ev=36
' affichage des échelles horizontale et verticale
List 2:top 2,yh:left 2,xh:width 2,490:height 2,20:Font_Name 2,"Courier New":Font_Size 2,12:Font_Color 2,0,0,255:Font_Bold 2
List 3:top 3,yv:left 3,xv:width 3,20:height 3,570:Font_Name 3,"Courier New":Font_Size 3,12:Font_Color 3,0,0,255:Font_Bold 3
Print_Target_Is 2: Print " 0  1  2  3  4  5  6  7  8  9  A  B  C  D  E  F"
For i%=0 To 15:Item_Add 3,Hex$(i%):Item_Add 3,"":Next i%
xlp=xh+13:ylp=yv
' exemple de texte
edit 4:Top 4,635:Left 4,5:Width 4,we-40:Height 4,100:font_name 4,"Arial":text 4,tx$
DLIST 6:FONT_NAMES_LOAD 6:np=COUNT(6):CAPTION 0," "+STR$(np)+" polices de caractères"
Picture 9:top 9,-800
FOR i%=1 TO np
    Police$=ITEM_READ$(6,i%):FONT_NAME 9,Police$:j%=TEXT_WIDTH("iiiiiiiiii",9):k%=TEXT_WIDTH("mmmmmmmmmm",9)
    IF j%=k%:a$="F "+Police$:ELSE:a$="  " +Police$:END_IF
    ITEM_ADD 1,a$
NEXT i%
DELETE 9:Police$="Arial":Gosub Afpol

edit 10:left 10,5:top 10,4:width 10,220:font_name 10,"Consolas":font_size 10,10:text 10,tx$:on_change 10,texte

button 12:left 12,15:top 12,580:font_name 12,"Consolas":caption 12,"EDIT":on_click 12,objet
button 14:left 14,15:top 14,605:font_name 14,"Consolas":caption 14,"LIST":on_click 14,objet
button 16:left 16,width(12)+50:top 16,580:font_name 16,"Consolas":caption 16,"MEMO":on_click 16,objet
button 18:left 18,width(14)+50:top 18,605:font_name 18,"Consolas":caption 18,"ALPHA":on_click 18,objet

combo 30:left 30,230:width 30,40:font_size 30,10:for a=6 to 50:item_add 30,str$(a):next a:text 30,"10":on_change 30,taille

ALPHA 40: TOP 40,-2: LEFT 40,xh+405:font_name 40,"Consolas":FONT_SIZE 40,8:CAPTION 40,"Hex    Dec"
LIST 41: TOP 41,5: LEFT 41,xh+350: WIDTH 41,45: HEIGHT 41,28
FONT_COLOR 41,255,0,0
LIST 42: TOP 42,10: LEFT 42,LEFT(41)+45: WIDTH 42,45: HEIGHT 42,23
LIST 43: TOP 43,10: LEFT 43,LEFT(42)+50: WIDTH 43,45: HEIGHT 43,23
FONT_NAME 42,"Lucida Console": FONT_NAME 43,"Lucida Console"

check 45:left 45,280:top 45,10:font_size 45,9:font_bold 45:caption 45,"GRAS":on_click 45,gras
check 46:left 46,340:top 46,10:font_size 46,9:font_bold 46:caption 46,"RAYÉ":on_click 46,raye
check 47:left 47,400:top 47,10:font_size 47,9:font_bold 47:caption 47,"ITALIQUE":on_click 47,ital
check 48:left 48,480:top 48,10:font_size 48,9:font_bold 48:caption 48,"SOULIGNÉ":on_click 48,soul

alpha 60:left 60,50:top 60,735:font_bold 60:caption 60,"Couleur de fond"
scroll_bar 61:left 61,5:top 61,760:width 61,256:min 61,0:max 61,255:position 61,255:on_change 61,fond
scroll_bar 62:left 62,5:top 62,780:width 62,256:min 62,0:max 62,255:position 62,255:on_change 62,fond
scroll_bar 63:left 63,5:top 63,800:width 63,256:min 63,0:max 63,255:position 63,255:on_change 63,fond
alpha 081:left 081,265:top 081,760:font_name 081,"Consolas":font_color 081,255,0,0:font_bold 081
alpha 082:left 082,265:top 082,780:font_name 082,"Consolas":font_color 082,0,155,0:font_bold 082
alpha 083:left 083,265:top 083,800:font_name 083,"Consolas":font_color 083,0,0,255:font_bold 083
gosub fond

alpha 90:left 90,435:top 90,735:font_bold 90:caption 90,"Couleur police"
scroll_bar 91:left 91,390:top 91,760:width 91,245:min 91,0:max 91,255:on_change 91,font
scroll_bar 92:left 92,390:top 92,780:width 92,245:min 92,0:max 92,255:on_change 92,font
scroll_bar 93:left 93,390:top 93,800:width 93,245:min 93,0:max 93,255:on_change 93,font
alpha 101:left 101,640:top 101,760:font_name 101,"Consolas":font_color 101,255,0,0:font_bold 101
alpha 102:left 102,640:top 102,780:font_name 102,"Consolas":font_color 102,0,155,0:font_bold 102
alpha 103:left 103,640:top 103,800:font_name 103,"Consolas":font_color 103,0,0,255:font_bold 103
gosub font

End

texte:
tx$=text$(10)
if object_type(4)=3 then text 4,tx$
if object_type(4)=8 then print_target_is 0:delete 4:list 4:Top 4,635:Left 4,5:Width 4,we-40:Height 4,100:print_target_is 4:print "1-";tx$:print "2-";tx$:print "3-";tx$
if object_type(4)=4 then print_target_is 0:delete 4:memo 4:Top 4,635:Left 4,5:Width 4,we-40:Height 4,100:print_target_is 4:print tx$:print tx$
if object_type(4)=6 then caption 4,tx$
return

objet:
print_target_is 0:delete 4
if clicked(12)=1 then edit 4:Top 4,635:Left 4,5:Width 4,we-40:Height 4,100:text 4,tx$
if clicked(14)=1 then list 4:Top 4,635:Left 4,5:Width 4,we-40:Height 4,100:print_target_is 4:print "1-";tx$:print "2-";tx$:print "3-";tx$
if clicked(16)=1 then memo 4:Top 4,635:Left 4,5:Width 4,we-40:Height 4,100:print_target_is 4:print tx$:print tx$
if clicked(18)=1 then alpha 4:top 4,635:left 4,5:caption 4,tx$
gosub fond:gosub font:gosub taille:gosub gras:gosub raye:gosub ital:gosub soul
return

Clicar:
x% = MOUSE_X_POSITION(0): y% = MOUSE_Y_POSITION(0)
IF x%<xlp OR x%>(xlp+eh*16) OR y%<ylp OR y%>(ylp+ev*16) THEN RETURN
CLEAR 41: CLEAR 42: CLEAR 43
x% = x%-xlp: x% = x%/eh
y% = y%-ylp: y% = y%/ev
i% = x% + 16*y%: ITEM_ADD 42," "+RIGHT$("0"+HEX$(i%),2): ' caractère, hexa
ITEM_ADD 43, STR$(i%): ' décimal
FONT_NAME 41,Police$: ITEM_ADD 41," "+CHR$(i%)
RETURN

font:
cr%=position(91):cv%=position(92):cb%=position(93):font_color 4,cr%,cv%,cb%:caption 101,"ROUGE => "+str$(cr%):caption 102,"VERT ==> "+str$(cv%):caption 103,"BLEU ==> "+str$(cb%):return

fond:
fr%=position(61):fv%=position(62):fb%=position(63):color 4,fr%,fv%,fb%:caption 81,"ROUGE => "+str$(fr%):caption 82,"VERT ==> "+str$(fv%):caption 83,"BLEU ==> "+str$(fb%):return

gras:
font_bold_off 4:if checked(45)=1 then font_bold 4
return

raye:
font_strike_off 4:if checked(46)=1 then font_strike 4
return

ital:
font_italic_off 4:if checked(47)=1 then font_italic 4
return

soul:
font_underline_off 4:if checked(48)=1 then font_underline 4
return

taille:
if item_index(30)=0 then return
a=val(item_read$(30,item_index(30))):font_size 4,a:return

Debut:
Police$=LTRIM$(MID$(Item_Index$(1),2,100))
Afpol:
Font_Name 0,Police$:Font_Size 0,14:Print_Target_is 0:Display
' affichage des 256 caractères de la police
For j%=0 To 255 Step 16
    y%=ylp+ev*j%/16
    For i%=j% to j%+15:x%=xlp+eh*(i%-j%):Print_Locate x%,y%:Print Chr$(i%):Next i%
Next j%
Font_Name 4,Police$:Return
A+ Wink Wink Wink
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 5121
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 21:02

Bravo Bignono,

Tu remportes une petite victoire sur JL35 Very Happy (Je vais me faire incendier) Mais je donne les preuves.

Regarder ces 2 images et vous allez voir la différence entre les 2.

Merci à vous deux car maintenant c'est nickel. Que c'est beau le travail en commun (Moi qui suggère et ne fait rien Razz et Bignono et JL35 qui bossent cheers )





Un truc bizarre avec ma copie d'écran PipPick: on ne vois pas les caractéres dans le memo. En réalité ils existent.
Ce que je voulais montrer c'est que la police s'applique aux mots gras, italique... dans le programme de JL35. Ce qui est un inconvénient si on sélectionne certaines polices.

A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur En ligne
JL35



Nombre de messages : 6069
Localisation : 77
Date d'inscription : 29/11/2007

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 21:56

Oui Jean Claude, tu as raison et j'avais déjà corrigé (chez moi) tout à l'heure, d'ailleurs je vais corriger mon source ci-dessus, tu pourras réessayer.
Et Il me semble que les deux programmes sont à peu près équivalents.

Qu'est-ce que c'est cette copie d'écran avec PipPick ??? Pourquoi tu ne fais pas une copie avec Alt/Impécr, c'est bien plus simple... et ici plus exact !
comme ça (tu vois, c'est corrigé):
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 5121
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: passez à la loupe ses polices de caratères   Dim 6 Jan 2013 - 22:13

Je constate que la copie d'écran avec PicPick n'est pas fidèle (je vais regarder pour une mise à jour). Si j'emploie PicPick c'est parce qu'il il y a une fonction Zoom qui permet de réduire l'image en pourcentage.

Te voila à égalité avec Bignono Very Happy

En tous cas vos programmes sont, certes pratiquement identiques, (fusion oblige), mais ils sont surtout utiles pour faire des choix de police.

BRAVO à tous les deux.

Revenir en haut Aller en bas
Voir le profil de l'utilisateur En ligne
Contenu sponsorisé




MessageSujet: Re: passez à la loupe ses polices de caratères   

Revenir en haut Aller en bas
 
passez à la loupe ses polices de caratères
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 1 sur 3Aller à la page : 1, 2, 3  Suivant
 Sujets similaires
-
» passez à la loupe ses polices de caratères
» Dragnifier (loupe)
» [Résolu] Word : polices mégafonts
» Taille des polices pour Print dans un Picture
» sprite loupe

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Vos sources, vos utilitaires à partager-
Sauter vers: