FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» I Love You
par JL35 Jeu 19 Oct 2017 - 16:25

» MARK_ON déclenche un événement ON_CLICK à la place de ...
par Jean Claude Mer 18 Oct 2017 - 18:08

» mise a jour calculatrice
par joeeee2017 Mer 18 Oct 2017 - 15:57

» [solved] 3D_LINE How to ?
par Jicehel Mer 18 Oct 2017 - 11:01

» Convertisseur de base 10 de 2 à 36
par gigi75 Mar 17 Oct 2017 - 18:49

» calculatrice avec touches movibles
par joeeee2017 Dim 15 Oct 2017 - 1:11

» CORTANA
par gigi75 Sam 14 Oct 2017 - 16:32

» Calculatrice
par Jean Claude Sam 14 Oct 2017 - 12:30

» Compilateur FBPano
par jean_debord Jeu 12 Oct 2017 - 9:53

» KGF_dll - nouvelles versions
par Klaus Mar 10 Oct 2017 - 18:49

» à propos de Panoramic_Editor [Résolu]
par Klaus Mar 10 Oct 2017 - 3:19

» Un petit "coucou" à tous les Panoramiciens !
par Jack Ven 6 Oct 2017 - 10:24

» Pourquoi le compilateur stagne
par mindstorm Mer 4 Oct 2017 - 20:38

» Panoramic ?
par Marc37 Mer 4 Oct 2017 - 0:39

» Premiers pas avec Arduino
par Marc37 Mer 4 Oct 2017 - 0:29

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Octobre 2017
LunMarMerJeuVenSamDim
      1
2345678
9101112131415
16171819202122
23242526272829
3031     
CalendrierCalendrier

Partagez | 
 

 Un "PAGICIEL" Parcourt de pages Panoramic

Voir le sujet précédent Voir le sujet suivant Aller en bas 
Aller à la page : Précédent  1, 2, 3, 4  Suivant
AuteurMessage
Invité
Invité



MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   Jeu 23 Aoû 2012 - 8:23

Je pense qu'il y a un bug au niveau de la fonction TOP() d'un objet, lorsqu'on est en dehors de l'écran.

J'ai passé un bout de temps hier, en ayant ceci pour la procédure y
Code:

y:
  a%=item_index(105)
  y%=(a%-1)*i%
  for obj% = 1 to 20 step  1
      t%= top(obj%)  :h%= top(obj%) +  height(obj%) :item_add obj%,"maintenant top="+str$(t%)+"  top+height="+str$(h%)
      if y% >= t% and y% <= h% then exit_for
  next obj%
  if obj% < 21 then caption 0,"li:"+str$(a%)+" : y%="+str$(y%)+" => " +"    / / objet: " + str$(obj%)
return
Et là ça ne marche pas. A moins que je comprend mal ce que je fais, mais cela devrait être la même chose, surtout qu'en demandant le top d'un objet qui commence à 100, j'avais 98 je crois.

edit: j'ai rajouté une ligne dans chaque memo, lorsqu'on clic sur le list de gauche, et on voit que le top d'un objet ne convient plus. A mon avis, c'est pour Jack, pas sur cette variable que cela devrait jouer, mais sur une table interne pour la représentation.
Bon il est de penser au boulot!
Revenir en haut Aller en bas
Invité
Invité



MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   Jeu 23 Aoû 2012 - 19:24

Bonjour les gars.

Heureusement que je n'ai pas eu le temps de mettre le problème sur top() dans les bug, vu que vous ne semblez pas d'accord. C'est donc que je me suis trompé.

D'ailleurs, je pense que ce post ne vous plait pas. Aussi je mettrez juste mettre un lien de mon travail sur pagiciel, en grès des avancements, pour ne plus poluer ici, comme je le fais. Si quelqu'un est intéressé, il n'aura qu'à aller voir sur le lien, lors que je l'aurai mis, pour prendre la dernière version.
Je retourne sur ma planète.
Revenir en haut Aller en bas
Yannick

avatar

Nombre de messages : 7994
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Jeu 23 Aoû 2012 - 21:46

@ Cosmos,

Ce n'est pas que je ne m'intéresse pas à ton travail mais je n'ai pas tout suivi.
En plus je ne me crois pas assez compétent pour ramener ma science vu les
bourdes grossières que je publie de temps en temps.
Je vais jeter un oeil ( heu...faudra me le rendre... Laughing ) sur ton schmilblick vu que
je plante sur le mien et que j'ai fini ( sous réserve de commentaires de papydall... Laughing )
le précédent.

Je te repost si je vois un truc Suspect
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 7994
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Jeu 23 Aoû 2012 - 21:51

Pourrais tu mettre le code complet quelque part ?
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jicehel

avatar

Nombre de messages : 5858
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   Jeu 23 Aoû 2012 - 23:00

Pareil Cosmos, ne crois pas que l'on ne s’intéresse pas à ton travail, mais tu t'attaques toujours à des gros trucs bien compliqué ... alors pour aider, il faut comprendre et trouver alors que tu maitrise largement autant que nous ... et en plus ça prends beaucoup de temps.
Alors désolé Cosmos, ça nous intéresse mais on a du mal à t'aider (je dis nous car je pense que plusieurs personnes sont dans mon cas, mais je n'inclue pas tout le monde ....)
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Invité
Invité



MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   Jeu 23 Aoû 2012 - 23:05

Il n'y a pas de problème avec toi en particulier, mais sur le forum, il y a forcément quelqu'un pour donner son avis. Il y a maintenant 3 ans que je suis inscrit. Combien de fois je suis intervenu pour répondre à un problème, ou pour donner mon avis?

Planète Panoramique, je pense qu'ici je perd mon temps. Combien de programme que j'ai publié, sans avoir la moindre idée de savoir ce qu'on en pense. Quand je dis: ce qu'on pense, je parle de vérité, et non pas de douceur, alors qu'on a envie de dire: "tu me fais chier: (en toute lettres) avec ton programme, ou tes conneries". Car là je saurai que j'ai fait une erreur, et que mes programmes ne sont pas intéressant. Surement que je dérange, dont je vais de plus en plus me faire discret. Je mettrais un lien sur mon programme, de cette façon si le post est bloqué, il sera toujours possible de cliquer sur le lien, pour être à jour, pour le cas peu probable que cela intéressera quelqu'un. Il faut que je prenne l'habitude de rester à l'écart. Si Panoramic devient une drogue, c'est qu'en même pas une drogue dure! Nos intérêts sont différents, et je vais essayer de m'abtenir.

Bonsoir Planète Panoramic. Je vous salut du cosmos, tout en restant les pieds sur terre. Un exploit très difficile à faire.

@Ygeronimi: Pour la nouvelle version, il y a encore des chose à apporter, avant de mettre le code. Je suis surtout intervenu, à propos de ce que je considère un bug, mais peut-être que je n'ai pas vraiment compris l'instruction TOP() qui pourrait être modifiable selon la grandeur de la forme sur lequel est posé l'objet. Je ne l'avais pas vu ainsi.
Revenir en haut Aller en bas
Yannick

avatar

Nombre de messages : 7994
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Ven 24 Aoû 2012 - 0:32

Perso, ce que j'ai compris de top() c'est qu'elle renvoie la distance entre le point 0 du parent et le point 0 du client.


Si je créée un picture sur le form 0 , top(picture) me renvoie la distance en pixels entre le point 0 du cadre de travail
de la forme 0 et le coin en haut à gauche du picture.

maintenant, il n'y a qu'à voir grid et consors, certains objets même si tu les places en 0,0 sur form 0
tu n'est pas à raz le cadre de travail de la form 0
ceci est gênant car on travail à l'oeil et le cadre de l'objet n'est pas visible donc pour ces objets top() peut te dire 0
mais visuellement c'est 10 ou 15 pour ton oeil.

Je pense que lors de la création de certains objets comme ceux ci, l'execution par l'éditeur devrait montrer un cadre
en pointillés qui disparait dans un *.exe , un peu comme un preview.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 7994
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Ven 24 Aoû 2012 - 0:46

Autre chose,

Ton pagiciel m'intéresse, ET C EST VRAI !, je n'ai pas l'habitude caresser les gens dans le sens du poil.
Je ne suis pas fan des trucs de musique, j'ai jamais fait de solfège ( trop nul pale ) je ne composerai pas
un menuet demain mais j'essaie quand je peux, quand je sais ( c'est plus rare Crying or Very sad ) de répondre et d'aider.
Si quelque chose m'emmerde je le dis AUSSI mais comme je viens aussi pour apprendre, je lis les codes
je les détruit, je les recompose en y ajoutant un truc ou un autre pour voir ce que çà donne ( je ne te dis pas combien
de fois je passe par la case "gestionnaire de tâches" à tuer des processus Wink ).

Bref ton schmilblick (c'est pas péjoratif ) m'intéresse car chez moi , comme chez beaucoup d'autres je pense, c'est le boxon
dans les fichiers. Ton truc pourrait nous apporter une solution.

Aller, sur ce je retourne au dernier bug que je me suis auto-créé.... Laughing Laughing Laughing
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Invité
Invité



MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   Ven 24 Aoû 2012 - 3:05

Je reprend. Je crois que tu n'as pas vu le problème.
Dans l'exemple que j'ai mis, et que voici:
Code:

full_space 0  :width 0,380
label y
dim a% ,y% ,obj% ,i%,  t% , h%  ,g%(25,1)
i%=13
for a% = 1 to 20
  memo a%:left a%,30:top a%,a%*100:width a%,200:height a%,80 :g%(a%,0)=a%*100 : g%(a%,1)= g%(a%,0)+80
  item_add a%,a%
  item_add a%,"top="+str$(top(a%))
  item_add a%,"top+height="+str$(top(a%)+height(a%))
next a%

list 105:width 105,20:font_size 105,2:height 105,2050
color 105,color_pixel_red(0,20,100),color_pixel_green(0,20,100),color_pixel_blue(0,20,100)-20
font_color 105,color_pixel_red(0,20,100),color_pixel_green(0,20,100),color_pixel_blue(0,20,100)

for a%=1 to 1000:item_add 105,"":next a%
on_click 105,y

end
y:
  a%=item_index(105)
  y%=(a%-1)*i%
  for obj% = 1 to 20 step  1
    if count(obj%)>3 then item_delete obj%,count(3)
  '  t%= g%(obj%,0)  :h%= g%(obj%,1)
      t%= top(obj%)  :h%= top(obj%) +  height(obj%) :item_add obj%,"maintenant top="+str$(t%)+"  top+height="+str$(h%) +chr$(0)
      if y% >= t% and y% <= h% then exit_for
  next obj%
  if obj% < 21 then caption 0,"li:"+str$(a%)+" : y%="+str$(y%)+" => " +"  / objet:" + str$(obj%)
return
En mettant la ligne 25 en commentaire, qui donne le bon résultat, si tu décale l'écran avec l'ascenseur, pour cliquer sur le list de gauche, en face d'un memo, tu regardes le résultat du top, tel que le programme lit à ce moment là, et cela ne correspond pas du tout au top de l'objet qui est défini.
Tant que le décalage de l'écran n'intervient pas, cela est bon, mais si on décale l'écran pour voir les objets plus bas, ceux qu'on ne voit pas au départ, le top défini, n'est plus le même.


La limite d'écran qui n'est plus limité n'apporte rien à mon sens. Si on place un objet alors que l'écran est décalé, il n'est pas à la bonne place. J'ai déjà eu ce problème.

Maintenant, en retirant l'apostrophe de la ligne 25, pour la mettre sur la ligne suivante, là on peut repérer la position, et retrouver le n° de l'objet qui est devant. Chose que n'arrivais pas à faire avant. Sleep
Revenir en haut Aller en bas
Yannick

avatar

Nombre de messages : 7994
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Ven 24 Aoû 2012 - 3:31

Ton exemple ne fonctionne pas dans mon éditeur,
je n'ai pas d'affichage en caption 0
...et où que je clique... Suspect


Edit :

si çà y est, mais ton top() bouge pas car tu fais monter la fenêtre et pas l'objet...

si tu prends un carton et que tu écris une phrase,
ce n'est pas parce que tu tiens ton carton plus haut
que la phrase a changé de place sur le carton...
visuellement elle est plus haute car le support est plus haut
mais elle est toujours à la même place sur le support...
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Invité
Invité



MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   Ven 24 Aoû 2012 - 15:13

Ok, ça je l'avais compris. Seulement j'ai encore l'exemple en tête des problèmes que j'ai.
J'ai voulu savoir où on en était aujourd'hui, car je que je dis était en rapport à des cas réelles. Je pense entre-autre à ce que j'ai publié: un éditeur avec cellules. Il était alors impossible de savoir où je me trouvais, lorsque j'étais en dessous de l'écran.

Donc j'ai repris le programme plus haut, et je constate que des choses ont évoluées depuis. J'ai voulu savoir, si le positionnement d'un nouvel objet, était à la bonne place, lorsqu'on a décalé l'écran. C'est maintenant le cas, ce qui n'était pas toujours vrai. J'ai eu déja des objets placés en haut, alors qu'ils étaient sencés être dans la zone de l'écran. Et ce n'est plus le cas. Pourquoi: parce que maintenant, à chaque ajout d'un objet, la fenêtre se repositionne en haut.

Ensuite un picture: j'en ai placé un qui prend toute la hauteur, et lorsqu'on clique à n'importe qu'elle endroit, la position retenu est la bonne. Et l$ aussi grand changement par rapport à ce que je connaissais. J'ignore qu'en ces changements ont étés faites, mais j'étais pas au courant.

Ensuite j'ai vérifier en cliquant aussi sur la fenêtre. Là on voit la différence entre la fenêtre et le picture. En fait si on veut avoir une référence pour connaitre l'endroit où on se trouve, il suffit de mettre un picture sur tout l'écran, et là, la position du clic a un sens.

Maintenant que je suis au parfum de tous ces changements, je vais pouvoir reprndre mon programme en connaissance de cause.

Ce qui serait bien, ce serait d'avoir un programme de teste de l'ensemble des commandes dans toutes les circonstances, qu'on essayerait a chaque nouvelle version. Mais là c'est un autre problème.

Edit: j'ai oublié le programme.
Code:


full_space 0  :width 0,650
label y , ajout , cercle , zero  : on_click 0,zero
dim a% ,y% ,obj% ,i%,  t% , h%  ,g%(25,1) , nu% ,l% ,r,x,y
i%=13  : nu% = 31
for a% = 1 to 20
  memo a%:left a%,30:top a%,a%*100:width a%,200:height a%,80 :g%(a%,0)=a%*100 : g%(a%,1)= g%(a%,0)+80
  item_add a%,a%
  item_add a%,"top="+str$(top(a%))
  item_add a%,"top+height="+str$(top(a%)+height(a%))
next a%

list 105:width 105,20:font_size 105,2:height 105,2050
color 105,color_pixel_red(0,20,100),color_pixel_green(0,20,100),color_pixel_blue(0,20,100)-20
font_color 105,color_pixel_red(0,20,100),color_pixel_green(0,20,100),color_pixel_blue(0,20,100)

button  30:left 30,240:width 30,20:height 30,top(20)+height(20) :on_click 30,ajout

picture 35:left 35,400:width 35,200:height 35,top(20)+height(20) :on_click 35,cercle


for a%=1 to 1000:item_add 105,"":next a%
on_click 105,y

end
y:
  a%=item_index(105)
  y%=(a%-1)*i%
  for obj% = 1 to 20 step  1
    if count(obj%)>3 then item_delete obj%,count(3)
      t%= g%(obj%,0)  :h%= g%(obj%,1)
  '  t%= top(obj%)  :h%= top(obj%) +  height(obj%)
      item_add obj%,"maintenant top="+str$(t%)+"  top+height="+str$(h%) +chr$(0)
      if y% >= t% and y% <= h% then exit_for
  next obj%
  if obj% < 21 then caption 0,"li:"+str$(a%)+" : y%="+str$(y%)+" => " +"  / objet:" + str$(obj%)
return

ajout:
  if nu%<35
      picture nu%:left nu%,270+l%:top nu%,top(20):height nu%,50:color nu%,255,l%,l%
      nu%=nu%+1 :l%=l%+50
  end_if
return

cercle:
  2d_target_is 35 : print_target_is 35
  x=mouse_x_position(35)
  y=mouse_y_position(35)
  r=10
  2d_circle x,y,r
  print_locate x+15,y : print "y="+str$(y)
return
zero:
  2d_target_is 35 : print_target_is 0
  x=mouse_x_position(0)
  y=mouse_y_position(0)

  r=10
  2d_circle x,y,r
  print_locate x+15,y : print "y="+str$(y)
return
Revenir en haut Aller en bas
Yannick

avatar

Nombre de messages : 7994
Age : 46
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Ven 24 Aoû 2012 - 19:58

@ cosmos,

J'ai une petite suggestion à te faire...
lorsque l'un des objets est cliquable par l'utisateur et
qu'il n'est pas franchement visible, mets un "cursor_point"
comme çà on voit Shocked quand on est sur la zone de l'objet.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Invité
Invité



MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   Ven 7 Sep 2012 - 13:04

Je pose la question: avec MyDrive, comment vous avez fait pour mette un "@" dans le pseudo que vous donnez. Exemple: panoramic@tartenpion.
Systmatiquement, il y a un refus, sans compté qu'à chaque fois que j'ai voulu envoyer un programme sur un dossier que j'ai créé, QtWeb qui est un petit navigateur, vu que j'ai pas de place pour mettre ceux que vous utilisez, plante.
Je n'arrive pas à bien comprendre: il y a le nom de domaine en quelque sorte, mais c'est pas celui que vous mettez, sinon tout le monde pourrait modifier les fichiers.

Journée noire aujourd'hui! Non seulement le nouveau Panoramic attendu, me pose un problème, mais Pagiciel que je voulais envoyer ce soir, Plouf perdu! La dernière version est du 31 août et je venais de complètement débogger. tout marchait impécable, mais comme je n'ai pas de disque dur sur cet ordi, ce sont des mémoires flashs, pour éviter de tout le temps faire des sauvegardes dessus, je travaille avec un disque virtuel. De temps en temps je fais une copie sur une clé, mais ne voyant pas le temps passé, cela faisait une semaine qu'apparemment ce n'est pas fait. Là il y a un problème car j'ai une procédure pour cela et il faut que je la regarde de plus près.
Donc ce n'est pas ce soir que je mettrais ce programme. En tout cas, il est presque sûre qu'il ne tournera pas avec le new-Panoramic, vu qu'il devait être capable de lancer des sources. Rendez-vous compte, moi qui n'est pas de mémoire sur EEEPC, si il faut que je fasse un exécutable pour chaque programme, où je vais?

Je vais essayé de me calmer, là cela fait beaucoup! Je sais j'ai parfois une tête de cochon pig
Revenir en haut Aller en bas
Klaus

avatar

Nombre de messages : 10074
Age : 68
Localisation : Ile de France
Date d'inscription : 29/12/2009

MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   Ven 7 Sep 2012 - 13:12

Tu as raison, Cosmos70 - cette histoire de CHAIN/EXECUTE me gêne également énormément. J'avais pris l'habitude de générer dynamiquement des morceaux de code, j'avais développé (et publié sur le forum) un moyen de chaîner une ligne de code ou une portion plus longue comme un sous-programme, et cela ne marchera plus. A mon sens, Panoramic perd une souplesse et une fonctionnalité intéressante. J'ose espérer que Jack entendra nos remarques, Jack qui a toujours été tellement pointilleux avec la compatibilité ascendante...
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://klauspanoramic.comxa.com/index.html
Jicehel

avatar

Nombre de messages : 5858
Age : 45
Localisation : 77500
Date d'inscription : 19/04/2011

MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   Ven 7 Sep 2012 - 14:09

@klaus: pour cette discussion mieux vaut en parler dans l'autre sujet, je pense pour ne pas surcharger le post de Cosmos (Oui, je sais c'est moi qui dit ça alors que j'en suis le spécialiste)

@Cosmos: ça se rajoute tout seul quand tu créé ton compte invité. tu le nommes juste Panoramic et il va rajouter tout seul @cosmos70
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Invité
Invité



MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   Ven 7 Sep 2012 - 15:32

Merci Jicehel. Cette fois-ci c'est réussi.
Donc ce sera : panoramic@cosmos70
MDP: panoramic123
On verra plus tard. Il va falloir que je fasse un petit outils (où même vous) pour récupérer chaque adresse avec le mot de passe en collant dans le presse papier avec un bouton.
Revenir en haut Aller en bas
Klaus

avatar

Nombre de messages : 10074
Age : 68
Localisation : Ile de France
Date d'inscription : 29/12/2009

MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   Ven 7 Sep 2012 - 15:43

J'avais fait ceci, et je l'avais publié:
Code:
' Presse_papier.bas

label labels : gosub labels
gosub constantes
gosub variables
gosub donnees
gosub form0
gosub menu
gosub GUI
gosub initialisations

end

labels:
  label constantes, variables, donnees, form0, menu, GUI, initialisations
  label add_cb, rep_cb, cop_cb, sup_cb, hlp_cb, combo_sel
  return
 
constantes:
  dim titre$ : titre$ = "Mon presse-papier - "
  dim cr$ : cr$ = chr$(13)
  dim crlf$ : crlf$ = chr$(13)+chr$(10)
  dim crlflf$ : crlflf$ = chr$(13)+chr$(10)+chr$(10)
  return
 
variables:
  dim no%, no1%, no2%, i%, n%, s$, t$, sel_num%
  dim sel_typ% : ' 1=texte  2=image
  dim no_combo%, no_memo%, no_dlist%, no_picture%, no_visu%
  return

donnees:
  return

form0:
  border_small 0 : caption 0,titre$ + "0 confettis"
  width 0,800 : height 0,280
  return

menu:
  return

GUI:
  no% = no% + 1 : dlist no% : no_dlist% = no%
 
  no% = no% + 1 : combo no% : no_combo% = no%
    width no%,width(0)-20-200 : on_click no%,combo_sel
  no% = no% + 1 : memo no% : no_memo% = no%
    width no%,width(no_combo%) : bar_both no%
    height no%,200 : top no%,20
  no% = no% + 1 : button no% : caption no%,"Ajouter presse-papier"
    top no%,220 : left no%,0 : width no%,150 : on_click no%,add_cb
  no% = no% + 1 : button no% : caption no%,"Remplacer par presse-papier"
    top no%,220 : left no%,150 : width no%,150 : on_click no%,rep_cb
  no% = no% + 1 : button no% : caption no%,"Supprimer de confetti"
    top no%,220 : left no%,300 : width no%,150 : on_click no%,sup_cb
  no% = no% + 1 : button no% : caption no%,"Copier dans presse-papier"
    top no%,220 : left no%,450 : width no%,150 : on_click no%,cop_cb
  no% = no% + 1 : button no% : caption no%,"Aide"
    top no%,220 : left no%,600 : width no%,150 : on_click no%,hlp_cb
  no% = no% + 1 : picture no% : hide no% : no_picture% = no%
    width no%,200 : height no%,200 : top no%,20 : stretch_on no%
  no% = no% + 1 : picture no% : no_visu% = no%
    top no%,20 : left no%,width(no_memo%) : width no%,200 : height no%,200
    2d_target_is no_visu% :stretch_on no_visu%
  return

initialisations:
  return
 
combo_sel:
  n% = item_index(no_combo%)
  no1% = val(item_read$(no_dlist%,n%))
  sel_num% = no1%
  clear no_memo%
  if no1%<0
    sel_typ% = 2
    2d_image_paste 0-sel_num%,0,0
  else
    color no_visu%,255,255,255
    sel_typ% = 1
    for i%=1 to count(no1%)
      item_add no_memo%,item_read$(no1%,i%)
    next i%
  end_if
  return

add_cb:
  s$ = clipboard_string_paste$
  if s$=""
    clipboard_paste no_picture%
    if (color_pixel_red(no_picture%,0,0)=255) and (color_pixel_green(no_picture%,0,0)=255) and (color_pixel_blue(no_picture%,0,0)=255)
      message "Le presse-papier ne contient ni un texte ni une image valide."
      return
    end_if
    no% = no% + 1 : image no%
    clipboard_paste no%
    clipboard_paste no_visu%
    item_add no_dlist%,str$(0-no%)
    t$ = "Image no. "+str$(no%)
    item_add no_combo%,t$
    text no_combo%,t$
    clear no_memo%
    sel_typ% = 2
    sel_num% = 0 - no%
    caption 0,titre$ + str$(count(no_combo%))+" confettis"
    return
  end_if
  color no_visu%,255,255,255
  i% = instr(s$,cr$)
  if i%=0 then i% = len(s$)+1
  t$ = left$(s$,i%-1)
  no% = no% + 1 : dlist no%
  item_add no_dlist%,str$(no%)
  item_add no%,s$
  item_add no_combo%,t$
  text no_combo%,t$
  clear no_memo%
  item_add no_memo%,s$
  sel_typ% = 1
  sel_num% = no%
  caption 0,titre$ + str$(count(no_combo%))+" confettis"
  return
 
rep_cb:
  s$ = text$(no_combo%)
  if trim$(s$)=""
    message "Aucun confetti n'est sélectionné."
    return
  end_if
  if sel_typ%=1
    s$ = clipboard_string_paste$
    if s$=""
      message "Le presse-papier ne contient pas un texte valide."
      return
    end_if
    color no_visu%,255,255,255
    i% = instr(s$,cr$)
    if i%=0 then i% = len(s$)+1
    t$ = left$(s$,i%-1)
    n% = item_index(no_combo%)
    no1% = val(item_read$(no_dlist%,n%))
    clear no1%
    item_add no1%,s$
    item_delete no_combo%,n%
    item_insert no_combo%,n%,t$
    text no_combo%,t$
    clear no_memo%
    item_add no_memo%,s$
  else
    color no_picture%,255,255,255
    clipboard_paste no_visu%
    clipboard_paste no_picture%
    if (color_pixel_red(no_picture%,0,0)=255) and (color_pixel_green(no_picture%,0,0)=255) and (color_pixel_blue(no_picture%,0,0)=255)
      message "Le presse-papier ne contient pas une image valide."
      return
    end_if
    clipboard_paste (0-sel_num%)
  end_if
  return

cop_cb:
  s$ = text$(no_combo%)
  if trim$(s$)=""
    message "Aucun confetti n'est sélectionné."
    return
  end_if
  clipboard_string_copy "<Vide>"
  select sel_typ%
    case 1: ' texte
      s$ = ""
      for i%=1 to count(no_memo%)
        s$ = s$ + item_read$(no_memo%,i%) + crlf$
      next i%
'      clipboard_copy no_memo%
      clipboard_string_copy s$
    case 2: ' image
      clipboard_copy 0-sel_num%
  end_select
  return

sup_cb:
  if text$(no_combo%)="" then return
  if count(no_combo%)=0 then return
  n% = item_index(no_combo%)
  if n%=0 then return
  no1% = val(item_read$(no_dlist%,n%))
  clear no_memo%
  text no_combo%,""
  item_delete no_combo%,n%
  item_delete no_dlist%,n%
  delete no1%
  if n%>count(no_combo%) then n% = n% - 1
  if n%>0
    no1% = val(item_read$(no_dlist%,n%))
    sel_num% = no1%
    if sel_num%<0
      sel_typ% = 2
      2d_image_paste 0-sel_num%,0,0
    else
      color no_visu%,255,255,255
      sel_typ% = 1
      for i%=1 to count(no1%)
        item_add no_memo%,item_read$(no1%,i%)
      next i%
      text no_combo%,item_read$(no_memo%,1)
    end_if
  end_if
  caption 0,titre$ + str$(count(no_combo%))+" confettis"
  return
 
hlp_cb:
  s$ = "Bienvenu dans Mon Presse-papier !" + crlflf$
  s$ = s$ + "Cet outil gère des morceaux de texte ou des images," + crlf$
  s$ = s$ + "contenus dans le presse-papier." + crlf$
  s$ = s$ + "    Ajouter: créer un nouveau confetti."+crlf$
  s$ = s$ + "Remplacer: remplacer le confetti.sélectionné"+crlf$
  s$ = s$ + " Supprimer: supprimer un confetti."+crlf$
  s$ = s$ + "      Copier: copier le confetti sélectionné dans le presse-papier."+crlf$
  s$ = s$ + "          Aide: afficher ce texte."+crlf$
  message s$
  return

Le mieux, c'est de le générer en EXE, de le démarrer une fois au démarrage et de le laisser en route. Ainsi, ce remplacement du presse-papier est toujours disponible. On peut mettre des textes et des images.

Il lui manque que la sauvegarde/restitution sur disque, mais c'est facile à ajouter (une série de file_load et file_save).
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://klauspanoramic.comxa.com/index.html
Invité
Invité



MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   Ven 7 Sep 2012 - 15:53

Merci Klaus pour cet outil.
Ce qui serait bien, est de faire un essai en se servant de la DLL pour les touches.
Là je me disperse, je dois d'abord remettre au point mon programme, pendant que j'ai encore le cheminement des idées.

EDIT
Autre chose: je crois que je me suis tromper pour MyDrive, le compte invité, je l'ai réglé sur Red acces, mais je pense que ce devrait être Upload access.
Revenir en haut Aller en bas
Jean Claude

avatar

Nombre de messages : 5040
Age : 63
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   Ven 7 Sep 2012 - 16:57

@cosmos, et tout Panoramicien intéressé...

Voici un outil que j'ai fabriqué, il y a longtemps, il permet d'enregistrer ses liens préférés. Pour chaque nouvel enregistrement le programme te demande de copier/coller le liens internet, ensuite l'identifiant, le mot de passe, + un 3ème élément (certains sites ont besoin de 3 éléments) et pour finir le nom du site. Une fois enregistré le programme crée un bouton dont le Caption est le nom du site.
A l'utilisation il te suffira de cliquer le bouton correspondant au site choisi, ce qui ouvrira ton navigateur à la page que tu aura enregistrée et t'affichera dans un mémo les éléments que tu pourras copier/coller.

Conseil: mettre l'ex dans un dossier pour le fichier de stockage, et créer un raccourci sur le bureau.

De mémoire il me semble l'avoir déjà posté mais dans le doute je le met à disposition.
Code:
dim a$,b$,lien$,e1$,e2$,e3$,fi$,f,nbe,no,lig,nbb,pv$,n,lienp$
label new,new2,new3,new4,new5,new6,new7,new8,new9,new10,new11,init,go,aide
label modsup,md1,modif,sup,modlien,modlien2,modident,modident2,modident3
label modiMDP,modiMDP2,modiMDP3,modiel,modiel2,modiel3,modibuton,modibuton2
label modibuton3,fin,ferme_form,enregmodif
' ******************************************************************************
width 0,200:left 0,10:height 0,screen_y:caption 0,"Mémo Sites":on_close 0,fin
memo 100:height 100,80:width 100,140:top 100,20:left 100,20:color 100,250,250,0:font_color 100,0,0,255:font_size 100,10
button 101:height 101,15:width 101,15:top 101,50:left 101,170:caption 101,"+":font_bold 101:on_click 101,new
hint 101,"Enregistrement d'un nouveau site"
button 102:height 102,15:width 102,15:top 102,25:left 102,170:caption 102,"?":font_bold 102:on_click 102,aide
hint 102,"Aide"
button 103:height 103,15:width 103,15:top 103,75:left 103,170:caption 103,"M":font_bold 103:on_click 103,modsup
hint 103,"Modification ou Suppression d'un élément"
' ******************************************************************************
form 200:width 200,screen_x-100:top 200,50:left 200,50:height 200,390:caption 200,"Mémo Sites: Enregistrement":hide 200
command_target_is 200:on_close 200,ferme_form
alpha 201:top 201,10:left 201,10:caption 201,"Lien du site: collez ici le lien (EX:http://panoramic.free-boards.net/login)":font_name 201,fixedsys
edit 202:top 202,30:left 202,10:width 202,screen_x-130
hint 202,"Ouvrez votre navigateur internet à la page d'identification du Site à enregistrer."+chr$(13)+"Copiez le lien qui apparaît en haut de votre navigateur et collez-le ICI."
alpha 203:top 203,70:left 203,10:caption 203,"Identifiant d'accès au site:(EX:Tartempion01)":font_name 203,fixedsys
edit 204:top 204,90:left 204,10:width 204,200
hint 204,"Entrez votre identifiant"+chr$(13)+"Correspondant au Site (Sortie par Entrée)."
hide 203:hide 204
alpha 205:top 205,130:left 205,10:caption 205,"Mot de Passe d'accès au site:(EX:123456Z)":font_name 205,fixedsys
edit 206:top 206,150:left 206,10:width 206,200
hint 206,"Entrez votre Mot de Passe"+chr$(13)+"Correspondant au Site (Sortie par Entrée)."
hide 205:hide 206
alpha 207:top 207,190:left 207,10:caption 207,"Autre élément d'accès au site:(EX: Code Postal)":font_name 207,fixedsys
edit 208:top 208,210:left 208,10:width 208,200
hint 208,"Entrez l'élément supplémentaire"+chr$(13)+"Correspondant au Site (Sortie par Entrée)."
hide 207:hide 208
alpha 209:top 209,250:left 209,10:caption 209,"Nom du site:(EX: Panoramic)":font_name 209,fixedsys
edit 210:top 210,270:left 210,10:width 210,100
hint 210,"Entrez le Nom du Site"+chr$(13)+"qui apparaîtra sur le boutton (13 caractères maxi. Sortie par Entrée)."
hide 209:hide 210
button 211:top 211,310:width 211,160:left 211,(screen_x/2)-160:caption 211,"Valider et Quitter":font_name 211,fixedsys
hide 211
' ******************************************************************************
form 300:width 300,screen_x-220:top 300,50:left 300,215:height 300,390:caption 300,"Mémo Sites: Modification ou suppression d'un élément":hide 300
command_target_is 300:on_close 300,ferme_form
alpha 301:top 301,10:left 301,10:caption 301,"Cliquez dans la colone de gauche sur l'élément à modifier ou à supprimer":font_name 301,fixedsys
container_option 302:top 302,10:left 302,10:caption 302,"  Cochez votre option  ":width 302,125:height 302,70:hide 302
option 303:parent 303,302:top 303,20:left 303,10:caption 303," Mofification "
option 304:parent 304,302:top 304,40:left 304,10:caption 304," Suppression "
alpha 305:top 305,10:left 305,10:caption 305,"Lien du site: collez ici le lien (par coller uniquement)":font_name 305,fixedsys
edit 306:top 306,30:left 306,10:width 306,screen_x-280
button 307:height 307,15:width 307,15:top 307,33:left 307,width(306)+20:caption 307,"X":font_bold 307
hint 307,"Modification du lien":hide 305:hide 306:hide 307
alpha 308:top 308,70:left 308,10:caption 308,"Identifiant d'accès au site":font_name 308,fixedsys
edit 309:top 309,90:left 309,10:width 309,200
hint 309,"Entrez votre identifiant"+chr$(13)+"Correspondant au Site (Sortie par Entrée)."
button 310:height 310,15:width 310,15:top 310,93:left 310,width(309)+20:caption 310,"X":font_bold 310
hint 310,"Modification de l'identifiant":hide 308:hide 309:hide 310
alpha 311:top 311,130:left 311,10:caption 311,"Mot de Passe d'accès au site":font_name 311,fixedsys
edit 312:top 312,150:left 312,10:width 312,200
hint 312,"Entrez votre Mot de Passe"+chr$(13)+"Correspondant au Site (Sortie par Entrée)."
button 313:height 313,15:width 313,15:top 313,153:left 313,width(309)+20:caption 313,"X":font_bold 313
hint 313,"Modification du Mot de Pass":hide 311:hide 312:hide 313
alpha 314:top 314,190:left 314,10:caption 314,"Autre élément d'accès au site:(EX: Code Postal)":font_name 314,fixedsys
edit 315:top 315,210:left 315,10:width 315,200
hint 315,"Entrez l'élément supplémentaire"+chr$(13)+"Correspondant au Site (Sortie par Entrée)."
button 316:height 316,15:width 316,15:top 316,213:left 316,width(309)+20:caption 316,"X":font_bold 316
hint 316,"Modification du Mot de Pass":hide 314:hide 315:hide 316
alpha 317:top 317,250:left 317,10:caption 317,"Nom du site:(EX: Panoramic)":font_name 317,fixedsys
edit 318:top 318,270:left 318,10:width 318,100
hint 318,"Entrez le Nom du Site"+chr$(13)+"qui apparaîtra sur le boutton (13 caractères maxi. Sortie par Entrée)."
button 319:height 319,15:width 319,15:top 319,273:left 319,width(318)+20:caption 319,"X":font_bold 319
hint 319,"Modification du Nom du Site":hide 317:hide 318:hide 319
alpha 320:top 320,320:left 320,10:caption 320,"pour sortir sans valider, utilisez la croix rouge":font_color 320,50,0,255:font_name 320,fixedsys
button 321:top 321,315:width 321,160:left 321,(screen_x/2)-160:caption 321,"Valider et Quitter":font_name 321,fixedsys
hide 320:hide 321
' ******************************************************************************
form 400:width 400,screen_x-220:top 400,450:left 400,215:height 400,int((screen_x/2))-130
caption 400,"Mémo Sites: Aide":hide 400:color 400,220,220,220:on_close 400,ferme_form
command_target_is 400
alpha 401:top 401,10:font_name 401,fixedsys:hide 401
' ******************************************************************************
command_target_is 200
f=file_exists("memsitjc.mjc")
if f=0 then file_open_write 212,"memsitjc.mjc":nbe=0:file_writeln 212,nbe:file_close 212
dlist 213:file_load 213,"memsitjc.mjc"
a$=item_read$(213,count(213)):nbe=val(a$)
if nbe>0 then gosub init
END
' ******************************************************************************
aide:
show 400:show 401
a$=" MEMO SITE: pour faciliter vos accès Internet."+chr$(13)+chr$(13)
a$=a$+" Ce petit programme a pour but d'afficher sur votre bureau une fenêtre dans laquelle,"
a$=a$+" vous pourrez accèder à vos sites Internet,"+chr$(13)
a$=a$+" en ayant sous la main vos identifiants et vos codes d'accès."+chr$(13)+chr$(13)
a$=a$+" La fenêtre vous propose un bouton par site préalablement enregistré."+chr$(13)+chr$(13)
a$=a$+" En haut de cette fenêtre, un post-it affiche votre Identifiant, votre Mot de Passe,"+chr$(13)
a$=a$+" et un troisième élément (pour certains sites: un code postal, ...)"+chr$(13)
a$=a$+" Ce post-it vous permet de copier votre identifiant et de le le coller sur le site sélectionné. (idem pour le mot de passe)"+chr$(13)+chr$(13)
a$=a$+" A droite de ce post-it il y a 3 boutons: 1) [?] pour visualiser l'aide"+chr$(13)
a$=a$+"                                          2) [+] pour enregistrer un nouveau site"+chr$(13)
a$=a$+"                                          3) [M] pour Modifier ou supprimmer un site"+chr$(13)+chr$(13)+chr$(13)
a$=a$+"-------------------------------------------------------------------------"+chr$(13)
a$=a$+" MEMO SITE: enregistrez votre premier site."+chr$(13)+chr$(13)
a$=a$+" Cliquez sur [+] pour accèder à la fenêtre d'enregistrement."
a$=a$+" Démarrez votre navigateur Internet sur votre site le plus utilisé,"+chr$(13)
a$=a$+" allez jusqu'à la page qui vous demande votre identifiant et votre code d'accès (Mot de Passe),"+chr$(13)
a$=a$+" copier le lien en haut de votre navigateur et collez-le dans l'edit prévu à cet effet."+chr$(13)
a$=a$+" Ensuite complètez identifiant, mot de passe etc..."+chr$(13)
a$=a$+" Notez que le nom du site sera celui qui apparaîtra sur le bouton correspondant"+chr$(13)
a$=a$+" Après validation le programme redémarre avec le bouton correspondant au site que vous venez de créer"+chr$(13)+chr$(13)+chr$(13)+chr$(13)+chr$(13)
a$=a$+"MémoSite.Jean claude.2011."
caption 401,a$
return
' ******************************************************************************
modsup:
if nbe<1 then message "Pas d'enregistrement":return
show 300:pv$="M"
return

md1:
text 306,"":text 309,"":text 312,"":text 315,"":text 318,""
lien$="":e1$="":e2$="":e3$="":b$=""
no=number_click:lig=no*6
clear 213:file_load 213,"memsitjc.mjc"
b$=item_read$(213,lig)
caption 300,"Mémo Sites: Modification ou suppression de "+b$:hide 301:set_focus 300
lien$=item_read$(213,lig-4)
e1$=item_read$(213,lig-3):item_add 100,e1$
e2$=item_read$(213,lig-2):item_add 100,e2$
e3$=item_read$(213,lig-1):item_add 100,e3$
show 302:mark_off 303:mark_off 304
on_click 303,modif
on_click 304,sup
return

modif:
show 320:show 321:hide 302:caption 300,"Mémo Sites: Modification de "+b$
show 305:show 306:inactive 306:text 306,lien$:show 307
show 308:show 309:inactive 309:text 309,e1$:show 310
show 311:show 312:inactive 312:text 312,e2$:show 313
show 314:show 315:inactive 315:text 315,e3$:show 316
show 317:show 318:inactive 318:text 318,b$:show 319
on_click 307,modlien
on_click 310,modident
on_click 313,modiMDP
on_click 316,modiel
on_click 319,modibuton
on_click 321,enregmodif
return

enregmodif:
if e1$="" then message "Identifiant Manquant":hide 211:set_focus 309:return
if e2$="" then message "Mot de Passe Manquant":hide 211:set_focus 312:return
if b$="" then message "Nom du Site Mnquant":hide 211:set_focus 318:return
if e3$="" then e3$=" "
lig=lig-5
item_delete 213,lig:item_insert 213,lig,"*"
item_delete 213,lig+1:item_insert 213,lig+1,lien$
item_delete 213,lig+2:item_insert 213,lig+2,e1$
item_delete 213,lig+3:item_insert 213,lig+3,e2$
item_delete 213,lig+4:item_insert 213,lig+4,e3$
item_delete 213,lig+5:item_insert 213,lig+5,b$
file_save 213,"memsitjc.mjc"
hide 200:show 0
execute MemoSiteJCJ.exe
terminate
return

modibuton:
active 318:inactive 319:text 318,"":set_focus 318
on_key_up 318, modibuton2
return

modibuton2:
if key_up_code=13 then gosub modibuton3
return

modibuton3:
b$=upper$(text$(318))
inactive 318:active 319
return

modiel:
active 315:inactive 316:text 315,"":set_focus 315
on_key_up 315, modiel2
return

modiel2:
if key_up_code=13 then gosub modiel3
return

modiel3:
e3$=text$(315)
inactive 315:active 316
return

modiMDP:
active 312:inactive 313:text 312,"":set_focus 312
on_key_up 312, modiMDP2
return

modiMDP2:
if key_up_code=13 then gosub modiMDP3
return

modiMDP3:
e2$=text$(312)
inactive 312:active 313
return

modident:
active 309:inactive 310:text 309,"":set_focus 309
on_key_up 309, modident2
return

modident2:
if key_up_code=13 then gosub modident3
return

modident3:
e1$=text$(309)
inactive 309:active 310
return

modlien:
inactive 307:active 306:text 306,""
set_focus 306:on_change 306,modlien2
return

modlien2:
active 307:inactive 306
lienp$=text$(306)
return

sup:
n=message_confirmation_yes_no("La suppression de "+b$+" entraine la suppression du bouton correspondant."+chr$(13)+chr$(13)+"Voulez-vous continuer ?")
if n<>1 then return
caption 300,"Mémo Sites: Suppression de "+b$
lig=lig-5
for n=1 to 6:item_delete 213,lig:next n
lig=count(213):nbe=nbe-1:item_delete 213,lig:item_insert 213,lig,nbe
file_save 213,"memsitjc.mjc"
hide 200:show 0
execute MemoSiteJCJ.exe
terminate
return
' ******************************************************************************
init:
nbb=int((screen_y-100)/40)+1
if nbe>=nbb then return
command_target_is 0
b$=item_read$(213,6)
button 1:top 1,140:width 1,120:height 1,20:left 1,30:caption 1,b$:font_name 1,fixedsys:on_click 1,go
if nbe=1 then return
lig=6
 for no=2 to nbe
  lig=lig+6:b$=item_read$(213,lig)
  button no:top no,top(no-1)+35:left no,30:width no,120:height no,20:caption no,b$:font_name no,fixedsys
  on_click no,go
 next no
return
' ******************************************************************************
go:
if pv$="M" then gosub md1:return
clear 100:lig=0
no=number_click:lig=no*6
b$=item_read$(213,lig)
lien$=item_read$(213,lig-4)
e1$=item_read$(213,lig-3):item_add 100,e1$
e2$=item_read$(213,lig-2):item_add 100,e2$
e3$=item_read$(213,lig-1):item_add 100,e3$
execute lien$
return
' ******************************************************************************
new:
lien$="":e1$="":e2$="":e3$="":b$=""
text 202,"":text 204,"":text 206,"":text 208,"":text 210,""
if nbe=24 then message "Plus de place pour un nouveau Site":return
show 200:hide 0
on_change 202,new2
return

new2:
lien$=text$(202)
show 203:show 204:set_focus 204
on_key_up 204,new3
return

new3:
if key_up_code=13 then gosub new4
return

new4:
e1$=text$(204)
show 205:show 206:set_focus 206
on_key_up 206,new5
return

new5:
if key_up_code=13 then gosub new6
return

new6:
e2$=text$(206)
show 207:show 208:set_focus 208
on_key_up 208,new7
return

new7:
if key_up_code=13 then gosub new8
return

new8:
e3$=text$(208)
show 209:show 210:set_focus 210
on_key_up 210,new9
return

new9:
if key_up_code=13 then gosub new10
return

new10:
b$=upper$(text$(210))
if len(b$)>13 then message "13 caractères Maximum":b$="":text 210,"":return
show 211:on_click 211,new11
return

new11:
if e1$="" then message "Identifiant Manquant":hide 211:set_focus 204:return
if e2$="" then message "Mot de Passe Manquant":hide 211:set_focus 206:return
if b$="" then message "Nom du Site Mnquant":hide 211:set_focus 210:return
if e3$="" then e3$=" "
nbe=nbe+1
item_add 213,lien$:item_add 213,e1$:item_add 213,e2$:item_add 213,e3$:item_add 213,b$:item_add 213,nbe
file_save 213,"memsitjc.mjc"
hide 200:show 0
execute MemoSiteJCJ.exe
terminate
return
' ******************************************************************************
ferme_form:
show 0:pv$="":clear 100:set_focus 100
return

fin:
terminate

A+

PS: il y a une aide intégrée et c'est le programme qui crée le fichier de stockage....
.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Klaus

avatar

Nombre de messages : 10074
Age : 68
Localisation : Ile de France
Date d'inscription : 29/12/2009

MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   Ven 7 Sep 2012 - 17:16

@Cosmos70:

Non, Read access est très bien - cela permet à nous tous de lire les dossiers.
Si tu autorises Upload, cela nous permettra de charger des choses dans tes dossiers. C'est périllleux car cela peut écraser ce que tu as mis.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://klauspanoramic.comxa.com/index.html
Invité
Invité



MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   Ven 7 Sep 2012 - 17:18

Bonjour Jean-Claude.
Oui, il me semble que tu l'a posté, il y a x temps.
Je regarderai à temps voulu. Je dois d'abord refaire mon programme.
Merci
Revenir en haut Aller en bas
Nardo26

avatar

Nombre de messages : 2294
Age : 49
Localisation : Valence
Date d'inscription : 02/07/2010

MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   Ven 7 Sep 2012 - 17:35

Bonjour,

Au sujet de myDrive :

Jusqu'à maintenant, tous le monde a employé le même système :
username : panoramic@pseudo
password : panoramic123

donc pour ce coup là, il n'y a pas grand chose à retenir...

Si un jour tartempion69 créé un compte sous mydrive,
par soucis de simplicité, je m'attendrai à retrouver ceci :

username : panoramic@tartempion69
password : panoramic123

Wink

Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://nardo26.lescigales.org
Invité
Invité



MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   Ven 7 Sep 2012 - 18:59

Salut Nardo, dans un autre post, je parle de simulation de clavier, car constamment je tape sur deux touches qui m'oblige à revenir en arrière. Je part du principe suivant, et si je peux avoir une simulation du clavier c'est encore mieux, je tape sur un bouton, il y a copie du pseudo, et si il y a <TAB> je peux envoyer en même temps le mot de passe. Et avec une liste, on a juste à choisir. C'est pas beau la vie, quand ça va bien. Je sais le mot "bien", chez moi, c'est pas souvent. pale
Revenir en haut Aller en bas
Invité
Invité



MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   Sam 15 Sep 2012 - 2:21

Bonsoir,
Je ne sais plus très bien ce que je dois faire.
Je me bats depuis plusieurs jours avec un problème de windows qui me donne le message suivant.



et ensuite bien souvent:



Chaque gosub a son return, je vérifie de partout. J'ai une chaine dans un edit qui marque le passage des routines sélectionnées, j'ai aussi une liste de toutes les procédures qui sont vues à la suite pour suivre le programme. Je ne vois pas ce que je peux reprocher à ce programme. Dès fois tout en faisant la même action, comme si j'avais une macro, j'ai pas d'erreur, bien souvent elle apparaît la 1ère ou la seconde fois.

Je ne peux pas avancer, et maintenant ça me dégoûte. J'en ai marre de ce putain de programme, dont je n'ai rien a reprocher, et qui bloque sans raison. Si il y a une raison, elle est vraiment subtile.

J'ai pensé que cela venait de l'instruction chain, car avec l'éditeur, cela semblait marché, et puis non! c'est revenu plus tard. J'ai fais un exécutable, idem. J'avais téléchargé la dernière version pour voir si il avait un changement. Pareil! Je ne suis pas infaillible, et jusqu'à maintenant je mettais le problème sur moi-même, et si seulement c'était vrai. Je pourrai trouver une parade. Mais maintenant, quoi faire?

Sleep ça n'apportera rien de continuer.

(loader_multiple.exe) est le lanceur que j'ai fais pour PsPad. J'ai une liste de programme, et je clique sur l'un des items qui correspond au programme.
Revenir en haut Aller en bas
Nardo26

avatar

Nombre de messages : 2294
Age : 49
Localisation : Valence
Date d'inscription : 02/07/2010

MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   Dim 16 Sep 2012 - 2:32

J'ai déjà rencontré le même problème sur un bout de code de 5 lignes qui ne comportai aucune erreur et la seule façon de m'en sortir a été de fermer l'editeur Panoramic et de le re-ouvrir... (il n'y avait pas de processus PANORAMIC.EXE de planqué derriere)

Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://nardo26.lescigales.org
Contenu sponsorisé




MessageSujet: Re: Un "PAGICIEL" Parcourt de pages Panoramic   

Revenir en haut Aller en bas
 
Un "PAGICIEL" Parcourt de pages Panoramic
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 2 sur 4Aller à la page : Précédent  1, 2, 3, 4  Suivant
 Sujets similaires
-
» pages internet sauteuses
» EDI réalisé entièrement en Panoramic
» EDI réalisé entièrement en Panoramic
» [Resolu] nombre de pages dans le sprite livre ??
» [Résolu] Liste des pages visitées dans Google

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Vos sources, vos utilitaires à partager-
Sauter vers: